Afficher certaines feuilles selon mot de passe saisi

**NEC14** · 24/01/2013, 16h43

Bonjour à tous,

J'essaie de mettre en place un UserForm où l'on pourra saisir un identifiant et un mot de passe.
Selon l'identifiant seul un certain nombre de feuille doivent être affichée.
L'identifiant correspond à un numéro se trouvant dans la feuille Recap et dans les cellules H2:H32.
Par exemple, si l'identifiant est 1300, alors seule les feuilles qui correspondent à ce code doivent être affichée.
Comment puis-je procéder ? Quelqu'un a-t'il déjà fait quelque chose de similaire ?
Merci par avance pour votre aide
René

**enernaej** · 24/01/2013, 17h02

Bonjour,

Je suppose que dans la feuille Recap il y a plusieurs informations :
- identifiant
- mot de passe
- liste des feuilles à afficher

Donc la première opération est de cacher les feuilles sauf une

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

  Sheet("nom_de_la_feuille").Visible = xlSheetVeryHidden

Ensuite d'afficher le formulaire et si la saisie est valide alors afficher la liste des feuilles par des

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

  Sheet("nom_de_la_feuille").Visible = xlSheetVisible

Et s'il y a un bouton de déconnexion, il faudra recacher ces feuilles.

**NEC14** · 25/01/2013, 08h36

Bonjour,

Je joins un fichier avec quelques explications, et une partie du code que j'ai commencé.
Merci par avance pour votre aide

A l'initialisation de l'UserForm

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
Private Sub UserForm_Initialize()
Dim WS As Worksheet
    With Me
    .Caption = T
    .Txb_Pwd_Util.PasswordChar = "*"
    End With
 
    For Each WS In Worksheets
        If WS.Name <> "Accueil" Then
            WS.Visible = xlSheetVeryHidden
        End If
    Next
End Sub

Lorsque l'on clique sur OK après avoir taper l'identifiant et mot de passe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
Private Sub Cmd_Ok_Btn_Click()
Dim Rech As Range
Dim MonParametre As Byte
Static TentativePW As Byte, TentativeID As Byte
 
    If Txb_ID_Util = Empty Then End
 
    Set Rech = Range("Users").Find(Txb_ID_Util, LookIn:=xlValues, Lookat:=xlWhole)
        If Not Rech Is Nothing Then
 
            If Txb_Pwd_Util = Rech.Offset(0, 1) Then
                MonParametre = Rech.Offset(0, 2)
                MaMacro MonParametre 'Ici passage de paramètres "Niveau"
            Else
                TentativePW = TentativePW + 1 'Ici on calcule le nombre de tentative pour le mot de passe,
                    If TentativePW > 3 Then ThisWorkbook.Close 0  'si supérieure à 3 alors le classeur se ferme
                MsgBox "Mot de passe invalide, Tentative n° " & TentativePW & " sur 3 ", vbCritical, T 'Ici on indique le nombre de tentative
                    With Me.Txb_Pwd_Util
                .Value = ""
                .SetFocus
                    End With
                End If
 
            Else
                TentativeID = TentativeID + 1 'Ici on calcule le nombre de tentative pour l'identifiant,
                    If TentativeID > 3 Then ThisWorkbook.Close 0
                MsgBox "Utilisateur inconnu, , Tentative n° " & TentativeID & " sur 3 ", vbCritical, T
 
                    With Me.Txb_ID_Util
                .SetFocus
                .SelStart = 0
                .SelLength = Len(Me.Txb_ID_Util.Text)
                    End With
                    End If
End Sub

Appel de la macro "MaMacro" et c'est là que je ne sais plus faire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
 
Private Sub MaMacro(Niveau As Byte)
    Select Case Niveau
    Case 1, 2, 3
 
        With Niv1
        .Visible = True
            ActiveWindow.WindowState = xlMaximized
        .Activate
        End With
 
        With Niv2
        .Visible = True
            ActiveWindow.WindowState = xlMaximized
        .Activate
        End With
 
        With Niv3
        .Visible = True
            ActiveWindow.WindowState = xlMaximized
        .Activate
        End With
 
 
        End Select
End Sub

**enernaej** · 25/01/2013, 11h03

Bonjour,

Même s'il semble y avoir un doublon entre le niveau et le mot de passe, on devrait avoir quelque chose de la forme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Private Sub MaMacro(Niveau As Byte)
  Dim WS As Worksheet
  dim indexLigne as Integer
 
    Select Case Niveau
    Case 1
      For indexLigne = 2 To Sheets("Recap").range("A1").end(xldown).row
         If Sheets("Recap").Cells(indexLigne, 8) = 1320 Then
           Sheets(Sheets("Recap").Cells(indexLigne, 1)).Visible = xlSheetVisible
         End If
      Next
 
    case 2
      For indexLigne = 2 To Sheets("Recap").range("A1").end(xldown).row
         If Sheets("Recap").Cells(indexLigne, 8) = 1330 Then
           Sheets(Sheets("Recap").Cells(indexLigne, 1)).Visible = xlSheetVisible
         End If
      Next
 
    case 3
       For Each WS In Worksheets
         WS.Visible = xlSheetVisible
      Next
 
  End Select
End Sub

Voilà une idée à travailler.

**NEC14** · 25/01/2013, 11h19

Merci beaucoup, je mets tout cela en place et je vous tiens au courant

**Oliv-** · 25/01/2013, 12h17

Salut,
Masquer n'est pas suffisant car certains utilitaires comme "excel utilities" (de rob bovey) permettent d'afficher toutes les feuilles masquées.

Regarde ici une couche supplémentaire

**Schat6903** · 25/01/2013, 14h47

Pour ma part j'ai créé un classeur "sécurisé" qui demande un mot de passe pour les admins et dans ce cas affiche toutes les feuilles.
pour vérifier si le mdp est correct j'utilise un API qui compare le mdp rentré à celui du réseau, comme ça pas besoin de stocker de mdp ni de le crypter.
Par défaut les feuilles sont invisibles, elles ne deviennent visibles que si l'user à le droit d'accès

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
Public Sub ControlLogin()
 
    Dim hideFeuil() As String
    Dim xlApp As Excel.Application
    Dim xlSheet As Excel.Worksheet
    Dim idUser As String
    Dim accesTabAdmin() As Variant, accesTabUser As Variant
    Dim I As Integer, iBis As Integer, Y As Integer
    Set xlApp = Excel.Application
    'Protection des feuilles
    For Each ws In ThisWorkbook.Worksheets
        ws.Protect
    Next ws
    'Creation d'un tableau contenant le nom des feuilles
    ReDim hideFeuil(1 To ThisWorkbook.Worksheets.Count)
 
    For Y = 1 To ThisWorkbook.Worksheets.Count
        hideFeuil(Y) = ThisWorkbook.Worksheets(Y).Name
    Next Y
 
    Set xlSheet = Sheets("GestionAcces") 'Feuille contenant les LOGIN autorisés
 
    I = xlSheet.Range("a65536").End(xlUp).Row 'Dans la colonne A : liste des Admin
    iBis = xlSheet.Range("B65536").End(xlUp).Row 'Dans la colonne B : liste des Users simple
 
    'Récupération de l'ID de l'utilisateur connecté
    idUser = Environ("USERNAME")
 
    'dimensionnement d'un tableau contenant les log des admin
    ReDim accesTabAdmin(1 To I - 1)
    For X = 1 To I - 1
        accesTabAdmin(X) = xlSheet.Range("a" & X + 1).Value
    Next X
 
    For X = LBound(accesTabAdmin) To UBound(accesTabAdmin)
        'comparaison de l'ID connecté au tableau des admin
        'si l'ID est == , accès total au fichier
        If idUser = accesTabAdmin(X) Then
            MdPForm.Show
            If UserCheckPassword(idUser, MdPForm.motDP.Value) = True Then 'Demande du mot de passe réseau
                MdPForm.motDP.Value = ""
                Worksheets("Start").Activate
                MsgBox "Accès total au fichier" & Chr(10) & "Attention à ne pas modifier les paramètres involontairement", vbInformation, "Contrôle d'accès"
 
                'Affichage de toutes les feuilles pour les admins
                For Y = 1 To UBound(hideFeuil)
                    Sheets(hideFeuil(Y)).Visible = True
                Next Y
                Sheets("Alerte").Visible = False
            Else
                MsgBox "mauvais mot de passe, fermeture du fichier"
                Set xlSheet = Nothing
                xlApp.Quit
                Set xlApp = Nothing
            End If
            Exit Sub
        End If
    Next X
 
    'sinon on dimensionne un tableau qui récupère la liste des Users
    ReDim accesTabUser(1 To iBis - 1)
    For X = 1 To iBis - 1
        accesTabUser(X) = xlSheet.Range("B" & X + 1).Value
    Next X
 
    For X = LBound(accesTabUser) To UBound(accesTabUser)
        'si l'ID connecté == , accès en tant que Users
        If idUser = accesTabUser(X) Then
            Worksheets("Start").Activate
 
            'Affichage des sheets accessible pour les users (Pas toutes les feuilles, seul la feuille 1 et 2)
            For Y = 1 To 2
                Sheets(hideFeuil(Y)).Visible = True
            Next Y
            Sheets("Alerte").Visible = False
            Exit Sub
        End If
    Next X
 
    'sinon affichage du form d'info et fermeture de l'appli
    BoxInformation.Show
    xlApp.DisplayAlerts = False
    ThisWorkbook.Save
    xlApp.Quit
End Sub
 
'Purpose   :    Checks if a the NT password for a user is correct.
'Inputs    :    UserName                The username
'               Password                The password
'               [Domain]                If DOMAIN is omitted uses the local account database.
'Outputs   :    Returns True if the password and user name are valid.
'Notes     :    Windows NT and 2000 ONLY. Requires correct permissions to run (must have
'               the SE_TCB_NAME privilege. In User Manager, this is the "Act as part of the
'               Operating System" right).
 
Function UserCheckPassword(ByVal Username As String, ByVal Password As String, Optional ByVal Domain As String = vbNullString) As Boolean
    Dim lRet As Long, hToken As Long
 
    Const LOGON32_LOGON_NETWORK = 3&            'Intended for high performance servers to authenticate clear text passwords
    Const LOGON32_LOGON_INTERACTIVE = 2&        'Intended for users who will be interactively using the machine, such as a user being logged on by a terminal server
    Const LOGON32_LOGON_BATCH = 4&
 
    Const LOGON32_PROVIDER_DEFAULT = 0&         'Use the standard logon provider for the system
    Const LOGON32_PROVIDER_WINNT40 = 2&         'Use the Windows NT 4.0 logon provider
    Const LOGON32_PROVIDER_WINNT35 = 1&         'Use the Windows NT 3.5 logon provider
    Const LOGON32_PROVIDER_WINNT50 = 3&         'Use the Windows 2000 logon provider.
 
    'Check the username and password
    lRet = LogonUser(Username, Domain, Password, LOGON32_LOGON_NETWORK, LOGON32_PROVIDER_DEFAULT, hToken)
 
    If lRet Then
        'Password correct
        UserCheckPassword = True
        CloseHandle hToken
    'Else
        'Failed:
        'MsgBox "Error: " & DLLErrorText(Err.LastDllError)
    End If
End Function

J'espère que dans ce fouillis (je ne suis qu'un '"débutant" autodidacte qui à des progrès à faire dans l'arrangement du codage) tu trouveras quelque chose qui t'aide

**Oliv-** · 25/01/2013, 15h30

Teste donc ce code à partir d'un classeur quelconque mais avec ton fichier protégé ouvert dans la même session Excel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub montrer_les_feuilles_cachees()
    For Each wk In Application.Workbooks
        For Each sh In wk.Sheets
            If Not sh.Visible Then sh.Visible = True
        Next sh
    Next wk
End Sub

**NEC14** · 28/01/2013, 09h06

Bonjour à tous,

Merci pour vos réponses et suggestions. Beaucoup d'info pour un Lundi matin.
Je vais essayer de comprendre tout ça et voir comment je peux l'appliquer à mes besoins.

Dès que j'aurai terminé, je vous informe du résultat.

Encore merci pour votre aide

René

**NEC14** · 20/02/2013, 14h31

Bonjour,

J'ai mis le code en place, mais j'ai des messages d'erreur et cela ne fonctionne pas correctement.
Par exemple la saisie du mot de passe va au-delà de 3 essais et je n'arrive pas à afficher mes feuilles.

Voir le fichier joint

**Oliv-** · 20/02/2013, 15h57

en gras si je n'ai rien oublié les corrections

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
'Convention des libellés
' - Cmd = Boutons de commande
' - Txb = Zones de texte


Option Explicit
Const T As String = "Saisissez vos indentifiants"
Private Sub Cmb_Exit_Click()
    Unload Me
End Sub

Private Sub CmbOk_Click()
    Dim Rech As Range
    Dim MonParametre As Byte
    Static TentativePW As Byte, TentativeID As Byte

    If Me.Txb_ID_Util = Empty Then End

    Set Rech = Range("Users").Find(Me.Txb_ID_Util, LookIn:=xlValues, LookAt:=xlWhole)
    If Not Rech Is Nothing Then

        If Me.Txb_Pwd_Util = CStr(Rech.Offset(0, 1)) Then
            MonParametre = Rech.Offset(0, 2)
            MaMacro MonParametre    'ici passage de paramètre "Niveau"
            Unload Me
        Else
            TentativePW = TentativePW + 1    'Ici on calcule le nombre de tentative pour le mot de passe
            If TentativePW > 3 Then
                Unload Me    'Si plus de 3 tentative, l'UF se ferme
            Else

                MsgBox "Mot de passe invalide, tentative n°" & TentativePW & "sur 3", vbCritical, T    'ici on indique le nombre de tentative

                With Me.Txb_Pwd_Util
                    .Value = ""
                    .SetFocus
                End With
            End If
        End If

    Else

        TentativeID = TentativeID + 1    'Ici on calcule le nombre de tentative pour l'identifiant
        If TentativeID > 3 Then
            Unload Me
        Else
            MsgBox "Utilisateur inconnu, , tentative n°" & TentativeID & " sur 3", vbCritical, T

            With Me.Txb_ID_Util
                .SetFocus
                .SelStart = 0
                .SelLength = Len(Me.Txb_ID_Util.Text)
            End With
        End If
    End If

End Sub

Private Sub UserForm_Activate()
    Me.Txb_ID_Util.SetFocus
End Sub

Private Sub UserForm_Initialize()
    Dim WS As Worksheet
    With Me
        .Caption = T
        .Txb_Pwd_Util.PasswordChar = "*"
    End With

    For Each WS In Worksheets
        If WS.Name <> "Accueil" Then
            WS.Visible = xlSheetVeryHidden
        End If
    Next
End Sub

Private Sub MaMacro(Niveau As Byte)
    Dim WS As Worksheet
    Dim IndexLigne As Integer
    On Error Resume Next
    Select Case Niveau
    Case 1
        For IndexLigne = 2 To Sheets("Recap").Range("A1").End(xlDown).Row
            If Sheets("Recap").Cells(IndexLigne, 8) = 1320 Then
                Sheets(Sheets("Recap").Cells(IndexLigne, 1).Value).Visible = xlSheetVisible
            End If
        Next

    Case 2
        For IndexLigne = 2 To Sheets("Recap").Range("A1").End(xlDown).Row
            If Sheets("Recap").Cells(IndexLigne, 8) = 1330 Then
                Sheets(Sheets("Recap").Cells(IndexLigne, 1).Value).Visible = xlSheetVisible
            End If
        Next

    Case 3
        For Each WS In Worksheets
            WS.Visible = xlSheetVisible

        Next
    End Select

End Sub

ton code ne peut fonctionner correctement que si tu masques tes feuilles en quittant, car si on ouvre san activer els macros on peut tout voir

**NEC14** · 20/02/2013, 16h28

Bonjour Oliv et merci beaucoup,

Ton aide me permet d'avancer. Cependant, quel que soit le mot de passe se sont toujours les mêmes feuilles qui sont affichées.
Je ne comprends pas.

Afficher certaines feuilles selon mot de passe saisi

Macros et VBA Excel

Discussions similaires

Partager

Partager