Discussion :

[jfox]

Bonjour,

j'ai un tableau contenant plusieurs colonnes, chaque colonne contenant un nombre variable de cellules non vides.
J'utilise la formule matricielle suivante pour déterminer la dernière cellule non vide de chaque colonne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

{=ADRESSE(MAX(EQUIV(9^9;A:A);EQUIV("zzz";A:A));1)}

Je voudrais pouvoir utiliser le résultat de cette formule matricielle dans une autre formule mais je n'y parviens pas. Par exemple, si le résultat est $A$63 (stocké dans la cellule B1 par exemple) pouvoir saisir (en B2 par exemple) =NBVAL(A3:<valeur dans B1>)
Merci pour votre aide.

[papouclo]

Bonjour,
L'adresse de la dernière cellule non vide de la colonne A étant en B1, on peut écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NBVAL(A3:INDIRECT(B1))

Si d'une part on veut écrire cette formule sans l'utilisation d'une cellule intermédiaire et d'autre part l'adresse de la dernière cellule non vide de la colonne A est obtenue par la formule matricielle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

{=ADRESSE(MAX(EQUIV(9^9;A:A);EQUIV("zzz";A:A));1)}

on peut écrire directement la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NBVAL( A3:INDIRECT(ADRESSE(MAX(EQUIV(9^9;A:A);EQUIV("zzz";A:A));1))

à valider par ctrl + maj + entrée.
Remarque : Si les valeurs non numériques de la colonne A sont du "texte sensé" la formule indiquée dans le 1er message remplit son rôle mais, en toute rigueur,
s'il y a une dernière cellule dans la colonne A contenant le texte "zzza", elle ne sera pas repérée par cette formule.
Il vaut mieux utiliser la formule matricielle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ADRESSE(MAX(LIGNE(A:A)*(A:A<>""));1)

à valider par ctrl + maj + entrée.
Cordialement
Claude

[jfox]

Merci beaucoup Claude, c'est exactement ce que je voulais.
Bonne journée.