Discussion :

[brunounours]

Bonjour,

Je souhaiterai charger une ComboBox en utilisant un filtre par l'intermédiaire d'OptionBox.

En réalité, dans ma feuille Excel "Table" j'ai en colonne A le type de profilé et en colonne B le nom du profilé

j'ai un certain nombre de type de profilés: IPE, HEA,UPN...

Dans mon Userform, j'ai un certain nombre d'OptionButton: OptionButtonIPE, OptionButtonHEA, OptionButtonUPN....

Ce que je souhaite:

Lorsque je sélectionne une Optionbox par exemple OptionButtonIPE que la ComboBoxNomDuProfile ne se charge que des Nom de profilés (colonne B) qui ont dans la colonne A le type de profilé sélectionné dans l'OptionBox (dans notre exemple IPE).

J'espère avoir été clair, pour plus de clarté, je mets en pièce jointe le fichier sur lequel je travail.

Merci beaucoup pour votre aide.

Cdt, Bruno

[Theze]

Bonjour,

Une piste. Tu insère un module de classe et tu le nomme "ClsOption" dans sa propriété "Name" puis tu colle le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
Public WithEvents GroupeOpt As MSForms.OptionButton
 
Private Sub GroupeOpt_Click()
 
    Dim Ctrl As Control
    Dim Plage As Range
    Dim Cel As Range
 
    'défini la plage de recherche, à adapter, car je suppose qu'elle va grandir !
    'ou alors la définir dynamiquement
    Set Plage = Worksheets("Table").[A20:A82]
 
    With UserFormPrix
 
        'parcour les boutons d'option du cadre
        For Each Ctrl In .Frame1.Controls
 
            If TypeName(Ctrl) = "OptionButton" Then
 
                'si coché
                If Ctrl.Value = True Then
 
                    'vide le combo
                    .ComboBoxNomDuProfile.Clear
 
                    For Each Cel In Plage
 
                        'si le nom du bouton d'option coché contient
                        'la valeur de la cellule, charge la valeur de la
                        'cellule située immédiatement à droite de la cellule active
                        If InStr(Ctrl.Name, Cel) <> 0 Then
                            .ComboBoxNomDuProfile.AddItem Cel.Offset(0, 1)
                        End If
 
                    Next Cel
 
                    'il n'est pas nécessaire d'aller plus loin, 1 seul bouton
                    'pouvant être coché
                    Exit Sub
 
                End If
 
            End If
 
        Next Ctrl
 
    End With
 
    Set Ctrl = Nothing
 
End Sub

Dans le module de ta Form "UserFormPrix" tu colle le code ci-dessous (en tête de module) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Dim Opt() As New ClsOption '<-- en tête de module
 
Private Sub UserForm_Initialize()
 
    Dim Ctrl As Control
    Dim I As Integer
 
    'parcour la collection de boutons d'option du cadre
    'et les mets dans un tableau afin d'avoir une proc
    'commune à tous (voir le module de classe "ClsOption")
    For Each Ctrl In Me.Frame1.Controls
 
        If TypeName(Ctrl) = "OptionButton" Then
 
            I = I + 1
            ReDim Preserve Opt(1 To I)
            Set Opt(I).GroupeOpt = Ctrl
 
        End If
 
    Next Ctrl
 
    Set Ctrl = Nothing
 
End Sub

A chaque clic sur un bouton d'option, le combo se remplira avec les valeurs correspondantes, pour cela, la cellule doit contenir une partie du nom du bouton d'option mais attention, il y aura un problème avec le bouton d'option "T" car les valeurs de "TubeCarre" et TubeRond" seront aussi chargées. Faire suivre "T" d'une autre ou de plusieurs autres lettres afin d'avoir des valeurs uniques.

Hervé.

[brunounours]

Merci beaucoup!!

Ca Marche trés bien! (En changeant T mais cela n'a pas d'importance )

J'ai trouvé une autre solution qui marche aussi sans le problème du T.

En PJ le fichier.

Cdt, Bruno