Discussion :

[Leehan]

Bonjour,

Soit un tableau dont une colonne dont certaines cellules contenant une série de chiffres séparées par des ,
ex : ligne1 2524, 2525, 2526

Je cherche à obtenir
ligne1 2524
ligne2 2525
ligne3 2526

les lignes2 et 3 ayant été insérées.

Je n'arrive pas à adapter les macros approchantes trouvées sur le forum à ce cas.(à moins que cela soit faisable avec les formules ?)
Merci de votre aide.

[QuestVba]

Bonjour

Voici un code : sépare les nombres séparés par "," et écrit dans les autres cellules

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub ExtractionNombres()
    Dim Tableau() As String
    Dim i As Integer
    x = Cells(1, 1).Value
    Tableau = Split(x, ", ")
 
    For i = 0 To UBound(Tableau)
          Cells(i + 1, 1).Value = Tableau(i)
    Next i
End Sub

[Daniel.C]

les valeurs de la colonne A sont réparties à partir de la colonne B :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub test1()
    Dim C As Range, Item As Variant, Ctr As Integer
    For Each C In Range([A1], Cells(Rows.Count, 1).End(xlUp))
        Ctr = 1
        For Each Item In Split(C.Value, ", ")
            Ctr = Ctr + 1
            Cells(C.Row, Ctr) = Item
        Next Item
    Next C
End Sub

[Leehan]

merci de vos réponses.
Le premier code fonctionne sur la premiere ligne rencontrée avec plusieures occurences dedans mais je suis incapable de reproduire le truc pour les suivantes

Le seconde separe bien les valeurs...mais en colonne or j'essaie de les avoir en ligne.

Dans la piece jointe, en feuille1 les données de départ, en feuille 2 les données que je souhaiterais à l'arrivée.
Merci

[Daniel.C]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub test1()
    Dim C As Range, Item As Variant, Ligne As Long, Plage As Range, Ctr As Integer
    Ligne = 0
    With Sheets("Feuil1")
        Set Plage = .Range(.[B1], .Cells(.Rows.Count, 2).End(xlUp))
    End With
    With Sheets("Feuil2")
        For Each C In Plage
            Ctr = C.Offset(, -1).Value
            If C.Value <> "" Then
                For Each Item In Split(C.Value, ", ")
                    Ligne = Ligne + 1
                    If Ctr <> 0 Then
                        .Cells(Ligne, 1) = Ctr
                        Ctr = 0
                    End If
                    .Cells(Ligne, 2) = Item
                Next Item
            End If
        Next C
    End With
End Sub

[QuestVba]

Bonjour,

Ou encore

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub ExtractionNombres()
    Dim Tableau() As String
    Dim i As Integer
 
    Sheets("feuil1").Activate
    Range("a1").Activate
 
    Do
 
        x = ActiveCell.Value
        Tableau = Split(x, ", ")
 
        For i = 0 To UBound(Tableau)
            ActiveCell.Value = Tableau(i)
            ActiveCell.Offset(rowoffset:=1, columnoffset:=0).Activate
            If i <> UBound(Tableau) Then Selection.EntireRow.Insert
        Next i
 
    Loop Until ActiveCell = ""
 
End Sub

[Leehan]

merci !
C'est parfait.
Ensuite, il me reste qques manip à faire pour remplir mon tableau initial qui comporte bcp plus de colonnes.
Merci encore.