Discussion :

[DidZTM]

Bonjour,
Je coince sur ce problème depuis un petit temps.

Comment rendre un champ mémo d'une table Rich text par programmation.

Voici ce que j'ai trouvé sur le net :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub Commande3_Click()
 Dim db As DAO.Database
 Dim tdf As DAO.TableDef
 Dim fld As DAO.Field
 
 'Create the table with a memo field
 Set db = CurrentDb()
 Set tdf = db.CreateTableDef("Table1")
 Set fld = tdf.CreateField("MyRichTextField", dbMemo)
 tdf.Fields.Append fld
 With tdf.Fields("MyRichTextField")
 
    .Properties.Append .CreateProperty("TextFormat", dbByte, acTextFormatHTMLRichText)
 End With
db.TableDefs.Append tdf
 'Clean up
 Set fld = Nothing
 Set tdf = Nothing
 Set db = Nothing
 
 
End Sub

Le problème c'est que celà me génère une erreur.

Quelqu'un pourrait-il m'expliquer comment arriver à faire çà ?

Merci

[loufab]

Bonjour,

On copie, on modifie et ça plante...

Voici comment il faut procéder :
1) je crée l'objet table en mémoire
2) je crée l'objet field en mémoire dans l'objet table
3) j'ajoute l'objet table à la bd
4) je crée la propriété dans le champ de la table qui maintenant existe.

Surtout ne pas mettre la charrue avant les bœufs.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 Dim db As DAO.Database
 Dim tdf As DAO.TableDef
 Dim fld As DAO.Field
 Dim prp As DAO.Property
 
 Set db = CurrentDb()
 '1)
 Set tdf = db.CreateTableDef("Table1")
 '2)
 Set fld = tdf.CreateField("MyRichTextField", dbMemo)
 tdf.Fields.Append fld
 '3)
 db.TableDefs.Append tdf
 '4)
 Set prp = fld.CreateProperty("TextFormat", dbByte, acTextFormatHTMLRichText)
 fld.Properties.Append prp
 
 Set fld = Nothing
 Set tdf = Nothing
 Set db = Nothing

Il y a un tuto sur DAO, je te le conseille.

Cordialement,