Discussion :

[Invité]

J'ai une centaine de feuilles dans excel à classer. Elles portent des noms type "xxxx (1)", "xxxx (2)" ect "xxxx (20)"
J'ai trouvé une macro sur ce topic http://www.developpez.net/forums/d13...nologiquement/
mais les feuilles se classent pas exactement comme je veux. Elles se classent comme ça:

"xxxx (1)", "xxxx (10)","xxxx (2)" ect "xxxx (20)"

[Efgé2]

Bonjour wywy22n
Une proposition avec un quick sort de tri
Il faut tout placer dans le même module
Le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub Tri_Onglets()
Dim I&, F As Worksheet, d As Object, T As Variant, Flag As Boolean
Dim ActF As Worksheet
Set ActF = ActiveSheet
Set d = CreateObject("Scripting.Dictionary")
For Each F In Worksheets
    If InStr(F.Name, "(") Then
        d(Format(Split(Replace(F.Name, ")", ""), "(")(1), "000")) = F.Name
    Else
        Flag = True
    End If
Next F
 
T = d.Keys
 
Call tri(T, 0, UBound(T))
Application.ScreenUpdating = False
For I = LBound(T) To UBound(T) - Not Flag
    Sheets(d(T(I))).Move Before:=Sheets(I + 1)
Next I
ActF.Activate
End Sub

Le tri :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub tri(a, gauc, droi)  ' Quick sort http://boisgontierj.free.fr/
Dim Ref&, g&, d&, Temp$
  Ref = a((gauc + droi) \ 2)
  g = gauc: d = droi
  Do
    Do While a(g) < Ref: g = g + 1: Loop
    Do While Ref < a(d): d = d - 1: Loop
    If g <= d Then
      Temp = a(g): a(g) = a(d): a(d) = Temp
      g = g + 1: d = d - 1
    End If
  Loop While g <= d
  If g < droi Then Call tri(a, g, droi)
  If gauc < d Then Call tri(a, gauc, d)
End Sub

Cordialement

[Efgé2]

Bonjour wywy22, Bonjour à tous,
Hier soir je n'avais pas vu que le fil cité parlait de ComboBox (désolé )

Une proposition plus adaptée :
Premier bouton pour créer les feuilles de "XXX (1)" à "XXX (300)" en ordre aléatoire
Deuxième bouton pour afficher la combobox triée.

Cordialement

[Invité]

Merci, pour votre aide, j'ai utilisé le code de la première réponse et sa fonctionne parfaitement.

[patricktoulon]

Bonjour
Sinon il y avait ca

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub met_en_ordre_alpha_les_feuilles()
 Dim X As Variant
 Dim I As Variant
 For Each X In ActiveWorkbook.Sheets
 For I = 2 To ActiveWorkbook.Sheets.Count
 If Sheets(I-1).Name>Sheets(I).Name Then
 Sheets(I-1).Move After:=Sheets(I)
 End If
 Next
 Next
 End Sub

Au plaisir