Discussion :

[Silencee]

Bonjour à tous,

J'ai un petit problème avec une liste de date et malgré quelques recherches, je n'ai pas trouvé de solutions.

Alors j'ai une première colonne avec des dates qui peuvent se répéter mais toujours dans l'ordre chronologique.
Je voudrais pouvoir récupérer sur une autre feuille la liste de dates sans doublons mais de façon automatique car je connais la fonction Tri automatique sans doublon mais cela se fait manuellement.

Exemple:

01/01/2012 => 01/01/2012
01/01/2012 => 02/01/2012
02/01/2012 => 03/01/2012
03/01/2012 => 05/01/2012
03/01/2012 =>
05/01/2012 =>
00/01/00
00/01/00
etc...

Merci d'avance

[Daranc]

une piste
http://www.developpez.net/forums/d61...vba-suite-fin/
à adapter en fonction de tes besoins

[Silencee]

Merci Daranc pour ta réponse rapide!

c'est sympa mais c'est je pense un peu trop compliqué pour ce que j'ai à faire, je ne suis pas un pro d'Excel

Il y aurait pas quelque chose de plus simple (sans forcément passer par VBA même si j'en pratique un petit peu) ?

[Daniel.C]

Bonjour,

Essaie comme ceci, avec tes données à partir de A1 :

en C1 (à adapter) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=A1

en C2, à recopier vers le bas (formule matricielle, à valider avec Ctrl+Maj+Entrée) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMME(($A$1:$A$10<>0)*1/NB.SI($A$1:$A$10;$A$1:$A$10))<LIGNE();"";SI(INDEX($A$1:$A$10;MIN(SI(ESTNA(EQUIV($A$1:$A$10;$C$1:C1;0));LIGNE($A$1:$A$10)));1)=0;"";INDEX($A$1:$A$10;MIN(SI(ESTNA(EQUIV($A$1:$A$10;$C$1:C1;0));LIGNE($A$1:$A$10)));1)))

[Silencee]

Bonjour Daniel.C,

Merci pour votre proposition mais j'ai un problème lorsque j'essaie de l'adapter.
Il apparaît toujours la même date.

Mes dates sont à partir de F3 jusqu'à F1000. Ce n'est pas rempli pour l'instant jusqu'à F1000 mais c'est un fichier qui va se remplir au fur et à mesure.

J'ai donc écris en BC3:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=F3

Puis en BB3 en matriciel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMME(($F$3:$F$1000<>0)*1/NB.SI($F$3:$F$1000;$F$3:$F$1000))<LIGNE();"";SI(INDEX($F$3:$F$1000;MIN(SI(ESTNA(EQUIV($F$3:$F$1000;$BC$3:BC3;0));LIGNE($F$3:$F$1000)));1)=0;"";INDEX($F$3:$F$1000;MIN(SI(ESTNA(EQUIV($F$3:$F$1000;$BC$3:BC3;0));LIGNE($F$3:$F$1000)));1)))

[Daniel.C]

Telle qu'elle est prévue, la formule matricielle doit être en BC4 puis, BC5 etc.

[Silencee]

Ok merci beaucoup pour l'aide

[Silencee]

Re-bonjour,

Je rouvre ce fil car j'ai réalisé quelques modifications (qui marchaient jusqu'a présent) et j'ai de nouveau un petit problème.

Je précise que j'utilise la même formule dans plusieurs fichiers mais je ne sais pas pourquoi, depuis quelques jours, cela ne marche plus sur l'un d'entre eux.

Le tri automatique des dates s'arrête toujours à l'avant dernière date et ne prend pas la dernière en compte.

Un fichier exemple est en pièce jointe.

Merci d'avance

[papouclo]

Bonjour,
Remplacer en A3 la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(LIGNES(A$3:A3)>SOMME(SI(Dates<>"";1/NB.SI(Dates;Dates)));"";INDEX(Dates;MIN(SI(NB.SI(A$2:A2;Dates)=0;LIGNE(Dates)))-2))

par la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(LIGNES(A$3:A3)>ARRONDI(SOMME(SI(Dates<>"";1/NB.SI(Dates;Dates)));0);"";INDEX(Dates;MIN(SI(NB.SI(A$2:A2;Dates)=0;LIGNE(Dates)))-2))

et recopier vers le bas.
En effet, Excel joue des tours en cellule A93 où l'ancienne formule devient :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(LIGNES(A$3:A93)>SOMME(SI(Dates<>"";1/NB.SI(Dates;Dates)));"";INDEX(Dates;MIN(SI(NB.SI(A$2:A92;Dates)=0;LIGNE(Dates)))-2))

Or si on teste LIGNES(A$3:A93) ( sélectionner cette partie dans la barre de formule et cliquer sur la touche f9 ) on obtient bien sûr 91 mais,
testée de la même façon, SOMME(SI(Dates<>"";1/NB.SI(Dates;Dates))) donne non pas 91 mais 90,9999999999999 et du coup le test
LIGNES(A$3:A93) > SOMME(SI(Dates<>"";1/NB.SI(Dates;Dates))) au lieu de renvoyer FAUX (ce qui conduirait au calcul) renvoie VRAI (ce qui provoque en réponse de la formule une chaîne vide "").
Cordialement
Claude

[Silencee]

Bonjour Claude,

Merci beaucoup pour votre réponse! Ca résoud parfaitement mon problème.
Explications très claires !

Et merci pour le tuyau avec la touche F9, ça me sera très utile à l'avenir