Discussion :

[max76]

Bonjour à tous,

Je cherche à réaliser une macro sur des données à préparer avant un import en base de données.
J'ai un tableau Excel avec n colonnes. La colonne D peut présenter plusieurs fois une même valeur (ex: ARBRE). La colonne Y doit présenter toujours la même valeur pour une valeur de D donnée.

Quelle macro utiliser pour mettre en évidence des valeurs de Y (colorer les cellules ?) différentes pour une même valeur de D ?

Ex:

D … Y
ARBRE … VERT
MAISON … BLANC
ETANG … BLEU
ROUTE … NOIR
GRANGE … JAUNE
ETANG … BLEU
GRANGE … JAUNE
GRANGE … VERT
ETANG … BLEU
ARBRE … VERT
MAISON … BLANC

Merci d'avance pour votre aide !

Max

[Trius]

Salut!

Il y a certainement plus efficace que ça mais ça tourne en tout cas:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Sub Principal()
 
Dim mot As String
 
mot = InputBox("Valeur D")
Call Test(mot)
 
End Sub
 
Sub Test(mot)
 
Dim i As Integer
Dim x As String
Dim y As Boolean
 
x = ""
i = 2
y = False
 
While Cells(i, 1).Value <> ""
 
    If Cells(i, 1).Value = mot And x = "" Then
 
     x = Cells(i, 2).Value
 
    End If
 
    If Cells(i, 1).Value = mot And Cells(i, 2).Value <> x And x <> "" Then
 
    y = True
 
    End If
 
i = i + 1
 
Wend
 
i = 2
 
If y = True Then
 
While Cells(i, 1).Value <> ""
 
    If Cells(i, 1).Value = mot Then
 
        Cells(i, 2).Interior.ColorIndex = 6
 
    End If
 
i = i + 1
 
Wend
 
End If
 
End Sub

[max76]

Merci pour ta réponse rapide Trius :-)

Cependant ça ne marche pas. J'ai essayé sur les colonnes D et Y : pas de résultat...
J'ai donc regardé ton code, j'ai un peu de mal à le comprendre (normal je suis un novice) mais j'ai l'impression déjà qu'il travaille en ligne et non en colonnes.

Je joins un fichier Excel avec ma structure de départ en feuille 1 et le résultat souhaité en feuille 2 (mais je veux que la macro ne travaille que sur la feuille 1 la feuille 2 c'est pour illustrer).

Merci !

[Trius]

Il faut adapter le code à tes colonnes

Je travaillais sur les colonnes 1 et 2 mais toi tu ne travailles pas sur les mêmes!

Regarde le fichier que je joins et tu devrais comprendre:

[Guiiand]

Bonjour max76

Voici ce que je viens de coder, je suis passe par les tableau de mon cote. J'espere que cela t'aideras.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Sub VerificationValeur()
 
    Dim Donnees()
    Dim FinTableau As Integer
    Dim Ligne As Integer
    Dim NbMots As Integer
 
    FinTableau = Range("D65536").End(xlUp).Row
    NbMots = 1
 
    ReDim Donnees(1 To 3, 1 To NbMots)
 
    For Ligne = 1 To FinTableau
        For i = 1 To NbMots
            If Range("D" & Ligne) = Donnees(1, i) Then
                If Range("Y" & Ligne) <> Donnees(2, i) Then
                    Donnees(3, i) = True
                    Exit For
                End If
            End If
        Next i
 
        If i > NbMots Then
            NbMots = NbMots + 1
            ReDim Preserve Donnees(1 To 3, 1 To NbMots)
            Donnees(1, i) = Range("D" & Ligne)
            Donnees(2, i) = Range("Y" & Ligne)
            Donnees(3, i) = False
        End If
    Next
 
    For i = 1 To NbMots
        If Donnees(3, i) Then
            For Ligne = 1 To FinTableau
                If Range("D" & Ligne) = Donnees(1, i) Then
                    Range("Y" & Ligne).Interior.Color = 65535
                End If
            Next
        End If
    Next
 
 
End Sub

Bonne journée à toi

[max76]

Merci pour ta contribution Trius mais le code de Guiiand est juste parfaitement adapté à mon cas.

Merci Guiiand, c'est du très beau travail !