Discussion :

[Plc8919]

Bonjour,

J'ai un problème, j'ai besoin de comparer les valeurs contenues dans une colonne afin de voir si elles sont dans une deuxième colonne.

Si la valeur de la première colonne est dans la deuxième colonne alors on inscrit "OK" dans la troisième colonne, autrement on inscrit "aucune référence".

Voir photo en PJ.

Ma macro que j'ai tenté de réaliser ne marche pas.

Ma macro:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub comparaison_colonnes2()
Dim i As Long, e As Long
 
   Worksheets("Feuil1").Activate
 
    For i = 2 To Range("A2").End(xlDown).Row
        For e = 2 To Range("B2").End(xlDown).Row
            If Cells(i, 1).Value = Cells(e, 2).Value Then
            Cells(e, 2).Offset(0, 1).Value = "OK"
            Else
            Cells(e, 2).Offset(0, 1).Value = "aucune référence"
            End If
        Next e
    Next i
End Sub

Si quelqu'un peut m'aider svp.

[QuestVba]

Bonjour
avec ce code (pour trois lignes)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub comparaison()
'
Dim VALEURA As String, VALEURB As String
'
For i = 1 To 3
VALEURB = Range("b" & i).Value
For j = 1 To 3
VALEURA = Range("A" & j).Value
If VALEURA = VALEURB Then
Range("c" & j).Value = "ok"
Else: Range("c" & j).Value = "aucune référence"
End If
Next j
Next i
End Sub

[Plc8919]

Bonjour,

J'ai testé votre code mais j'obtiens le même résultat qu'avec ma propre macro, voir fichier en PJ.

Par exemple en deuxième ligne il me met aucune référence alors que dans la deuxième colonne il y a bien la référence "P24585"... Je comprends pas pourquoi.. Normalement il ne devrait y avoir que la première ligne en "aucune référence".

[AlainTech]

Bonjour,

Une autre piste:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Sub Comparaison()
 
  Dim c As Range
  Dim cFound As Range
  Dim rPcode As Range
  Dim rAlertes As Range
  Dim wks As Worksheet
 
  Set wks = ThisWorkbook.Sheets(1) ' A adapter
  Set rPcode = Range(wks.Cells(2, 1), wks.Cells(wks.Rows.Count, 1).End(xlUp)) ' Colonne 1
  Set rAlertes = Range(wks.Cells(2, 2), wks.Cells(wks.Rows.Count, 2).End(xlUp)) ' Colonne 2
  For Each c In rPcode
    Set cFound = rAlertes.Find(what:=c.Value, lookat:=xlWhole)
    If cFound Is Nothing Then
      c.Offset(0, 2) = "aucune référence"
    Else
      c.Offset(0, 2) = "OK"
    End If
  Next c
End Sub

[Plc8919]

Merci beaucoup Alain Gerard pour votre réponse, cela fonctionne parfaitement bien !

Je passe le sujet en résolé.

Bon wk!