Vérifier qu'un AddIn est chargé

**Oyabi** · 21/08/2012, 14h54

Bonjour à tous,
je souhaiterais vérifier qu'un AddIn est chargé à l'ouverture d'un classeur.
J'utilise ce code mais j'ai une erreur (Erreur d’exécution '9': L'indice n'appartient pas à la sélection).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Check()
 
    If AddIns("Le nom de mon AddIn").Installed = True Then
        MsgBox "Installé"
   Else
      MsgBox "L'AddIn n'est pas installé. Seule la consultation est possible."
        ThisWorkbook.ChangeFileAccess Mode:=xlReadOnly
    End If
 
End Sub

Voyez vous ou est l'erreur ?
Bonne journée.

**Philippe Tulliez** · 21/08/2012, 15h01

Bonjour,
Ce ne serait pas superflu que tu indiques à quelle ligne ce message d'erreur s'affiche.

**Oyabi** · 21/08/2012, 15h09

Aucune ligne en particulier malheureusement, j'ai juste ce message qui s'affiche.
Si je rajoute On Error Resume Next je n'ai plus l'erreur mais qu'importe ce que je mets comme nom d'AddIn, le message Installé s'affiche.

**fring** · 21/08/2012, 15h16

Bonjour,

Essaie comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Application.AddIns.Item("Le nom de mon AddIn").Installed = True Then

**Oyabi** · 21/08/2012, 15h25

Toujours pareil, ne faudrait il pas faire un foreach sur chaque AddIn et le comparer au miens ? Mais comment obtenir la liste ?
Merci

**Philippe Tulliez** · 21/08/2012, 15h30

Bonjour,
Voici un exemple de code pour lister le non des addins et s'ils sont installés ou pas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 Dim ad As AddIn
 For Each ad In AddIns
  Debug.Print ad.Name, ad.Installed = True
 Next

Il y a effectivement une erreur qui est déclenchée avec ce test que tu as montré.
On pourrait le détourner avec un ON ERROR

**mercatog** · 21/08/2012, 15h32

Je ferai comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Test()
 
Check "XYChartLabeler.xlam"
End Sub
 
Private Sub Check(ByVal AdiName As String)
Dim Adin As AddIn
 
If Not ThisWorkbook.ReadOnly Then
    For Each Adin In AddIns
        If Adin.Name = AdiName Then
            If Adin.Installed = True Then
                MsgBox "Installé"
            Else
                MsgBox "L'AddIn " & AdiName & " n'est pas installé. Seule la consultation est possible."
                ThisWorkbook.Saved = True
                ThisWorkbook.ChangeFileAccess Mode:=xlReadOnly
            End If
            Exit For
        End If
    Next Adin
End If
End Sub

**Oyabi** · 21/08/2012, 15h52

Malheureusement rien ne se produit que je mette un nom correct ou non.

Toujours rien avec ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Workbook_Open()
    Dim ad As AddIn
    For Each ad In AddIns
        If ad.Application.AddIns.Item("Le nom de mon AddIn").Installed = True Then
           MsgBox "Installé"
         Else
             MsgBox "L'AddIn n'est pas installé. Seule la consultation est possible."
              ThisWorkbook.ChangeFileAccess Mode:=xlReadOnly
         End If
    Next
End Sub

Je sèche complétement là.

Si vous avez des idées je suis tout ouie.

**mercatog** · 21/08/2012, 16h10

J'ai testé la code proposé (mais mis sur l'évènement Open du classeur)

Testé avec 2 addins de chez moi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub Workbook_Open()
 
Check "SOLVER.XLAM"
'Check "XYChartLabeler.xlam"
End Sub
 
Private Sub Check(ByVal AdiName As String)
Dim Adin As AddIn
 
If Not ThisWorkbook.ReadOnly Then
    For Each Adin In Application.AddIns
        If UCase(Adin.Name) = UCase(AdiName) Then
            If Adin.Installed = True Then
                MsgBox "AddIn " & AdiName & " installé"
            Else
                MsgBox "L'AddIn " & AdiName & " n'est pas installé. Seule la consultation est possible."
                ThisWorkbook.Saved = True
                ThisWorkbook.ChangeFileAccess Mode:=xlReadOnly
            End If
            Exit For
        End If
    Next Adin
End If
End Sub

**Oyabi** · 21/08/2012, 16h23

Ça fonctionne en effet avec Check "SOLVER.XLAM" mais pas avec Check "XYChartLabeler.xlam", ni avec Check "Gestion Planning.vsto" qui est mon AddIn. Étrange non ?

**mercatog** · 21/08/2012, 16h38

Tes Addins sont référencés dans l'onglet Développeur > Compléments??

**Oyabi** · 21/08/2012, 16h40

Mon AddIn est dans Développeur -> Compléments COM. Et il est bien activé. mais le fichier est un vsto ça peut poser problème tu crois ?
Mais c'est bizarre que ça ne marche pas avec Check "XYChartLabeler.xlam" de toute façon non ?

**Philippe Tulliez** · 21/08/2012, 16h45

Bonjour,
Quand tu fais tourner ce code, ton addin est il reprit dans la liste

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 Dim ad As AddIn
 For Each ad In AddIns
  Debug.Print ad.Name, ad.Installed
 Next

**Oyabi** · 21/08/2012, 16h56

Rien ne s'affiche.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Public Sub test()
Dim ad As AddIn
 For Each ad In AddIns
  Debug.Print ad.Name, ad.Installed
 Next
End Sub

Désolé je ne connais pas grand chose en développement de macro j'ai peut être mal copié ton code.

**Philippe Tulliez** · 21/08/2012, 17h19

Bonjour,

L'instruction Debug.Print est une commande qui permet d'afficher ce qui suit dans la fenêtre d'exécution. Cela remplace avantageusement le MsgBox qui interrompt l'exécution du programme puisqu'il faut chaque fois répondre OK
Donc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print ad.Name, ad.Installed

est préférable à

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox ad.Name, ad.Installed

pour déboguer un programme.
Pour afficher la fenêtre d'exécution dans l'éditeur VBE
Affichage/Fenêtre Exécution ou Ctrl+G

**mercatog** · 21/08/2012, 18h03

Il s'agit d'un Complément COM. Analogiquement (on utilise la description au lieu du nom)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub Workbook_Open()
 
'Check "VBA Code Cleaner 5.0"
Check "Smart PDF Converter Excel Addin"
End Sub
 
Private Sub Check(ByVal cmAdDesc As String)
Dim CmAd As COMAddIn
 
If Not ThisWorkbook.ReadOnly Then
    For Each CmAd In Application.COMAddIns
        If UCase(CmAd.Description) = UCase(cmAdDesc) Then
            If CmAd.Connect Then
                MsgBox "COM Add-In " & cmAdDesc & " installé"
            Else
                MsgBox "COM AddIn " & CmAd & " n'est pas installé. Seule la consultation est possible."
                ThisWorkbook.Saved = True
                ThisWorkbook.ChangeFileAccess Mode:=xlReadOnly
            End If
            Exit For
        End If
    Next CmAd
End If
End Sub

**Oyabi** · 21/08/2012, 18h10

@ corona
Je comprends mieux merci à toi.

@ mercatog
Ca marche j'arrive à voir mon AddIn bien joué.

En revanche ça ne marche pas si je mets un nom bidon. Je vais chercher d'où ça peut venir. Je mettrais en résolu quand j'aurais trouvé.
Merci à vous.

**mercatog** · 21/08/2012, 18h34

Fais ce test

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Test()
Dim CmAd As COMAddIn
 
For Each CmAd In Application.COMAddIns
    Debug.Print CmAd.Description, CmAd.progID, CmAd.Connect
Next CmAd
End Sub

Regarde mon précédent post #16 qui utilise la Description du COM Add-In

**Oyabi** · 21/08/2012, 18h42

Je viens d'éditer mon post j'avais malheureusement loupé le tiens.

Pourrais-je avoir une explication sur les différents type de fichiers (XLAM, VSTO et XLL je crois) ou tout du moins un lien ?

**mercatog** · 21/08/2012, 19h06

Pour vérifier les 3 cas de figures
1. COM existant et connecté
2. COM existant mais non connecté
3. COM inexistant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Sub Check(ByVal cmAdDesc As String)
Dim Trouve As Boolean, Connecte As Boolean
Dim CmAd As COMAddIn
Dim Msg As String
 
If Not ThisWorkbook.ReadOnly Then
    For Each CmAd In Application.COMAddIns
        If UCase(CmAd.Description) = UCase(cmAdDesc) Then
            Trouve = True
            Connecte = CmAd.Connect
            Exit For
        End If
    Next CmAd
 
    If Trouve And Connecte Then
        Msg = "COM Add-In " & cmAdDesc & " connecté"
    Else
        Msg = "COM AddIn " & cmAdDesc & " n'est pas " & IIf(Not Trouve, "installé", "connecté") & "." & vbNewLine & "Seule la consultation est possible."
        With ThisWorkbook
            .Saved = True
            .ChangeFileAccess Mode:=xlReadOnly
        End With
    End If
    MsgBox Msg
End If
End Sub

Vérifier qu'un AddIn est chargé [XL-2010]

Macros et VBA Excel

Discussions similaires

Partager

Partager