Discussion :

[momobjk]

Bonjour,

je suis débutant en VBA et surtout je ne connais quasiment pas l'API Office, j'aurais donc besoin de votre aide. J'aimerais savoir comment je pourrais faire en sorte d'écrire dans un fichier Excel lorsque je double clique sur un mail non lu sur Outlook.
J'ai réussi la partie où il faut créer le fichier Excel, j'arrive aussi à récupérer les info du mail. Mon problème est le suivant : je ne veux écrire seulement les mails qui n'ont pas été lu. Lorsque j’ai exécuté pas à pas, je me suis rendu compte que la propriété UnRead du mail est toujours fausse car le mail passe automatiquement en "lu", je ne peux donc pas utiliser cette condition pour ne traiter que les mails non lu.

Connaisez vous une méthode pour palier à ce problème ?

Merci.

Voici mon code actuel (je n'ai pas mis les fonctions utilitaires)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
 
Public WithEvents m_objMail As Outlook.mailItem
 
Sub Application_ItemLoad(ByVal Item As Object)
    On Error Resume Next
    Dim strClass As String
    Select Case Item.Class
        Case olMail
            Set m_objMail = Item
    End Select
End Sub
 
 
Sub m_objMail_Open(Cancel As Boolean)
    If m_objMail.UnRead Then
            Dim olkMsg As Object, _
            excApp As Object, _
            excWkb As Object, _
            excWks As Object, _
            intRow As Integer, _
            intVersion As Integer, _
            strFilename As String, _
            sender As String
 
        strFilename = "C:\Temp\Test.xlsx"
 
        If strFilename <> "" Then
            intVersion = GetOutlookVersion()
            Set excApp = CreateObject("Excel.Application")
            If FileExists(strFilename) Then
                Set excWkb = excApp.Workbooks.Open(strFilename)
                Set excWks = excWkb.ActiveSheet
            Else
                excApp.SheetsInNewWorkbook = 1
                Set excWkb = excApp.Workbooks.Add
                excWkb.SaveAs (strFilename)
                MsgBox ("Le fichier a été créé sur " + strFilename)
                excWkb.WorkSheets(1).Name = "Mail"
 
                Set excWks = excWkb.ActiveSheet
 
                With excWks
                    .Cells(1, 1) = "Expéditeur"
                    .Cells(1, 2) = "Objet"
                    .Cells(1, 3) = "Date de récéption"
                    .Cells(1, 4) = "Date d'ouverture"
                End With
            End If
 
            excWks.Rows(2).Insert
            sender = GetSMTPAddress(m_objMail, intVersion)
            excWks.Cells(2, 1) = sender
            excWks.Cells(2, 2) = m_objMail.Subject
            excWks.Cells(2, 3) = m_objMail.ReceivedTime
            excWks.Cells(2, 4) = Date + Time
 
            excWkb.Close (True)
        End If
        Set excWks = Nothing
        Set excWkb = Nothing
        excApp.Quit
        Set excApp = Nothing
 
        MsgBox ("Le mail de " + sender + " a été exporté avec succès")
    End If
End Sub

[momobjk]

Je crois que j'ai trouvé une solution.

J'ai ajouté une variable globale que je met à jours dans l’événement Read() :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Public WithEvents m_objMail As Outlook.mailItem
Dim m_unread As Boolean
 
Sub Application_ItemLoad(ByVal Item As Object)
    On Error Resume Next
    Dim strClass As String
    Select Case Item.Class
        Case olMail
        Set m_objMail = Item
    End Select
End Sub
 
Sub m_objMail_Read()
    m_unread = m_objMail.UnRead
End Sub
 
 
Sub m_objMail_Open(Cancel As Boolean)
    If m_unread Then
...

[Oliv-]

Bonjour,
Tu peux utiliser l'événement qui se déclenche à chaque RECEPTION DE MAIL(Application_NewMailEx),
où alors vérifier dans ton fichier excel si l'ID du mail est présent(EntryID).