Discussion :

[alain16]

Bonsoir,
Je cherche le moyen à l’intérieure d’une boucle de placer arbitrairement chaque cellule dans un tableau d’une autre feuille

Par exemple :
Ma boucle va lire les 10 cellules A1 à A10 de la feuille 1 et je souhaite placer chacune de ces cellules dans la colonne B ( B1 à B10) de la feuille 2 mais à des lignes arbitrairement différentes

Exemple :
A1-----en ---B5
A2-----en ---B9
A3----en ----B4
Etc…… ;
Avec quel code ?

Merci par avance

[Philippe Tulliez]

Bonsoir,
Je ne vois pas ce que tu appelles par arbitraire mais voilà un petit exemple.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub test()
 Dim shtFrom As Worksheet, shtTo As Worksheet
 With ThisWorkbook
  Set shtFrom = .Worksheets("Feuil1"): Set shtTo = .Worksheets("Feuil4")
 End With
 With shtTo
 .Range("B5") = shtFrom.Range("A1")
 .Range("B9") = shtFrom.Range("A2")
 .Range("B4") = shtFrom.Range("A3")
 ' etc ....
 End With
End Sub

[EDIT] Désolé mon code n'était pas complet

[mercatog]

ça pourra paraitre de niveau intermédiaire, ci-joint proposition utilisant les variables tableaux

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Test()
Dim Tb
 
Tb = Worksheets("Feuil1").Range("A1:A10")
ALEA Tb
Worksheets("Feuil2").Range("B1:B10") = Tb
End Sub
 
Private Sub ALEA(ByRef Tbl)
Dim i As Long, j As Long, N As Long
Dim Tmp As String
 
Randomize
N = UBound(Tbl, 1)
For i = 1 To N
    j = CLng(((N - i) * Rnd) + i)
'on inverse les lignes i et j
    If i <> j Then
        Tmp = Tbl(i, 1)
        Tbl(i, 1) = Tbl(j, 1)
        Tbl(j, 1) = Tmp
    End If
Next i
End Sub

[casefayere]

Bonsoir à tou(te)s,

Je pensais aussi à cette solution, à adapter bien sur, avec des nombres aléatoires

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Macro3()
Dim tbl
tbl = Range("A1:A10")
Range("B1:B10").FormulaR1C1 = "=RAND()"
Range("A1:B10").Sort key1:=Range("B1:B10"), order1:=xlAscending, Header:=xlYes
Range("B1:B10") = Range("A1:A10").Value
Range("A1:A10") = tbl
End Sub

PS : je n'avais pas vu ta proposition, mercatog, bonne soirée

[Marc-L]

Bonsoir Alain,

voici un autre code j'espère assez formateur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function AleatRange(Rg As Range)
         TS = Rg:  N& = Rg.Count:  ReDim AR(1 To N, 1 To 1):  Randomize
 
         For R& = 1 To N
             Do
                 C& = Fix(Rnd * N) + 1:  B = AR(C, 1) = "":  If B Then AR(C, 1) = TS(R, 1)
             Loop Until B
         Next
 
         AleatRange = AR
End Function
 
 
Sub Demo()
    Feuil2.[B1:B10] = AleatRange(Feuil1.[A1:A10])
End Sub

__________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …

[alain16]

Merci messieurs pour ces propositions
je vais les essayer, mais je précise que dans mon esprit
Arbitrairement ne veut pas dire aléatoirement

je ne souhaite pas empiler mes 10 cellules dans le même ordre que sur la feuille 1 mais à des lignes différentes choisies définitivement

Bien cordialement

[Philippe Tulliez]

Bonjour,

C'est justement la question que je te posais.
Si tu veux de l'aide il serait intéressant pour toi d'être plus explicite.

[Marc-L]

Exemple :
A1-----en ---B5
A2-----en ---B9
A3----en ----B4

Avec quel code ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub DemoArbitraire()
    L = [{5,9,4}]
    For R = 1 To 3:  Feuil2.Cells(L(R), 2) = Feuil1.Cells(R, 1):  Next
End Sub

__________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …


__________________________________________________________________________________________
Pour s'endormir, un mouton ne peut compter que sur lui-même …

[alain16]

Merci Marc-L c'est ce que je cherchais