Discussion :

[AbsolutAlex]

Bonjour tout le monde,

Tout d'abord je tiens à préciser que j'ai pas mal parcouru le forum sans trouver quelques choses pour m'aider.

Mon problème est le suivant :

Je voudrais calculer le nombre d'occurrence différente contenant une information.

Donc pour calculer le nombre d'occurrence contenant l'information en question je fais :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI(Infos!K2:K23341;"*" & C7 & "*")

J'obtiens le bon résultat. Mais ensuite lorsque je veux calculer le nombre d'occurrence différente, je n'y arrive pas. J'ai essayé la solution suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS(Infos!K2:K23341;"*" & C7 & "*";Infos!K2:K23341;Infos!K2:K23341)

Avec ou sans formule matricielle, ça ne fonctionne pas. J'ai essayé avec un SOMME ou un SOMMEPROD, ça ne fonctionne pas non plus.

Pour infos, il n'y a pas de cellule vide dans la colonne K.

En espérant que vous pourrez m'aider.

Bon week-end.

Alex

[hben1961]

Bonjour à tous,

Un essai avec la formule matricielle suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(1/NB.SI(Infos!$K$2:$K$23341;Infos!$K$2:$K$23341))

NB: Il faut qu'il n'y ait pas de cellules vides dans la plage Infos!$K$2:$K$23341

Cordialement

[hben1961]

Bonjour à tous,

Une autre solution pour compter les occurences différentes dans une plage ne tenant pas compte des cellules vides ou contenant du texte:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SI(FREQUENCE(Infos!$K$2:$K$23341;Infos!$K$2:$K$23341)>0;1))

Et c'est une formule matricielle à valider par : CTRL+MAJ+ENTREE

Cordialement

[papouclo]

Bonjour,
Les formules de hbnen1961 (j'en suis sûr pour la première et merci pour la seconde) donnent le nombre d'occurrences distinctes de la plage $K2 : $K23341,
qu'elles contiennent l'information précisée en C7 ou non.
Or d'après la seconde formule qu' AbsolutAlex a essayée, je pense qu'il s'agit du nombre d'occurrences distinctes mais contenant l'information précisée en C7.
J'essayerais la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD ((1-ESTERR(CHERCHE(C7; $K2 : $K23341)))/NB.SI( $K2 : $K23341 ; $K2 : $K23341))

Cordialement
Claude

[AbsolutAlex]

Bonjour à tous,

Merci papouclo. En effet, j'ai oublié de le préciser dans mon post mais la valeur que je voulais rechercher était belle et bien dans la cellule C7. J'ai juste modifier un petit peu la formule que tu me donnes, car je veux savoir le nombre d'occurrence qui contienne la valeur de C7 et non pas le nombre d'occurrence qui sont égales à C7.

La formule finale est donc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD ((1-ESTERR(CHERCHE("*" & C7 & "*";Infos!$K$2:$K$23341)))/NB.SI(Infos!$K2:$K$23341;Infos!$K$2:$K$23341))

Mais mon PC étant tellement puissant, la formule met une 10aine de minutes à être calculée. Donc c'est même pas la peine d'espérer en calculer une dizaine d'un coup. Je vais donc passer par une macro...

Encore merci à papouclo et hben1961 !

Alex

[GerardCalc]

Bonjour,

Bonjour à tous,

Merci papouclo. En effet, j'ai oublié de le préciser dans mon post mais la valeur que je voulais rechercher était belle et bien dans la cellule C7. J'ai juste modifier un petit peu la formule que tu me donnes, car je veux savoir le nombre d'occurrence qui contienne la valeur de C7 et non pas le nombre d'occurrence qui sont égales à C7.

La formule finale est donc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD ((1-ESTERR(CHERCHE("*" & C7 & "*";Infos!$K$2:$K$23341)))/NB.SI(Infos!$K2:$K$23341;Infos!$K$2:$K$23341))

Inutile de rajouter "*"&"*", la formule de papoucho donne bien le nombre d'occurrences contenant C7. C'est tout l'intérêt de la fonction CHERCHE.

A+