Discussion :

[Thierry360]

Bonjour,

Je souhaite faire un graphique à partir d'une série de données dont la taille peut évoluer.
Après quelques recherche j'ai trouvé comme faire un graphique dynamique (sur un forum voisin).

SA :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(indicateurs!$B$2;0;0;1;NB(indicateurs!$2:$2))

Dates :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(indicateurs!$B$1;0;0;1;NB(indicateurs!$2:$2))

Graphique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SERIE(indicateurs!$A$2;'Nom du fichier.xls'!Dates;'Nom du fichier.xls'!SA;1)

Cela fonctionne très bien mais ne prend pas en compte le faire que le nom du fichier peut évoluer.

J'ai donc obtenu le nom du fichier courant dans une cellule renommée "nom_fichier" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=STXT(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1))+1;SOMME(TROUVE({"[";"]"};CELLULE("filename";A1))*{-1;1})-1)

J'insère cette référence "nom_fichier" dans la fonction du graphique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SERIE(indicateurs!$A$2;nom_fichier!Dates;nom_fichier!SA;1)

Mais cela génère une erreur :

Référence non valide. La référence doit renvoyer à une feuille de calcul ouverte

Je suppose qu'il me manque un élément pour faire référence au nom du fichier directement ?

Pourriez-vous m'aiguiller s'il vous plait ?

[mercatog]

1. Nommes par Dates (de portée feuilles: Dans le gestionnaire de noms, choisi dans la liste Zone, la feuille indicateurs)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(indicateurs!$B$1;0;0;1;NB(indicateurs!$2:$2))

2. Nommes par SF de la même manière

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(indicateurs!Dates;1;0)

Enfin, dans ta série, tu n'auras pas besoin du nom du classeur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SERIE(indicateurs!$A$2;indicateurs!Dates;indicateurs!SF;1)

[Thierry360]

Je te remercie pour ta réponse rapide.

J'ai repris ces fonctions mais dans la fonction du graphique la dernière référence (indicateurs!SF) est systématiquement remplacée par le nom du fichier quand on valide la formule .

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SERIE(indicateurs!$A$2;indicateurs!Dates;indicateurs!SF;1)

Autre problème : quand je n'ai plus aucune données (ni intitulés ni valeurs), excel génère une erreur :

une des formules de cette feuille de calcul contient une ou plusieurs références externes non valides.

[mercatog]

1. Pour éviter l'erreur quand aucune donnée, remplace la définition du nom Dates par celui ci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(Indicateurs!$B$1;0;0;;MAX(NB(Indicateurs!$2:$2);1))

SF reste le même

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(Indicateurs!Dates;1;0)

Pour la question de la portée des noms, regardes la figure ci-après

[Thierry360]

Oh, j'avais bien défini la zone pour l'un des noms mais pas pour l'autre ! Une fois cela redéfini correctement je n'ai plus eu de problème de référence au nom du fichier courant .
La fonction MAX fonctionne parfaitement pour gérer le cas de l'absence de valeurs .

Merci beaucoup mercatog !