Discussion :

[Gabout]

Bonjour,

J'essaie de convertir une cellule contenant une durée en format texte du genre 1(h) 26(m) 35(s) en secondes.

J'ai écrit un bout de code (voir ci-dessous). Ce code fonctionne sauf lorsque je dépasse 9(h) ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
'---------------------------------------------------------------------------------------
' Procédure : ConversionSecondes
' Auteur    : Jean-Pierre
' Date      : 08/02/2013
' Objet     : Conversion d'une donnée de type 1(h) 26(m) 30(s) en secondes
'---------------------------------------------------------------------------------------
Public Function ConversionSecondes(strDuree As String) As Long
  Dim bytPosh     As Byte       ' position de lecture de la parenthèse ouvrante des heures
  Dim bytPosm     As Byte       ' position de lecture de la parenthèse ouvrante des minutes
  Dim intHeures   As Integer    ' nombre d'heures
  Dim bytMinutes  As Byte       ' nombre de minutes
  Dim bytSecondes As Byte       ' nombre de secondes
  bytPosh = InStr(strDuree, "(h)")
  intHeures = CInt(Left(strDuree, bytPosh - 1))
  bytPosm = InStr(strDuree, "(m)")
  Select Case bytPosm - bytPosh
    Case 5: bytMinutes = CByte(Mid(strDuree, bytPosm - 1, 1))
    Case 6: bytMinutes = CByte(Mid(strDuree, bytPosm - 2, 2))
  End Select
  bytSecondes = CByte(Mid(strDuree, Len(strDuree) - 4, 2))
  ConversionSecondes = CLng((intHeures * 3600) + (bytMinutes * 60) + bytSecondes)
End Function

Avez-vous une idée ?

[edelweisseric]

Bonjour à tous
Bonjour Gabout

Perso j'aurai écris cela :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Option Explicit
 
Dim mavar() As String
Dim heure As Integer
Dim minute As Integer
Dim seconde As Integer
Dim nb_seconde As Long
 
Sub nombre_seconde()
mavar = Split(Range("B6"), " ")
heure = Mid(mavar(0), 1, InStr(mavar(0), "(") - 1)
minute = Mid(mavar(1), 1, InStr(mavar(1), "(") - 1)
seconde = Mid(mavar(2), 1, InStr(mavar(2), "(") - 1)
nb_seconde = (heure * 3600) + (minute * 60) + seconde
End Sub

mais il y a certainement mieux.
Tout dépend ce que tu veux faire après

Eric

[gFZT82]

Bonjour,

Tu dépasses la valeur maximale pour un entier (32767) pour la conversion des heures.
En changeant le type de tes variables, cela devrait passer.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
  Dim intHeures   As Long    ' nombre d'heures
  Dim bytMinutes  As Integer       ' nombre de minutes
  Dim bytSecondes As Integer       ' nombre de secondes

Cordialement.

[Gabout]

Bonjour edelweisseric et gFZT82

Effectivement, dans mon soucis (Access) d'occuper le moins de place, je n'avais pas fait attention aux limites des variables.

Merci pour vos réponses, cela fonctionne parfaitement !

[mercatog]

Bonjour à tous
Si les durées sont toujours sous la forme x(h) y(m) z(s), je propose une fonction (pour le fun)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Function SpecialText2Seconds(ByVal Str As String) As Long
 
Str = Replace(Str, "(h) ", "*3600+")
Str = Replace(Str, "(m) ", "*60+")
Str = Replace(Str, "(s)", "")
SpecialText2Seconds = Evaluate(Str)
End Function