Discussion :

[DYV007]

Bonjour,

J'ai une procédure vba qui exporte les données d'une de mes requête access en fichier excel. Cependant pour palier à un mauvais usage des utilisateurs du fichier Excel, j'ai besoin de protéger ce fichier Excel (lecture seule avec mot de passe ou pas).

Voici mon code de création de mon fichier Excel

'2. génération fichiers Excel
Dim qd As QueryDef
mag = Forms![Traitement retour global].[NumMagasin].Value
'MsgBox mag
jour = Format(Now, "dd-mm-yyyy hh_mm")
NomFichier = ("P:\RetourVpm\Export SAP\") & mag & (" Retour stock du ") & jour & (".xls")
'MsgBox NomFichier
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel97, "R_ExcelStock", NomFichier

NomFichier2 = ("P:\RetourVpm\Export SAP\") & mag & (" Destruction du ") & jour & (".xls")
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel97, "R_ExcelDestruction", NomFichier2

DoCmd.RunMacro "ValidFlag"

DoCmd.RunMacro "MacroFermeture"

Si quelqu'un pouvais me dire ce qu'il faut ajouter pour rendre ce fichier en lecture seule, se serait le top.

Merci d'avance

[paidge]

Bonjour,

Rajoutes ce code à la suite de ta fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
    ' ===== Déclaration des variables =====
    Dim XLApp As Excel.Application
    Dim XLBook As Excel.Workbook
    Dim feuille As Excel.Worksheet
 
    ' ===== Ouverture du classeur Excel en mode invisible =====
    Set XLApp = CreateObject("Excel.Application")
    XLApp.Visible = False
    Set XLBook = XLApp.Workbooks.Open(NomFichier)
 
    ' ===== Pour chaque feuille du classeur, on verrouille les cellules =====
    For Each feuille In XLBook.Sheets
        feuille.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
    Next feuille
 
    ' ===== Sauvegarde du fichier =====
    XLBook.Save
 
    ' ===== Fermeture d'Excel =====
    XLApp.Quit
 
    ' ===== Libération des variables =====
    Set feuille = Nothing
    Set XLBook = Nothing
    Set XLApp = Nothing

ça devrait le faire

[DYV007]

Merci je viens d'essayer et sur la ligne
=> Dim XLApp As Excel.Application

j'ai l'erreur :" type défini par l'utilisateur non défini"...

j'ai du louper qqchose

[DYV007]

j'ai trouvé, il fallait que j'active la bibliothèque... par contre ya autre chose qui marche pas faut que j'analyse...

Merci de ta réponse, cela fait un peu avancer le schmilblick

[paidge]

Oui désolé j'ai oublié de préciser pour la bibliothèque :p Sinon j'avais oublié un bout de code. Je l'ai mis à jour. Dis-moi si c'est mieux comme ça

[DYV007]

Cette solution, marche tip top... merci à toi !