Discussion :

[OutilSUiVi]

Bonjour à tous,

"Jeune codeur vba" je bloque sur ce problème:

Je souhaiterai, lors du double clic sur une cellule, afficher une fiche contact via un userform:

ex) ma feuille 1 colonne A contient en A3: "monsieur A / responsable...", A4: "monsieur B / chargé..."...
ma feuille 2 contient la liste des infos contact (tel, mail...) en A3 "monsieur C" en B3 "tel..." C3 "mail..." ...

je désire par ex les infos concernant "monsieur A"...

=> je double clic sur A1, le code "lit" le contenu de ma cellule A1 feuille1 (autrement dit "monsieur A"), cherche alors les infos contact correspondantes (dans ma feuille 2)... et me présente alors le résultat sous forme UF.

Merci d'avance pour votre aide, en espérant que l'explication soit à peu près claire

[Jean-Philippe André]

salut,

et à quel niveau de ton processus as-tu besoin d'être aiguillé ?

Le double clic est géré dans l'évènement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
 
End Sub

pour avoir la cellule tu as Target

exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
MsgBox Target.Address
End Sub

ensuite à toi de manipuler les données issues de cette cellule pour en faire ce que tu souhaites

[OutilSUiVi]

Merci pour ta résponse, j'aurais du en effet joindre mon mini bout de code

voilà ce que j'avais essayé (encore une fois je débute depuis 1petit mois dc soyez indulgents ^^ ç'est un peu de la cuisine avec mes minis connaissances )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
 
Dim a As String
Dim b As String
Dim i As Integer
 
a = Target.Value
 
For i = 3 To 20 'parcours la colonne contact
b = Sheets("COORDONNEES").Cells(i, "A").Value
 
If Left(a, 5) = Left(b, 5) Then 'comparaison des 5premiers caractères
MsgBox Target.Value & vbCrLf & vbCrLf & "mail:  " & Sheets("COORDONNEES").Cells(i, "B").Value & vbCrLf & "numéro(s) tél:  " & Sheets("COORDONNEES").Cells(i, "C").Value
End If
 
Next i
 
 
End Sub

mon problème se situe en fait d'avantage dans la comparaison de contenu, puisque les deux colonnes à comparer sont différentes...

la colonne "infos contact" contient exclusivement "NOM + Prénom" tandis que l'autre "NOM + PRENOM + / POSTE"...
avec la fonction left() je ne compare que les premiers caracteres mais cela reste limité:
ca bloque si par exemple j'ai 2 personnes "DUPOND"...
et difficile d'étendre d'avantage le test de left( ,6) à plus... ex) "LI Xu" va comparer avec "Li Xu /" et le test ne marche plus...

j'éspère avoir été clair , idéalement il faudrait une méthode de comparaison de contenu rigoureuse... des idées?

[Philippe Tulliez]

Bonjour,
Ce que tu cherches si j'ai bien compris, c'est comparer deux champs Nom et Prénom provenant de 2 endroits différents.
Dans l'un les champs ils sont dans une colonne et concaténés dans l'autre ils sont concaténés avec en plus le code postal précédé d'un Slash.

[OutilSUiVi]

Oui c'est presque ça

Ma première colonne tu as "NOM + PRENOM" ex) DUPOND Pierre

La seconde: "NOM + PRENOM + / + INTITULE POSTE" ex) DUPOND Pierre / responsable....

l'idéal serait donc de comparer jusqu'au caractere " / " mais je vois pas trop comment faire :S

spliter le contenu cellule pour ne garder que nom + prénom, puis copier dans une colonne les infos collectée ainsi et comparer alors le contenu exact des 2 colonnes restantes nom + prénom?

[Philippe Tulliez]

Bonjour,
Voilà une petite fonction vite fait à adapter suivant tes besoins

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Option Explicit
Sub testCompare()
 Dim N1 As String, N2 As String
 N1 = "Jean Til": N2 = "Jean  TIl/1050"
 MsgBox "Les noms " & N1 & " et " & N2 & " sont : " & IIf(isSame(N1, N2), "Similaires", "Différents")
 N1 = "Jeanne Til": N2 = "Jean  TIl / 1050"
 MsgBox "Les noms " & N1 & " et " & N2 & " sont : " & IIf(isSame(N1, N2), "Similaires", "Différents")
 N1 = "Jean Til": N2 = "Jean  TIl * 1050"
 MsgBox "Les noms " & N1 & " et " & N2 & " sont : " & IIf(isSame(N1, N2, "*"), "Similaires", "Différents")
End Sub
Function isSame(Nom1 As String, Nom2 As String, Optional Sep As String = "/") As Boolean
 ' Compare 2 chaînes de caractère Nom1 & Nom2 en supprimant les caractères "/" & suivants de Nom2
 ' La comparaison se fait en supprimant tous les espaces et transformant la chaîne en majuscule
 ' [Sep] argument facultatif avec comme valeur par défaut "/"
 Nom2 = Left(Nom2, InStrRev(Nom2, Sep) - 1)
 isSame = UCase(Replace(Trim(Nom1), " ", "")) = UCase(Replace(Trim(Nom2), " ", ""))
End Function

[OutilSUiVi]

j'ai peur de pas tt comprendre mais je vais creuser un peu, merci

[Philippe Tulliez]

Bonjour,
Qu'est-ce que tu ne comprends pas ?
C'est une fonction nommée isSame qui te renvoie TRUE si la chaîne de caractères contenue dans l'argument Nom1 est identique que la chaîne nom2 amputée du caractère représenté par l'argument Sep qui est optionnel et dont la valeur par défaut est le "/" slash, et les caractères qui le suivent.
Pour éviter les surprises de minuscules ou de caractères espacés, en général je transforme tout en majuscules et supprime les espaces.
Je viens à l'instant de constater une petite modification à apporter à la fonction qui risque de se mettre en erreur si Nom2 n'a pas le caractère représenté par l'argument Sep.
L'instruction ci-dessous doit être précédée d'un test.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 If InStrRev(Nom2, Sep) Then Nom2 = Left(Nom2, InStrRev(Nom2, Sep) - 1)

La procédure modifiée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Function isSame(Nom1 As String, Nom2 As String, Optional Sep As String = "/") As Boolean
 ' Compare 2 chaînes de caractères Nom1 & Nom2 en supprimant les caractères "/" & suivants de Nom2
 ' La comparaison se fait en supprimant tous les espaces et transformant la chaîne en majuscules
 ' [Sep] argument facultatif avec comme valeur par défaut "/"
 If InStrRev(Nom2, Sep) Then Nom2 = Left(Nom2, InStrRev(Nom2, Sep) - 1)
 isSame = UCase(Replace(Trim(Nom1), " ", "")) = UCase(Replace(Trim(Nom2), " ", ""))
End Function

[OutilSUiVi]

Super j'ai jeté un coup d'oeil dans l'aide vba suite à ton message concernant set et isame! en tt cas merci pour tes précisions

Bonne continuation

Merci à tous