Discussion :

[toto92]

Bonjour
j'execute : 1 macro Access + macro Excel + 1 macro Access : ce n'est pas tres joli mais ca marche et je me demande s'il est possible de tout faire avec une seule requete SQL ACCESS ?

il s'agit de relever le chiffre dans colonne C ( colonne "SAP Qty" dans "Exemple_SAP.xlsx" ) : Si zero ou 1 : Ne rien faire mais si > 1 : Dupliquer la ligne ( colonne A + colonne B + colonne C ) en autant de fois et avec incrementation dans colonne "no d'ordre" ( si possible sur 3 chiffres comme 001 002 003 etc.. )

Voir le resultat souhaité dans "Resultat_SAP.xlsx"

Je signale que mon macro Excel me permet d'obtenir le resultat voulu en partant de la derniere ligne mais je ne sais pas si la requete SQL fait pareil ?

si pas possible de faire une telle requete SQL : est il possible d'executer macro Excel à partir d1 macro ACCESS ( car je voudrais tout faire d'un seul clci )

je suis sous win 7 et Office 2010

Merci et bonne Année !

[f-leb]

Bonjour,

une petite procédure qui va piocher dans la table SAP([SAP Fixed Asset], [no d'ordre], [SAP Qty]) et donner le résultat dans la table SAP_resultat.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Public Sub resultat()
Dim strSQL As String
Dim rst As DAO.Recordset
Dim rst_resultat As DAO.Recordset
Dim i As Integer
 
' recopier les lignes pour [SAP Qty] <=1
CurrentDb.Execute "INSERT INTO SAP_Resultat ([SAP Fixed Asset], [no d'ordre], [SAP Qty]) " & _
                " SELECT [SAP Fixed Asset], [no d'ordre], [SAP Qty] FROM SAP " & _
                " WHERE [SAP Qty]<=1", dbFailOnError
 
 
strSQL = "SELECT [SAP Fixed Asset], [no d'ordre], [SAP Qty] FROM SAP " & _
                " WHERE [SAP Qty]>1" ' on récupère les lignes avec [SAP Qty]>1
Set rst = CurrentDb.OpenRecordset(strSQL)
Set rst_resultat = CurrentDb.OpenRecordset("SAP_Resultat")
 
 
With rst
    .MoveFirst
    While Not .EOF
        For i = 1 To .Fields("[SAP Qty]") ' on boucle sur [SAP Qty]
            rst_resultat.AddNew
            rst_resultat.Fields("[SAP Fixed Asset]") = .Fields("[SAP Fixed Asset]")
            rst_resultat.Fields("[no d'ordre]") = Format(i, "000")
            rst_resultat.Fields("[SAP Qty]") = .Fields("[SAP Qty]")
            rst_resultat.Update
        Next
        .MoveNext
    Wend
End With
 
rst.Close
Set rst = Nothing
rst_resultat.Close
Set rst_resultat = Nothing
 
End Sub

[toto92]

Desolé mais ca ne marche pas !
1) C'est à creer avec icone MODULE ou VISUAL BASIC sous ACCESS ? ( quelle difference entre les 2 ? )
2) "SAP_Resultat" doit-elle etre une table à l interieur d'une base de données ou un fichier exterieur de cette base de données ( et à quel format ? )

Merci !

[f-leb]

bonsoir,

1) à coller dans un module.

2) oui, je suis parti de deux tables dans la bdd: SAP_Resultat ([SAP Fixed Asset], [no d'ordre], [SAP Qty]) et SAP([SAP Fixed Asset], [no d'ordre], [SAP Qty])