Discussion :

[flo1411]

Bonjour à tous,
Je vous explique la situation : j'ai un userform avec une combobox dans lequel je selectionne une valeur. En cliquant sur le bouton ok, j'aimerais qu'un message s'affiche si une cellule de mon classeur contient la valeur de la combobox sachant que les cellules peuvent contenir cette valeur suivie d'autres choses.
Je ne sais pas comment faire pour parcourir toutes ces cellules et vérifier cela. J'ai écrit ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
firstRow = Cells.Range("A5").Row
lastRow = Cells([A65536].End(xlUp).Row, 1).Row
 
For k = firstRow To lastRow
    For l = 4 To 8
        If Cells(k, l).Value = CB_Lieu.Value & "*" Then
            MsgBox ("Valeur déjà présente")
        End If
    Next
Next

Pouvez-vous m'aider s'il vous plait ?

[gFZT82]

Bonjour,

Essaie comme cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub CommandButton1_Click()
Dim Plage As Range, C As Range
    Set Plage = Range("A5:A" & Range("A" & Rows.Count).End(xlUp).Row)
    Set C = Plage.Find(CB_Lieu.Value, LookIn:=xlValues, lookat:=xlPart)
    If Not C Is Nothing Then
        MsgBox ("Valeur présente")
    Else
        MsgBox ("Valeur absente")
    End If
    Set Plage = Nothing: Set C = Nothing
End Sub

Cordialement.

[keygen08]

Bonjour

Pour rechercher une chaine de texte. Remplacer

If Cells(k, l).value = CB_Lieu.Value & "*" Then

Par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Cells(k, l).text like CB_Lieu.Value & "*" Then

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Cells(k, l).text like "*" & CB_Lieu.Value & "*" Then

[jfontaine]

Bonjour,

Une autre méthode en utilisant la formule nb.si (Countif)

On couple avec une boucle sur chaque feuille du classeur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim sh As Worksheet
 
For Each sh In ThisWorkbook.Worksheets
    If Application.WorksheetFunction.CountIf(sh.Cells, CB_Lieu.Value) > 0 Then
         MsgBox ("Valeur déjà présente")
    End If
Next sh