Discussion :

[CaraLePoke]

Bonjour,

Je tente de copier des cellules dans un fichier 1, puis de les copier après la dernière ligne dans un autre fichier (après avoir retirer des colonnes dans ce nouveau fichier).

J'ai fait ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
'on copie les cellules du fichier A
 
macol = NumCol("Acheteur")
LigneFin = Application.WorksheetFunction.CountA(Columns(macol))
Range("2:" & LigneFin).Select
Selection.Copy
 
' On ouvre le fichier B et on y ajoute les ligne de A après l'avoir nettoyé
export = Application.GetOpenFilename("Classeurs Excel (*.xls), *.xls", 1, "Choisir le fichier d export", , False)
 
Workbooks.Open Filename:=export
export = ActiveWorkbook.Name
 
' On masque les premières ligne inutiles
Rows("1:5").Select
Selection.EntireRow.Hidden = True
 
' On efface les colonnes prix, prix unitaire
macol = NumCol("prix")
Columns(macol).Delete
macol = NumCol("prix unitaire")
Columns(macol).Delete
 
'on ajoute les lignes du fichier A à la fin du fichier B
macol = NumCol("Numéro de la commande")
LigneFin = Application.WorksheetFunction.CountA(Columns(macol))
LigMag = LigneFin + 1
 
 
Range("A" & LigMag).Select
ActiveSheet.Paste

Il me fait une erreur 1004 en disant que la méthode paste a échoué... j'ai tenté de plusieurs façon, j'ai de temps en temps une erreur 438...

Si quelqu'un voit mon erreur, je suis preneur...
D'avance merci!

P.S NumCol est une fonction qui donne le numéro de la colonne contenant le texte entré en variable dans sa première ligne.

[mercatog]

Utilise plutôt des variables objets Workbook et worksheet comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Dim MaCol As Integer, LaCol As Integer
Dim LigneFin As Long, NouvLig As Long
Dim Wbk As Workbook
Dim Sh As Worksheet
Dim Export
 
With ThisWorkbook.Worksheets("Feuil1")           'à adapter
    MaCol = NumCol("Acheteur")
    LigneFin = .Cells(.Rows.Count, MaCol).End(xlUp).Row
    ' On ouvre le fichier B et on y ajoute les ligne de A après l'avoir nettoyé
    Export = Application.GetOpenFilename("Classeurs Excel (*.xls), *.xls", 1, "Choisir le fichier d export", , False)
    If Export <> False Then
        Set Wbk = Workbooks.Open(Export)
        Set Sh = Wbk.Worksheets(1)               'Première feuille du fichier qui vien d'être ouvert
 
        ' On masque les premières ligne inutiles
        Sh.Rows("1:5").EntireRow.Hidden = True
 
        ' On efface les colonnes prix, prix unitaire
        Sh.Columns(NumCol("prix")).Delete
        Sh.Columns(NumCol("prix unitaire")).Delete
 
        'on ajoute les lignes du fichier A à la fin du fichier B
        LaCol = NumCol("Numéro de la commande")
        NouvLig = Sh.Cells(Sh.Rows.Count, LaCol).End(xlUp).Row + 1
        .Rows("2:" & LigneFin).Copy Sh.Range("A" & NouvLig)
        Set Sh = Nothing
        Wbk.Close True
        Set Wbk = Nothing
    End If
End With

[CaraLePoke]

Je suis pas à l'aise avec les workbook... je pensais que l'on pouvait s'en passer pour ça

J'ai repris ton code en mettant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With ThisWorkbook.Worksheets("Export")

Export est le nom de ma feuille...
au début pour me placer dans la bonne feuille (en partant du principe que je suis dans le workbook A et il me dt que "l'indice n'appartient pas à la selection).
J'ai aussi essayé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With Workbook.Name(syst).Worksheets("Export")

syst étant la variable ou j'ai sauvé le nom de mon workbook
sans succès...
comment je m'assure d'avoir le bon workbook?

[mercatog]

Explique nous la disposition de tes fichiers. notamment le nom de la feuille de ton fichier contenant la macro et le nom de la feuille du classeur ouvert.

Je suis pas à l'aise avec les workbook

C'est le moment de retrousser les manches. Plus tard tu sauras que ce n'est pas la mer à boire et qu'ainsi tu n'auras aucun souci de savoir quel est le classeur actif.

[CaraLePoke]

Mon fichier qui contient les macro s'appelle SysAjout avec une feuille contenant des boutons avec plusieurs macros.

J'ai sauvé le nom de mon fichier A dans syst et la feuille où sont les lignes à copier s'appelle Export. J'ouvre un fichier B dans lequel je doit copier (après la dernière ligne de la première feuille). Tous les fichiers sont dans le même dossier au même niveau.

[CaraLePoke]

J4ai réussi à retrouver mon workbook comme ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With Workbooks(syst).Worksheets("ExportImprimeur")

j'ai été idiot de vouloir faire un .name -_- et j'avais oublié le s à la fin de workbooks