Discussion :

[SylvainM]

Bonjour à tous,

Pourriez-vous me mettre sur la bonne piste pour réaliser la manip suivante :
Je dispose d'un tableau (1ere ligne = champs, lignes suivantes = valeurs) de données, pour lequel je dois créer un graph de type "radars" pour chaque ligne, puis l'exporter en image (PNG, JPG...).
Si possible, j'aimerai que la couleur de mon graph soit liée à la valeur d'un champ ("couleur" qui prend 4 valeurs différentes).

Pourriez vous m'orienter sur les codes nécessaires à ce genre d'opération ?

Merci à vous !

Sylvain M.

[SylvainM]

Bon, je me répond à moi même pour une des étapes : l'export en PNG du graphique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub SauvePNG()
' Enregistre les graphiques du tableur au format image PNG
Fname = ThisWorkbook.Path & "\" & ActiveChart.Name & ".png"
ActiveChart.Export Filename:=Fname, FilterName:="PNG"
End Sub

Pour le reste, je cherche encore, mais si vous acceptez d'orienter mes recherches, j'accepte !

[SylvainM]

Histoire de mieux contextualiser, voici en pièce jointe un tableur qui montre mieux le principe. L'idée est d'exporter autant de graphiques que de lignes.

Si quelqu'un peut m'aider : merci d'avance !


[Edit : poursuite de mes investigations]

Voila un code qui fonctionne pour la partie "export pour chaque ligne".
Maintenant, il faudrait que j'y ajoute la couleur conditionnelle du graphique... et là, ça me semble beaucoup plus coton ! (à mon niveau en tout cas...)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub batch_graphs()
' Créé un graphique pour chaque ligne du tableau
Dim I As Integer
For I = 2 To 11
    Sheets("RADAR 1").Select
    ActiveChart.PlotArea.Select
    ActiveChart.SeriesCollection(1).Name = "='donnees'!$A$" & I
    ActiveChart.SeriesCollection(1).Values = "='donnees'!$B$" & I & ":$E$" & I
    ' Enregistre les graphiques du tableur au format image PNG
    Fname = ThisWorkbook.Path & "\" & ActiveChart.Name & "_" & I & ".png"
    ActiveChart.Export Filename:=Fname, FilterName:="PNG"
Next I
End Sub

[mercatog]

Bonsoir

On va préparer notre fichier comme suit

1. Sur la feuille donnees

• On nomme la cellule I1 par NN et la cellule J1 par COULEUR (Tous les noms décrits ici ont une portée la feuille donnees (cf case de nommage Zone))
• On met dans une plage (par exemple I2:J4 la correspondance entre la couleur et son code RGB)

Exemple:
Vert___5296274
Bleu___12611584
Rouge__255

• On nomme par TITRE avec la formule suivante

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  =DECALER(donnees!$A$1;donnees!NN;)

• On nomme par DATA avec la formule suivante

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  =DECALER(donnees!TITRE;;1;;4)

• En J1 (nommée COULEUR) on inscrit la formule suivante

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  =SIERREUR(RECHERCHEV(DECALER(TITRE;;5);$I$2:$J$4;2;FAUX);0)

2. Sur la feuille graphique:

• On nomme notre feuille graphique RADAR

• On sélectionne la série sur le graphique et dans la barre des formule en remplace la formule existante par celle-ci

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  =SERIE(donnees!TITRE;donnees!$B$1:$E$1;donnees!DATA;1)

3. Code vba

La macro suivante suffira

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub TEST()
Dim LastLig As Long, i As Long
 
With Worksheets("donnees")
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For i = 2 To LastLig
        .Range("I1") = i - 1
        Charts("RADAR").SeriesCollection(1).Format.Line.ForeColor.RGB = .Range("COULEUR")
        DoEvents
        SauvePNG
    Next i
End With
End Sub
 
Private Sub SauvePNG()
Dim Fname As String
 
Fname = ThisWorkbook.Path & "\" & Worksheets("donnees").Range("TITRE") & ".png"
Charts("RADAR").Export Filename:=Fname, FilterName:="PNG"
End Sub

Cf Fichier

[SylvainM]

Bon, ben je suis fiers de moi : je viens de parvenir, seul (!), a écrire une macro qui fait ce que je veux...
Voici donc la solution à mon problème :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub batch_graphs()
' Créé un graphique pour chaque ligne du tableau
Dim I As Integer
Dim D As Worksheet
Set D = Worksheets("donnees")
For I = 2 To 11
    Sheets("RADAR").Select
    ' modifie les données sources du graphique
    ActiveChart.PlotArea.Select
    ActiveChart.SeriesCollection(1).Name = "='donnees'!$A$" & I
    ActiveChart.SeriesCollection(1).Values = "='donnees'!$B$" & I & ":$E$" & I
    ' détermine de quelle couleur est la ligne
    If D.Cells(I, 6).Text = "bleu" Then ActiveChart.SeriesCollection(1).Border.Color = vbBlue
    If D.Cells(I, 6).Text = "vert" Then ActiveChart.SeriesCollection(1).Border.Color = vbGreen
    If D.Cells(I, 6).Text = "rouge" Then ActiveChart.SeriesCollection(1).Border.Color = vbRed
    ' Enregistre les graphiques du tableur au format image PNG
    Fname = ThisWorkbook.Path & "\" & ActiveChart.Name & "_" & I & ".png"
    ActiveChart.Export Filename:=Fname, FilterName:="PNG"
Next I
End Sub

Merci à moi !

Bon, je ne sais pas si ce monologue a un intérêt sur le forum, donc je ne le prendrai pas mal si on supprime ces messages !

Bonne soirée !

Sylvain M.

[casefayere]

Bonsoir,

Bon, je ne sais pas si ce monologue a un intérêt sur le forum, donc je ne le prendrai pas mal si on supprime ces messages

as-tu au moins regardé la proposition de mercatog, abonné expérimenté et de bon conseil

bonne nuit

[SylvainM]

Pardon Mercatog : je n'avais pas vu que tu m'avais écris une proposition !
Je vais regarder ça a tête reposée demain (là mes yeux commencent à piquer après ces exploits d'apprenti codeur !) : ça me semble beaucoup plus propre et reproductible.

Donc merci à toi !

Sylvain M.

[mercatog]

Bonsoir Dominique et merci pour toi.

Bonsoir Sylvain
Ce que tu as trouvé est aussi bon (à quelques remarques près, Les Select et si un jour tu veux ajouter une couleur, il faudra modifier le code)

En tout cas, bon travail.