Discussion :

[mickniclln]

Bonjour,

J'ai un fichier XML du genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
<cours>
  <id>c1</id>
  <departement>d1</departement>
  <groupe>g1</groupe>
</cours>
<cours>
  <id>c2</id>
  <departement>d1</departement>
  <groupe>g1</groupe>
</cours>
<cours>
  <id>c3</id>
  <departement>d1</departement>
  <groupe>g2</departement>
</cours>
<cours>
  <id>c4</id>
  <departement>d2</departement>
  <groupe>g3</groupe>
</cours>
.....

Je voudrais a partir de ces infos afficher une liste qui reprend les groupes et les département. Cela doit donner quelque chose du genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
d1
  g1
  g2
d2
  g3

J'arrive a afficher les departements via un for-each-group mais pas a y associer les groupes.

Est ce que quelqu'un aurait la gentillesse de m'aider?

Merci

Mickael

[mickniclln]

Personne ne sait m'aider??

[tsuji]

Cela peut s'achever, si vous voulez, avec deux clés et un template d'ou le nom de l'element à matcher est le parent des "cours". Mais son nom n'est pas connu parce que vous n'avez pas montré dont j'y ai mis *[cours] qui peut paraître un peu cryptique mais qu'il reste marcher tout à fait.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
<xsl:key name="depgpliste" match="cours" use="concat(departement, '#', groupe)" />
<xsl:key name="depliste" match="cours" use="departement" />
 
<xsl:template match="*[cours]">
    <ul>
    <xsl:for-each select="cours[generate-id()=generate-id(key('depliste',departement)[1])]">
        <xsl:sort select="departement" />
        <li>
        <xsl:value-of select="departement" />
            <ul>
            <xsl:for-each select="../cours[
                generate-id()
                =
                generate-id(
                    key('depgpliste',concat(current()/departement,'#',groupe))[1]
                )
            ]">
                <li>
                <xsl:value-of select="groupe" />
                </li>
            </xsl:for-each>
            </ul>
        </li>
        </xsl:for-each>
    </ul>
</xsl:template>

[tsuji]

Je viens de voir ça:

J'arrive a afficher les departements via un for-each-group mais pas a y associer les groupes.

Si vous voulez utiliser xslt 2.0 stricte, ainsi ne plus soutenir xslt 1.0, avec des éléments comme xsl:for-each-group, on peut faire comme ça.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
<xsl:template match="*[cours]">
    <ul>
    <xsl:for-each-group select="cours" group-by="departement">
        <xsl:sort select="departement" />
        <li>
            <xsl:value-of select="departement" />
            <ul>
            <xsl:for-each-group select="../cours[departement=current()/departement]" group-by="groupe">
                <li>
                    <xsl:value-of select="groupe" />
                </li>
            </xsl:for-each-group>
            </ul>
        </li>
    </xsl:for-each-group>
    </ul>
</xsl:template>

ou quelque variant de ça.

[mickniclln]

Super, cela fonctionne

Grand merci

Mickael

[thelvin]

On pouvait quand même remplacer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

select="../cours[departement=current()/departement]"

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

select="current-group()"

C'est fait pour, après tout -_-°.

[tsuji]

par

Code :Sélectionner tout - Visualiser dans une fenêtre à part
select="current-group()"

C'est fait pour, après tout -_-°.

C'est vrai et c'est plus v2.0-iste. Merci pour en noter. J'étais trop m'en préoccupé de faire passer avec continuité de v1.0 à v2.0... Voici un re-liste de cette variation.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
<xsl:template match="*[cours]">
    <ul>
    <xsl:for-each-group select="cours" group-by="departement">
        <xsl:sort select="departement" />
        <li>
            <xsl:value-of select="departement" />
            <ul>
            <xsl:for-each-group select="current-group()" group-by="groupe">
                <li>
                    <xsl:value-of select="groupe" />
                </li>
            </xsl:for-each-group>
            </ul>
        </li>
    </xsl:for-each-group>
    </ul>
</xsl:template>