Discussion :

[yfchauer]

Bonjour à tous,
Je cherche une formule qui me permettra de calculer la moyenne d'une plage sans tenir compte des cellules vides ou ayant la valeur '0'
Ex.
calculer la moyenne de la plage (A5:L5) dans la cellule M5 avec la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NBVAL(A5:L5)=0;"";MOYENNE(A5:L5)

Comme les données sur cette plage sont importées d'une autre feuille, la moyenne est erronée, lorsque certaines cellules de la plage sont vides
mais sous-entendu avec une valeur "0"
Merci d'avance pour votre aide.

[gFZT82]

Bonjour,

Essaie avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME($A$5:$L$5)/(NB.SI($A$5:$L$5;"<>0")-NB.VIDE($A$5:$L$5))

Cordialement.

[hben1961]

Bonjour à tous,

Une réponse à la question avec l'une des formules suivantes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOYENNE(SI(SOMMEPROD(($A$5:$L$5<>"")*($A$5:$L$5<>0));$A$5:$L$5))

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME($A$5:$L$5)/(12-SOMMEPROD(($A$5:$L$5="")*($A$5:$L$5=0)))

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME($A$5:$L$5)/SOMMEPROD(($A$5:$L$5<>"")*($A$5:$L$5<>0))

ou la formule matricielle (A valider par Ctrl+Maj+Entree)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOYENNE(SI(($A$5:$L$5<>"")*($A$5:$L$5<>0);($A$5:$L$5)))

Cordialement

[yfchauer]

Bonjour à tous,

Merci pour votre aide, les différentes formules fonctionnent.
j'en suis ravi.
Mais je viens de constater qu'il me renvoie une division par 0 sur une ligne où aucune donnée n'est récupérée.
Comme je l'ai dit plus haut, les données sont importées d'une autre feuille.
Donc, certaines lignes peuvent n'avoir aucune donnée, en incrémentant la formule, j'ai "#DIV/0"
Maintenant, je souhaite comment ne pas avoir cette erreur.
Une fois de plus, merci pour votre aide.

[gFZT82]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(SOMME($A$5:$L$5)/(NB.SI($A$5:$L$5;"<>0")-NB.VIDE($A$5:$L$5));"")

Cordialement.

[Zodette]

Bonjour,

Comme la version utilisée d'Excel est 2003, la fonction SIERREUR() n'est pas disponible.

À la place on utilise un si() régulier imbriqué avec la fonction ESTERREUR()

Voici la fonction.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERREUR(SOMME($A$5:$L$5)/(NB.SI($A$5:$L$5;"<>0")-NB.VIDE($A$5:$L$5)));"";SOMME($A$5:$L$5)/(NB.SI($A$5:$L$5;"<>0")-NB.VIDE($A$5:$L$5)))

Heureusement qu'en version 2007 ils on ajouté la fonction SIERREUR() ceci nous dispense de répéter le calcul pour tester si il retourne une erreur.

Zodette

[Daranc]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=esterreur(maformule);"";ma formule)

lourd mais le fait sous 2003

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=esterreur(maformule);"";ma formule)

Tu es sûr de ce que tu viens d'écrire?

[Daranc]

oups!
fectivement j'ai oublié le si
donc on reprends

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=si(esterreur(ma_formule);"";maformule)

avec toutefois les limitations de 2003: 7 fonction si imbriquées
et en relisant le poste je constate que zodette a déjà donné la réponse