Discussion :

[Genesis24]

Bonjour,
Je voudrais pouvoir changer la taille d'une image insérée grâce à un bouton de commande. J'ai beau enregistré ma macro via le système d'enregistrement ça ne donne rien car il n'y a rien de renseigné dans la macro (en gros il n'enregistre pas mes actions!). Pouvez-vous m'aider en me donne le code qui conviendrait?
Merci

[BlueMonkey]

Bonjour,

Pour redimensionner une image insérée dans la collection InlineShapes, tu peux utiliser les propriétés Width et Heigth :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    Dim sh As InlineShape
    Set sh = ActiveDocument.InlineShapes.AddPicture(FileName:="Le nom de mon fichier", LinkToFile:=False, SaveWithDocument:=True)
    With sh
        .Width = 50 'largeur
        .Height = 50 'hauteur
    End With

A+

[Genesis24]

Avec la chaleur, mon cerveau ne doit pas fonctionner! Je ne parviens pas à faire entrer ta macro dans celle déjà existante. Je la joins pour exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub CommandButton1_Click()
Selection.InlineShapes.AddPicture FileName:= _
        "\\coaxis-asp\rgcl$\Gcllk\users\Docsusers\" & Environ("UserName") & "\Mes documents\Mes images\signature.jpg" _
        , LinkToFile:=False, SaveWithDocument:=True
Dim signature as InlineShapes
 With
        .Width = 10
        .Height = 10
  End With
End Sub

Tu peux me dire ce qui cloche?
Merci

[Heureux-oli]

Salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
With
        .Width = 10
        .Height = 10
  End With

With s'utilise avec un objet, dans ton cas, il ne s'applique à rien.

BlueMonkey utilise son With avec un objet Shape (sh) et les modifications s'appliquent bien à cet objet.

[BlueMonkey]

Bonjour Heureux-oli,

J'ajouterais dans la liste des choses qui ne vont pas, qu'il faut également faire attention :
- au type d'objet déclaré un InlineShape n'est pas identique à un InlineShapes
- de récupérer une référence sur l'objet image lors de l'appel à AddPicture, sinon la variable signaturene sera pas initialisée.

Ci-dessous une solution commentée pour comprendre ce qui est fait.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub CommandButton1_Click()
    'déclare une variable capable de prendre une référence sur un objet du type InlineShape
    Dim signature As InlineShape
 
    'ajoute une image à l'emplacement de la sélection courante et garde une référence
    'sur l'objet image insérée dans la variable <signature>
    Set signature = Selection.InlineShapes.AddPicture( _
        FileName:="\\coaxis-asp\rgcl$\Gcllk\users\Docsusers\" & Environ("UserName") & _
                  "\Mes documents\Mes images\signature.jpg", _
        LinkToFile:=False, _
        SaveWithDocument:=True)
 
    'redimensionne l'image à partir de la référence sur l'objet image
    With signature
        .Width = 10
        .Height = 10
    End With
End Sub

PS. Lors d'ajout de code dans un post, en sélectionnant le code, et en cliquant sur , on obtient une mise en forme nettement plus lisible.
Merci pour la mise à jour du post #3

[Genesis24]

Merci beaucoup, ça fonctionne super et maintenant je saisis les réferences que j'utilise jusque là sans vraiment savoir pourquoi.
Vous êtes super!!!