Discussion :

[Alwaysin]

Bonjour,

j'ai des valeurs de temps dans une colonne. Soit :
- des minutes sous la forme "xx min" comme "10 min" ou "5 min"
- des heures sous la forme "xxh" comme "1h"
- des heures et minutes sous la forme "xxhxx" comme "1h40" ou "2h20"

Comment puis-je faire pour que cela me donne (en reprenant l'ordre des exemples) "10", "5", "60", "100" et "140" ?

Merci beaucoup d'avance !

[Daniel.C]

Bonjour,

Essaie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub test()
    Dim C As Range
    For Each C In Range([A1], Cells(Rows.Count, 1).End(xlUp))
        If Len(Application.Substitute(C.Value, " min", "")) <> Len(C.Value) Then
            C.Offset(, 1) = CInt(Application.Substitute(C.Value, " min", ""))
        Else
            tabl = Split(C.Value, "h")
            C.Offset(, 1) = CInt(tabl(0)) * 60 + CInt(tabl(1))
        End If
    Next C
End Sub

[Alwaysin]

Merci beaucoup pour la réponse !
Cela marche très bien, excepté pour les valeurs du second cas, de type "xh" comme "1h", où il renvoie une "erreur d'exécution 13" (incompatibilité de type). Mais si je change la valeur d'origine en "1h00", cela fonctionne bien, et je pourrais m'en accommoder.

Par contre, je suis vraiment débutant et je ne sais pas comment faire si je veux que cela s'applique à une sélection, par exemple de I6 à I11 et de I14 à I15. J'ai essayé de chercher du côté des "références relatives mais je n'arrive pas à trouver.

[Daniel.C]

Voici la macro modifiée pour les formats "xh". Il te suffit de sélectionner la ou les plages à traiter et de lancer la macro :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test()
    Dim C As Range
    For Each C In Selection
        If Len(Application.Substitute(C.Value, " min", "")) <> Len(C.Value) Then
            C.Offset(, 1) = CInt(Application.Substitute(C.Value, " min", ""))
        Else
            tabl = Split(C.Value, "h")
            If tabl(1) = "" Then
                C.Offset(, 1) = CInt(tabl(0)) * 60
            Else
                C.Offset(, 1) = CInt(tabl(0)) * 60 + CInt(tabl(1))
            End If
        End If
    Next C
End Sub

[mercatog]

Une petite fonction personnalisée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Function TimeConvert(ByVal Str As String) As Long
 
Str = Replace(Str, " ", "")
Str = Replace(Str, "min", "")
Str = Replace(Str, "h", "h0")
Str = Replace(Str, "h", "*60+")
TimeConvert = Evaluate(Str)
End Function

TimeConvert("1h40") donne 100

[Alwaysin]

@Daniel.C -> Yeah, merci infiniment ! Ca marche super, me reste plus qu'à jouer avec les offsets pour faire atterrir les résultats là où je veux

@mercatog -> Merci beaucoup pour la proposition, ça à l'air intéressant mais quel est l'avantage d'une fonction ? Est-ce plus performant et/ou plus simple à utiliser ?

[mercatog]

Tu peux utiliser la fonction à l'intérieur d'une Sub qui scrute toutes tes cellules (pour la lisibilité) ou bien tu peux carrément l'utiliser directement sur ta feuille (à la condition que la fonction soit écrite dans un module standard.

Exemple d'appel de la fonction à l'intérieur d'une Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Traitement()
Dim c As Range
 
For Each c In Worksheets("Feuil4").Range("A1:A50")
    c.Offset(0, 5) = TimeConvert(c.Value)
Next c
End Sub
 
Function TimeConvert(ByVal Str As String) As Long
 
On Error Resume Next
TimeConvert = Evaluate(Replace(Replace(Replace(Replace(LCase(Str), " ", ""), "min", ""), "h", "h0"), "h", "*60+"))
End Function