Discussion :

[Shankara]

Bonjour,
Mes connaissances sont assez limitées donc je voudrais votre avis.
J'ai un formulaire "frmRechercheClient" qui contient des champs de saisie à partir desquels la requête qui alimente la zone de liste affichant les clients est construite.
Lorsque je double-clique sur un élément de la liste, un autre formulaire "frmFicheClient" s'ouvre et les champs de saisie qu'il contient se remplissent avec les champs de l'élément double-cliqué du formulaire "frmRechercheClient".
Les 2 formulaires n'ont pas de source. Voici le code dans le formulaire "frmRechercheClient" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
Private Sub lstClients_DblClick(Cancel As Integer)
' Le double clic sur un client de la liste permet de modifier sa fiche
 
    Dim rs As recordset
    Dim SQL As String
    Dim ctrl As Control
 
    ' Ouverture d'un RecordSet permettant de récupérer toutes les propriétés d'un client donné et de les
    ' afficher dans les champs correspondants du formulaire "frmFicheClient"
    SQL = "SELECT * FROM Client WHERE NumCl = " & Me.lstClients & ";"
    Set rs = CurrentDb.OpenRecordset(SQL, dbOpenForwardOnly, dbReadOnly)
 
    ' Ouverture de la fiche Client et initialisation de la variable indiquant que l'on se trouve ici
    ' dans le cadre d'une modification de la fiche
    DoCmd.OpenForm "frmFicheClient"
    With Forms![frmFicheClient]
        .modifCl = True
        .numClient = Me.lstClients
    End With
 
    ' Remplissage des champs de la fiche, affichage du bouton "Modifier" (désactivé tant qu'aucune saisie n'a été faite dans les
    ' champs de la fiche Client), désactivation du bouton
    ' "Ajouter" qui est alors masqué puisqu'il est inutile pour la modification
    For Each ctrl In Forms![frmFicheClient].Controls
        Select Case ctrl.Name
            Case "txtNomClient"
                ctrl.Value = rs.Fields("NomCl").Value
            Case "txtPrenomClient"
                ctrl.Value = rs.Fields("PrenomCl").Value
                ctrl.Enabled = False
            Case "txtDateNaissClient"
                ctrl.Value = rs.Fields("DateNaissCl").Value
                ctrl.Enabled = False
            Case "txtAdresseClient"
                ctrl.Value = rs.Fields("AdresseCl").Value
            Case "txtCPClient"
                ctrl.Value = rs.Fields("CPCl").Value
            Case "txtVilleClient"
                ctrl.Value = rs.Fields("VilleCl").Value
            Case "txtTelClient"
                ctrl.Value = rs.Fields("TelCl").Value
            Case "txtDateInscClient"
                ctrl.Value = rs.Fields("DateInscCl").Value
                ctrl.Enabled = False
            Case "txtDateRadClient"
                ctrl.Value = rs.Fields("DateRadCl").Value
            Case "txtMotifRadClient"
                ctrl.Value = rs.Fields("MotifRadCl").Value
            Case "cmdAjoutClient"
                ctrl.Enabled = False
                ctrl.Visible = False
            Case "cmdModifClient"
                ctrl.Enabled = False
                ctrl.Visible = True
        End Select
    Next ctrl
 
    rs.Close
End Sub

Le formulaire frmFicheClient me sert à la fois pour la modification d'une fiche et pour l'ajout. Pour une modification, la variable modifCl est initialisée à True, à False pour un ajout. Le formulaire "frmFicheClient" n'a pas de source et ses contrôles non plus, ils ne sont remplis par code que lors d'une modification (double-clic dans la liste du formulaire "frmRechercheClient").

Est-ce la bonne méthode ? Dois-je plutôt faire en sorte que les contrôles du formulaire "frmFicheClient" soient liés à une requête et si oui comment ?
Merci de vos avis.

[marot_r]

Ce n'est pas une mauvaise méthode et cela te donne le plein contrôle sur ce qui est enregistré. Access validant automatiquement les données quand tu changes d'enregistrement cela peut être pénible.

Par contre tu redéveloppes quelque chose que Access fait naturellement.

Faire un formulaire lié est très simple, tu définis la source comme étant ta requête ou ta table et tu précises pour chaque champs quel est le champ correspondant dans la source.

Access s'occupe alors de gérer les accès concurents, les types de données, éventuellement les règles de validité sur les champs. Bref un tas de choses que tu n'as pas à recoder.

A+

[Shankara]

J'ai fait une copie de mon projet et j'essaie de remplacer mon formulaire indépendant par un formulaire dont la source est ma table Client. J'y mets une clause Where dans les arguments de DoCmd.OpenForm situé dans la procédure de double-clic sur la liste du formulaire "frmRechercheClient".
J'ai alors des messages d'erreur pour chaque procédure événementielle. J'ai retiré celles des contrôles pour seulement avoir la Form_BeforeUpdate mais j'ai là aussi un message d'erreur :
"L'expression AVANT MAJ entrée comme paramètre de la propriété de type événement est à l'origine d'une erreur. La déclaration de la procédure ne correspond pas à la description de l'événement ou de la procédure de même nom."
Voici le code associé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub Form_BeforeUpdate(Cancel As Integer)
    If Me.txtNomClient.Value <> Me.txtNomClient.OldValue Then
        MsgBox ("Ancienne valeur : " & Me.txtNomClient.OldValue & vbCrLf & _
                "Nouvelle valeur : " & Me.txtNomClient.Value)
    Else
        MsgBox ("Valeurs identiques")
        Cancel = True
    End If
End Sub

Je ne comprends pas. Il ne me semble pas qu'il y ait une erreur dans le code pourtant ...

[marot_r]

La déclaration de la procédure ne correspond pas à la description de l'événement ou de la procédure de même nom."

Tu as probablement altérer la signature (liste des paramètres) d'une de tes fonctions associées aux événements.

Mets ce code en commentaire et redemande la création du squelette de procédure événementielle en cliquant sur l'événement voulu.

A+