Discussion :

[AnalytX]

Bonjour à tous,

J'utilise la PROC SGPANEL comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
proc sgpanel data=TABLE; 
	panelby SEMAINE / layout=columnlattice onepanel noborder novarname colheaderpos=bottom;
	vbar TRAITEMENT / response=VARIABLE group=TRAITEMENT stat=mean transparency=0.4 limits=upper limitstat=stderr; 
	rowaxis grid label='Label Axe Y'; 
	colaxis label='Label Axe X' display=(novalues noticks);
	keylegend /position=right across=1; 
run;  
quit;

J'ai un problème avec la génération des barres d'erreur avec le message suivant :
WARNING: Limits are not allowed on bar charts when a group variable is used. The option will be ignored.

Avez-vous une idée pour contourner ce problème?

Merci d'avance et bonne journée

[datametric]

il semble que GROUP=TRAITEMENT soit en trop.

[AnalytX]

Bonjour,

Le GROUP= permet de mettre des couleurs différentes selon la classification désirée, ici le TRAITEMENT (couleurs précédemment définies dans une PROC TEMPLATE).

Ce problèmes est connu de SAS (http://support.sas.com/kb/40/752.html, mais je souhaitais savoir si quelqu'un avait trouvé une alternative.

[olivier.decourt]

Bonjour.
L'astuce est de calculer les stats à l'avance et de contourner les limites de VBAR en faisant à la place un NEEDLE avec des traits épais. L'intervalle de confiance provient pour sa part d'un SCATTER dont les marqueurs sont de taille zéro.
Dans l'exemple, la 1e SGPANEL est identique à ce que tu as sans option GROUP. Toutes les barres sont de même couleur. J'imagine que tu veux les différencier : c'est ce qu'on obtient dans la 2e, après préparation des données.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
PROC SGPANEL DATA=sashelp.class ;
  PANELBY age ;
  VBAR sex / RESPONSE=weight STAT=MEAN LIMITS=UPPER LIMITSTAT=STDERR ;
RUN ;
/* avec un GROUP pour avoir des barres de couleurs différentes */
PROC SUMMARY DATA=sashelp.class NWAY ;
  CLASS sex age ;
  VAR weight ;
  OUTPUT OUT=work.stats MEAN=moy STDERR=std ;
RUN ;
DATA work.stats ;
  SET work.stats ;
  up = moy+std ;
RUN ;
PROC SGPANEL DATA=work.stats NOAUTOLEGEND ;
  PANELBY age ;
  NEEDLE X=sex Y=moy / LINEATTRS=(THICKNESS=5% PATTERN=SOLID)
					   GROUP=sex ;
  SCATTER X=sex Y=moy / YERRORUPPER=up MARKERATTRS=(SIZE=0)
					   GROUP=sex ;
RUN ;

Bon courage.
Olivier

[AnalytX]

Bonjour,

Merci Olivier pour ta réponse. Bien vu. Je vais essayer de jouer avec ça.

Bonne journée.