Discussion :

[TraderAS]

Bonjour,

j'ai un problème que je n'arrive à résoudre, en faite j'ai une base de données composée de deux colonnes une colonnes dates et une colonne prix
la date des colonnes ne concerne que les prix des jours ouvrables c'est à dire du Lundi au Vendredi
sauf qu'il manque les lignes de certaines dates

Voici le fichier excel sur lequel je travail http://cjoint.com/?CDfnHPQECQ8

==> je souhaite avoir un code VB qui me permet d'insérer les lignes des dates manquantes et d'y insérer dans la colonne prix, le prix (j-1)

merci

[mercatog]

Valable pour la version Excel 2007 et suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Option Explicit
 
Sub Remplissage()
Dim LastLig As Long, i As Long, j As Long, k As Long, m As Long
Dim n As Integer
Dim Tb, Res()
 
Application.ScreenUpdating = False
With Worksheets("MaFeuille")                       'A adapter
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    Tb = .Range("A2:B" & LastLig)
 
    ReDim Res(1 To 2, 1 To 1)
    Res(1, 1) = CLng(Tb(1, 1))
    Res(2, 1) = Tb(1, 2)
    j = 1
    For i = 2 To LastLig - 1
        n = Diff(Tb, i)
        m = j + n
        ReDim Preserve Res(1 To 2, 1 To m)
        For k = j + 1 To m
            Res(1, k) = Suiv(Res(1, k - 1))
            Res(2, k) = IIf(n = 1 Or k = m, Tb(i, 2), Tb(i - 1, 2))
        Next k
        j = m
    Next i
    With .Range("D2")
        .Resize(j, 2) = Application.Transpose(Res)
        .Resize(j, 1).NumberFormat = "dd/mm/yyyy"
    End With
End With
End Sub
 
Private Function Diff(ByVal T, ByVal d As Long) As Byte
Dim Dte As Long, Der As Long
 
Der = CLng(T(d - 1, 1))
Dte = CLng(T(d, 1))
 
Diff = Evaluate("=NETWORKDAYS(" & Der & "," & Dte & ")") - 1
End Function
 
Private Function Suiv(ByVal Dte As Long) As Long
 
Suiv = Evaluate("=WORKDAY(" & Dte & ",1)")
End Function

[TraderAS]

bonjour et merci pour votre réponse, mais quand j'ai appliqué ce code j'ai eu cette erreur d'éxecution '6' Dépassement de capacité au niveau de :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Function Diff(ByVal T, ByVal d As Long) As Byte
Dim Dte As Long, Der As Long
 
Der = CLng(T(d - 1, 1))
Dte = CLng(T(d, 1))
 
****Diff = Evaluate("=NETWORKDAYS(" & Der & "," & Dte & ")") - 1***
End Function

voici le document surlequel je travail : http://cjoint.com/?CDiosKpPr2C

merci

[mercatog]

Le code proposé fonctionne si les dates initiales sont triées par ordre croissant

[TraderAS]

voici la colonne des dates :

20/03/2011
18/03/2011
16/03/2011
14/03/2011
12/03/2011
11/03/2011
10/03/2011
08/03/2011

dois je faire une manipulation sur c dates ?

[mercatog]

Fais un tri préalable de tes plages de données pour que les dates soient en ordre croissant.

Tu peux faire ceci aussi par code. je te laisse le soin de t'y pencher.

[TraderAS]

Bonjour mercatog

peut être que je me trompe monsieur mais l colonne des dates sur on fichier excel est bien ordonnée par ordre croissant, je ne sais pas, que dois je faire pour faire marcher le code

[keygen08]

Bonjour, Si le fichier joint correspond au fichiers reel, les dates sont classé par ordre decroissant, il faut donc inverser le sens de cette liste.