Discussion :

[Kmi444]

Bonjour à tous,
J'utilise Excel depuis un bout de temps mais aujourd'hui j'ai un serieux soucis. Je vous explique!
J'ai dans ma ligne 71, des valeurs que j'ajoute régulièrement.
Je voudrais, pour visualiser l'évolution, faire la soustraction des deux dernières valeurs.
Je rentre donc le code suivant :
=INDEX($C71:$XV71;EQUIV(RECHERCHE(9^9;$C71:$XV71);$C71:$XV71;0))-INDEX($C71:$XV71;EQUIV(RECHERCHE(9^9;$C71:$XV71);$C71:$XV71;0)-1)
Qui me permet de rechercher les 2 dernières cellules non vide de ma ligne 71 et de les soustraire.
Mes valeurs commencent à partir de la colonne C et je continue de les inserer tout le long de la ligne 71 d'où mon XV.

Cette formule marche très bien. Le soucis est que lorsque les deux dernieres valeurs sont égales je n'ai pas 0 comme résultat. Il me renvoie la soustraction de la derniere valeur et de la valeur précédente différente.
C'est très étrange et je n'arrive pas a comprendre ou est mon erreur.
Quelqu'un pourrait m'aider?
Merci beaucoup d'avance!

[papouclo]

Bonjour,
RECHERCHE(9^9;$C71:$XV71) renvoie la dernière valeur de la ligne et suffit pour donner le premier terme de la différence.
La formule pourrait donc s'écrire plus simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= RECHERCHE(9^9;$C71:$XV71) - INDEX($C71:$XV71;EQUIV(RECHERCHE(9^9;$C71:$XV71);$C71:$XV71;0)-1)

et fonctionnerait lorsque les deux dernières cellules non vides de la ligne 71 contiennent des valeurs différentes.

Le problème lorsque les deux dernières cellules non vides contiennent la même valeur N provient de la formule écrite pour le 2ème terme de la différence.
Il y a plusieurs occurrences de N dans la plage C71:XV71 et la portion de formule EQUIV(N;$C71:$XV71;0) renvoie le rang de la première occurrence de N,
c'est à dire non pas le rang r de la dernière cellule non vide mais le rang r - 1 de l'avant-dernière cellule non vide.
EQUIV(N;$C71:$XV71;0) - 1 renvoie donc non pas le rang de l'avant dernière mais de l'antepénultième (avant-avant-dernière) ; d'où un résultat différend de 0.

Autre proposition :
Dans la mesure où seules les valeurs de la ligne 71 nous intéressent et en supposant que l'on soit Feuil1, définir dans le Gestionnaire de nom un nom nouveau par exemple finligne par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(COLONNE(Feuil1!$71:$71)*(Feuil1!$71:$71<>""))

Ecrire ensuite comme formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX($71:$71;finligne)-INDEX($71:$71;finligne-1)

Cordialement
Claude

[EngueEngue]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHE(9^9;71:71)-DECALER(A71;0;EQUIV(RECHERCHE(9^9;71:71);71:71)-2)

Moi j'aurais plutôt trouvé la dernière et juste décalé de 1 colonne à gauche

[papouclo]

Que se passe-t-il si la dernière d'une vingtaine de valeurs écrites ligne 71 a déjà une occurrence dans la cellule D71 ?
A +

[EngueEngue]

Les chimpanzés mangeront des huîtres je pense...

Sinon je ne vois pas le rapport.
A+

[papouclo]

[IMG][/IMG]

Est-ce vraiment la réponse attendue ?

[Kmi444]

Merci Papouclo!
Ca répond exactement à mon problème!

[EngueEngue]

Mea culpa, je ne connaissais pas ce fonctionnement, en effet quand j'ai testé j'avais des valeus identiques, mais j'avais une case vide entre les doublons. Ce qui m'a induit en erreur.

Merci pour l'info Claude!