Discussion :

[PDMLive]

Nous venons de convertir notre système de MS-ACCESS 2002 à 2010. Nous n'avons pas trouvé comment se déplacer d'une fenêtre ouverte à l'autre facilement (sans CRTL-F6). Or, avec 2002, des icônes s'affichaient dans la barre de tâches rendant facile le repérage; ce n'est plus le cas.

Quelqu'un parmi vous peut aider?

Merci à l'avance de vous pencher sur la situation.

Salutations.

PDMLive

[mumen]

Peut être que l'option "Documents à onglets" est activée dans ta base, ce qui peut te faire perdre les repères.

Dans : Fichiers/Option/Base de données active/Option de la fenêtre de document

Essaye de mettre "Fenêtres superposées"

[LedZeppII]

Bonsoir,

La fonctionnalité a disparu dans Access 2007.
Même si on tente de l'activer par code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.SetOption "ShowWindowsInTaskbar", True

ça ne fonctionne pas.

Il reste peut-être une possibilité avec des fonctions de l'API Windows, qu'il faut appliquer après chaque ouverture d'une fenêtre.

Exemple (fonctionne avec XP).
créer un module de code et y coller ce code :

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Option Compare Database
Option Explicit
 
' --- Style Fenêtre ---------------------------------------
Private Const WS_EX_APPWINDOW As Long = &H40000
Private Const GWL_STYLE As Long = -16
Private Const GWL_EXSTYLE As Long = -20
 
Private Declare Function GetWindowLong Lib "user32.dll" Alias "GetWindowLongA" _
        (ByVal hWnd As Long, ByVal nIndex As Integer) As Long
 
Private Declare Function SetWindowLong Lib "user32.dll" Alias "SetWindowLongA" _
        (ByVal hWnd As Long, ByVal nIndex As Integer, ByVal dwNewLong As Long) As Long
 
' --- Masquer/Montrer fenêtre ------------------------------
Private Const SW_HIDE As Long = 0
Private Const SW_SHOWNORMAL As Long = 1
 
Private Declare Function ShowWindow Lib "user32.dll" (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long
 
 
Function ButtonInTaskBar(hWnd As Long, blnON As Boolean)
Dim dwLong As Long, dwNewLong As Long
    dwLong = GetWindowLong(hWnd, GWL_EXSTYLE)
    If blnON = False Then
       dwNewLong = dwLong And (Not WS_EX_APPWINDOW)
    Else
       dwNewLong = dwLong Or WS_EX_APPWINDOW
    End If
    ShowWindow hWnd, SW_HIDE
    dwLong = SetWindowLong(hWnd, GWL_EXSTYLE, dwNewLong)
    ShowWindow hWnd, SW_SHOWNORMAL
End Function

Dans un formulaire, aller dans le code événementiel de «sur chargement» et y coller

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ButtonInTaskBar Me.hWnd, True

Ça ne fonctionne bien sur, qu'avec des formulaires fenêtrées.
Soit on a choisi de mettre l'option citée par Mumen sur «Fenêtres superposées» (par opposition à «documents à onglets»),
soit la fenêtre du formulaire est de type indépendante (voir dans propriétés «Autres»).
Edit 2013-03-08: Ça à l'air de ne fonctionner que pour des fenêtres de type indépendantes.

A+