Discussion :

[Ulyssimo]

Bonjour,

Je souhaite répliquer une base de données ACCESS par le code, voici mon code :

Private Sub cmd_replica_Click()
Dim repMaster As New JRO.Replica

' Se connecter à la base de données Northwind.
repMaster.ActiveConnection = "C:\Veolia\Veolia.mdb"

' Suppression de la base de données myTestRep si elle existe.
If (Dir("C:\Veolia\Replica\myTestRep.mdb") <> "") Then
Kill ("C:\Veolia\Replica\ReplicaVeolia.mdb")
End If
' ' Créer un réplica complet.
repMaster.CreateReplica "C:\Veolia\Replica\ReplicaVeolia.mdb", "My Full Replica1", jrRepTypeFull, jrRepVisibilityGlobal


End Sub


Mais lorsque j’exécute mon code le message d’erreur suivant s’affiche et je n’arrive pas à résoudre le problème.


« La base de données a été placée par l’utilisateur Admin sur ‘le compte windows X’ dans un état l’empêchant d’être ouverte ou verrouillée »

Si vous avez des idées.

Merci par avance de votre aide.

[marot_r]

Voici du code que j'ai fais pour cela. Les méthodes publiques sont celles qui sont utilisatbles, les privates sont des tests.

Il te faut un ref sur Microsoft Jet and Replication Object.

C'est du code que j'ai mis dans me base de travail qui réplique d'autres bases mais pas elle-même.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
 
Option Compare Database
Option Explicit
Public Const AVEC_MESSAGE As Boolean = True
Public Const SANS_MESSAGE As Boolean = False
Public Sub CreerReplicatLocal(prmNomCompletReplicatMaitre As String, _
                              prmNomCompletReplicatLocal As String, _
                              prmDescriptionReplicatLocal As String, _
                              prmAvecMessage As Boolean)
 
    Dim replicatMaitre As New JRO.Replica
    Dim replicatLocal As New JRO.Replica
    Dim mess As String
 
    ' Se connecter à la base de données maitre
    replicatMaitre.ActiveConnection = prmNomCompletReplicatMaitre
 
    ' Créer un réplicat complet local
    replicatMaitre.CreateReplica prmNomCompletReplicatLocal, prmDescriptionReplicatLocal, jrRepTypeFull, jrRepVisibilityLocal
 
    'Complète liste des chemins d'accès aux réplicats
 
    replicatLocal.ActiveConnection = prmNomCompletReplicatLocal
 
    Dim db As Database
    Dim r As Recordset
    Set db = OpenDatabase(prmNomCompletReplicatLocal)
 
    Set r = db.OpenRecordset("NomReplicat", dbOpenDynaset)
 
    r.FindFirst "[IdReplicat]=""" & CStr(replicatLocal.ReplicaID) & """"
    If r.NoMatch Then
        r.AddNew
        r![IdReplicat] = CStr(replicatLocal.ReplicaID)
        r![NomComplet] = prmNomCompletReplicatLocal
        r.Update
    End If
 
    r.FindFirst "[IdReplicat]=""" & CStr(replicatMaitre.ReplicaID) & """"
    If r.NoMatch Then
        r.AddNew
        r![IdReplicat] = CStr(replicatMaitre.ReplicaID)
        r![NomComplet] = prmNomCompletReplicatMaitre
        r.Update
    End If
 
    r.Close: Set r = Nothing
 
    'Synchronise le replicat
    db.Synchronize prmNomCompletReplicatMaitre
 
    db.Close: Set db = Nothing
 
    mess = "Le replicat :" _
           & vbNewLine & replicatLocal.ReplicaID & " " & prmNomCompletReplicatLocal & " a été créé " _
           & vbNewLine & "à partir de : " _
           & vbNewLine & replicatMaitre.ReplicaID & " " & prmNomCompletReplicatMaitre & "."
 
    Set replicatLocal = Nothing
    Set replicatMaitre = Nothing
 
    If prmAvecMessage = AVEC_MESSAGE Then
        MsgBox mess
    End If
 
End Sub
 
Public Sub SynchroniserManuellement( _
                prmNomCompletReplicatMaitre As String, _
                prmNomCompletReplicatLocal As String, _
                prmAvecMessage As Boolean)
 
    Dim db As Database
    Dim mess As String
 
    Set db = OpenDatabase(prmNomCompletReplicatLocal)
    db.Synchronize prmNomCompletReplicatMaitre
    db.Close: Set db = Nothing
 
    mess = "Le replicat :" _
       & vbNewLine & prmNomCompletReplicatLocal & " a été mis à jour " _
       & vbNewLine & "à partir de : " _
       & vbNewLine & prmNomCompletReplicatMaitre & "."
    If prmAvecMessage = AVEC_MESSAGE Then
        MsgBox mess
    End If
End Sub
Private Sub CreerReplicatLocaux()
    Dim repMaster As New JRO.Replica
    Dim nomReplicat As String
    ' Se connecter à la base de données Northwind.
    repMaster.ActiveConnection = "C:\PJ\PJ217 - reglement par arrondissement\Replicat\Test3.mdb"
    ' Créer un réplica complet.
    nomReplicat = "C:\PJ\PJ217 - reglement par arrondissement\Replicat\RL1Test3.mdb"
    repMaster.CreateReplica nomReplicat, "RL1T3", jrRepTypeFull, jrRepVisibilityLocal
 
    nomReplicat = "C:\PJ\PJ217 - reglement par arrondissement\Replicat\RL2Test3.mdb"
    repMaster.CreateReplica nomReplicat, "RL2T3", jrRepTypeFull, jrRepVisibilityLocal
 
    nomReplicat = "C:\PJ\PJ217 - reglement par arrondissement\Replicat\RG1Test3.mdb"
    repMaster.CreateReplica nomReplicat, "RG1T3", jrRepTypeFull, jrRepVisibilityGlobal
 
    nomReplicat = "C:\PJ\PJ217 - reglement par arrondissement\Replicat\RA1Test3.mdb"
    repMaster.CreateReplica nomReplicat, "RA1T3", jrRepTypeFull, jrRepVisibilityAnon
 
End Sub
 
Private Sub CreerReplicatLocaux2()
    Dim repMaster As New JRO.Replica
    Dim nomReplicat As String
    ' Se connecter à la base de données Northwind.
    repMaster.ActiveConnection = "C:\PJ\PJ217 - reglement par arrondissement\DonneesPJ_R.mdb"
    ' Créer un réplica complet.
    nomReplicat = "C:\PJ\PJ217 - reglement par arrondissement\DonneesPJ_R_RL1.mdb"
    repMaster.CreateReplica nomReplicat, "DonneesPJ_R_RL1", jrRepTypeFull, jrRepVisibilityLocal
 
    nomReplicat = "C:\PJ\PJ217 - reglement par arrondissement\DonneesPJ_R_RL2.mdb"
    repMaster.CreateReplica nomReplicat, "DonneesPJ_R_RL2", jrRepTypeFull, jrRepVisibilityLocal
 
End Sub

Mais là encore je déconseille VIVEMENT l'usage des réplicats dans Access c'est une GROSSE source de pb.

A+

[Ulyssimo]

Je te remercie pour ton aide.

A+