Discussion :

[Nadounette123]

Bonjour ,V
j'ai une feuille excel qui contient plusieurs tableaux je souhaite trouver une macro qui permet de copier le dernier tableau et le coller juste en dessous tout en laissant une ligne vide afin de séparer le dernier du nouveau .
Voici mon code qui ne fonctionne pas et surtout même si ça marchais ce serait possible que pour la selection du tableau allant de A1 a GJ18 or moi je veux utiliser cela a chaque fois c'est a dire copier le dernier tableau qui changera forcement qui deviendra l'avant dernier donc je ne peux pas preciser sa taille vu qu'elle est susceptible de changer
n'hesitez pas a me poser des questions si ce n'est pas clair

Voici mon code qui me genere erreur d'execution 1004

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub nadounette()
 
dim b as integer
' on demande combien de tableau on veut coller
b = InputBox("Entrez le nombre de tableaux nécessaire?")
 
 
Range("A1:GJ18").Select ' 
Selection.Copy
'on copie
 
 
 
Range("A65536").End(xlUp).Offset(2, 0).Select
ActiveSheet.Paste
 
 
End Sub

merci mes amis informaticien !!!

[Invité]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Option Explicit
 
Private Sub CopierTableau()
 
  Dim intLng As Integer, intDeb As Integer, intCol As Integer
 
  With ActiveSheet
 
    intLng = .Range("A" & .Rows.Count).End(xlUp).Row
    intDeb = .Cells(intLng, 1).End(xlUp).Row
    intCol = .Cells(1, .Cells.Columns.Count).End(xlToLeft).Column
 
    .Range(.Cells(intDeb, 1), .Cells(intLng, intCol)).Copy
    .Cells(intLng, 1).Offset(2, 0).PasteSpecial
 
  End With
 
End Sub

[VinceVBA]

Autre méthode:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub nadounette()
 
    Dim b, i, Ligne, Colonne As Integer
    Ligne = 0
    Colonne = 0
 
    ' on demande combien de tableau on veut coller
    b = InputBox("Entrez le nombre de tableaux nécessaire?")
 
    ' calcul du nombre de lignes du 1er tableau
    While ActiveWorkbook.Worksheets(1).Range("A1").Offset(Ligne, 0) <> ""
        Ligne = Ligne + 1
    Wend
 
    ' calcul du nombre de colonnes du 1er tableau
    While ActiveWorkbook.Worksheets(1).Range("A1").Offset(0, Colonne) <> ""
        Colonne = Colonne + 1
    Wend
 
    ' Copie du tableau
    ActiveWorkbook.Worksheets(1).Range(Cells(1, 1), Cells(Ligne, Colonne)).Copy
 
    ' Collage du(des) tableau(x)
    For i = 1 To b
        ActiveWorkbook.Worksheets(1).Cells((i * Ligne) + (i + 1), 1).PasteSpecial
    Next i
 
 
End Sub

[Marc-L]

Bonjour,

ne pas oublier la propriété CurrentRegion allégeant le code …

[Invité]

Pour copier plusieurs tableaux d'un seul coup:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
 
Private Sub CopierTableau()
 
  Dim intLng As Integer, intDeb As Integer, intCol As Integer
  Dim intQue As Integer, i As Integer
 
  intQue = InputBox("Entrez le nombre de tableaux nécessaires:")
 
  For i = 1 To intQue
   With ActiveSheet
 
     intLng = .Range("A" & .Rows.Count).End(xlUp).Row
     intDeb = .Cells(intLng, 1).End(xlUp).Row
     intCol = .Cells(1, .Cells.Columns.Count).End(xlToLeft).Column
 
     .Range(.Cells(intDeb, 1), .Cells(intLng, intCol)).Copy
     .Cells(intLng, 1).Offset(2, 0).PasteSpecial
 
   End With
  Next i
 
End Sub

Suite à la remarque pertinente de 'Marc-L':

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Option Explicit
 
Private Sub CopierTableau()
 
  Dim intLng As Integer, intQue As Integer, i As Integer
 
  intQue = InputBox("Entrez le nombre de tableaux nécessaires:")
 
  For i = 1 To intQue
    With ActiveSheet
 
      intLng = .Range("A" & .Rows.Count).End(xlUp).Row
      .Cells(intLng, 1).CurrentRegion.Copy .Cells(intLng, 1).Offset(2, 0)
 
    End With
  Next i
 
End Sub

[Marc-L]

[…] copier le dernier tableau et le coller juste en dessous tout en laissant une ligne vide afin de séparer le dernier du nouveau .

Donc la copie peut se faire en une seule commande (s'il n'y a pas de trou entre les colonnes) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub DemoCopieDernierTableau()
    With ActiveSheet.UsedRange.Cells(ActiveSheet.UsedRange.Cells.Count).CurrentRegion
        .Copy Cells(.Rows(.Rows.Count).Row + 2, .Columns(1).Column)
    End With
End Sub

Précision : à partir de la version 2007, préférer la propriété CountLarge à la place de Count pour l'objet Cells …


__________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …


__________________________________________________________________________________________
A celle qui dit que les hommes sont tous pareils, lui répondre qu'il ne fallait pas tous les essayer !

[Nadounette123]

Merci de votre aides les amis !!!! mille merci