Discussion :

[idiot]

Bonjour,

Je ne sais pas si je suis au bon endroit du forum: Désolé.

J'ai réalisé une base à mon travail qui marche bien sans message d'erreur.

Mais cette base chez moi affiche le message suivant :
Erreur d'exécution 3043, l'accès réseau a été interrompu. Pour continuer, fermer la base de données, puis rouvrez-la."

J'ai fermé la base et ré-ouvert mais rien y fait.

Cela se passe quand j'ouvre un formulaire.

De plus sauf erreur, je ne cherche pas dans ma base a faire un appel au réseau.

merci!

[Invité]

Bonjour
J'ai eu de temps en temps ce message.
En général cela est le signe que la base est corrompue pour une raison ou une autre.
Dans un prmier temps tenter de faire un compactage.
Si cela continue, la seule façon que j'ai trouvé de résoudre le problème est de créer une base neuve et de réimporter les différents objets dedans.
Soit l'importation se fera normalement, soit elle bloquera sur l'objet corrompu.
Dans ce cas il faudra recréer cet objet.
Après l'importation, bien ajouter les références éventuelles manquantes et recompiler l'ensemble.

[idiot]

Merci pour ce conseil qui m'a permis de relever le problème.
Le problème est le suivant:
La base au travail je l'ai crée non pas sur le disque principale "c" mais sur un autre disque physique "d".
et j'ai fractionner la base pour avoir les données d'un coté et le reste de l'autre.
Mes tables sont lié avec un chemin défini au moment de la fraction ("d").
Et le problème est que chez moi il n'y a pas de disque "d". D'ou le message d'erreur.

Y -a t-il moyen à l'ouverture de la base qu'il prenne le chemin de la base qui est ouverte pour chercher dans le même dossier les tables liés.

merci!

[Kaptin]

Salut,

si tu as séparé tes tables de tes formulaires, requêtes, état, etc., si le chemin est différent sur ton poste, Acces ne peut faire le lien entre tes tables et le reste.

Une solution :

supprime le lien entre tes formulaires et les tables (en supprimant les tables dans la base qui contient les formulaires), ensuite va dans Données externes -> Importer -> Access

Dans l'assistant, choisir le deuxième choix, Suivant, sélectionne les tables que tu as besoin, Suivant, va chercher la base de données qui contient tes tables, et voilà!

Dit moi si cela fonctionne correctement

[Domi2]

Bonjour,

supprime le lien entre tes formulaires et les tables (en supprimant les tables dans la base qui contient les formulaires), ensuite va dans Données externes -> Importer -> Access

Non !

Si la base a été scindée base frontale/base dorsale, ce qui est un déploiement correct, pourquoi veux-tu réimporter les tables dans la base frontale ?

Il suffit simplement de rafraîchir les liens vers la base dorsale.

Pour les versions antérieures à Access 2007, menu Outils ==> Utilitaires de bases de données ==> Gestionnaire de tables liées.

Je n'ai pas Access 2010, à chercher.

Une fois l'assistant ouvert, tu cherches ta base contenant les données, tu sélectionnes les tables, et tu rafraîchis, c'est tout.

Domi2

[LedZeppII]

Bonjour,

Y -a t-il moyen à l'ouverture de la base qu'il prenne le chemin de la base qui est ouverte pour chercher dans le même dossier les tables liés.

Voici un exemple de code à lancer à l'ouverture de la base de données.
Conditions d'utilisations :
- Toutes les tables liées pointent vers une seule et même dorsale Access.
- La dorsale est dans le même dossier que la frontale, sinon adapter ligne 10.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
Sub VerifierTableLiees()
Dim sDorsale As String, sDorsaleDsLien As String
Dim sConn As String, sNewConn As String
Dim db As DAO.Database, tdef As DAO.TableDef
Dim ConnParams() As String, varParam As Variant
 
' On suppose que toutes les tables liées, le sont dans la même dorsale
 
' Chemin complet vers base dorsale
sDorsale = CurrentProject.Path & "\NomDeLaDorsale.mdb"
 
If Len(Dir(sDorsale)) = 0 Then
   MsgBox sDorsale, vbExclamation, "Dorsale non trouvée"
   Exit Sub
End If
 
Set db = CurrentDb
' Pour toutes les tables de cette bdd
For Each tdef In db.TableDefs
   ' Si c'est une table liée
   If (tdef.Attributes And dbAttachedTable) = dbAttachedTable Then
      ' Extraire chemin complet vers la dorsale
      sConn = tdef.Connect
      sDorsaleDsLien = GetLinkedACCDB(sConn)
      ' Si la dorsale n'est pas la bonne, recréer le lien
      If (sDorsaleDsLien <> sDorsale) Then
         ' Nouvelle chaîne de connexion
         sNewConn = ";"
         ' Récuperer mot de passe si existe
         ConnParams() = Split(sConn, ";")
         For Each varParam In ConnParams
             If varParam Like "PWD=*" Then
                sNewConn = sNewConn & varParam & ";"
             End If
         Next
         ' Ajout chemin vers la base dorsale
          sNewConn = sNewConn & "DATABASE=" & sDorsale
         ' rafraichir lien
         tdef.Connect = sNewConn
         tdef.RefreshLink
      End If
   End If
Next
 
End Sub
 
' Renvoie base liée access (Dorsale)
Function GetLinkedACCDB(strConnect As String) As String
Dim p As Long, strDBFullPathName As String
 
p = InStr(1, strConnect, "DATABASE=")
If p > 0 Then
   strDBFullPathName = Mid(strConnect, p + Len("DATABASE="))
End If
p = InStr(1, strDBFullPathName, ";")
If p > 1 Then
   strDBFullPathName = Left(strDBFullPathName, p - 1)
End If
 
GetLinkedACCDB = strDBFullPathName
End Function

A+

[Pierre Fauconnier]

Salut Domi,

[...]
Pour les versions antérieures à Access 2007, menu Outils ==> Utilitaires de bases de données ==> Gestionnaire de tables liées.

Je n'ai pas Access 2010, à chercher.[...]

Le plus simple, clic droit sur une table puis gestionnaire de tables liées.

Via le menu 2010, Données externes > Importer et lier > Gestionnaire de tables liées.