Discussion :

[Didpa]

Bonjour

Voilà, j'ai une liste d'articles et sa quantité consommé (Ticket de caisse), dans une feuille, j'aimerais le récupérer ans une autre feuille, sur une ligne pour faire un récap des consommation de chaque clients.

J'espère avoir été clair.

Voilà ce que j'ai en ce moment, mais pour moi il y a certainement quelque chose de plus efficace que du copié/collé

Cordialement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Sub recap()
'--------------------Rempli la feuille Recap (Credit, Carte, Espece)------------------
 
'---------------------------------Note les consommations-------------------------------------------
 Application.ScreenUpdating = False
 Worksheets("Recap").Activate 'selectionne la feuille Recap
    Range("A65536").End(xlUp).Offset(1, 0).Select
 ancienneDette = CaisseEnregistreuse.Lab_Dette.Caption
 
    ActiveCell.Value = CDate(Date)
    ActiveCell.Offset(0, 1).Value = Time
    ActiveCell.Offset(0, 2) = CaisseEnregistreuse.Lab_Serveur
    ActiveCell.Offset(0, 3) = CaisseEnregistreuse.Lab_Client
    If ancienneDette = "" Then
    Else
    ActiveCell.Offset(0, 4) = CDec(ancienneDette)
    End If
    ActiveCell.Offset(0, 5) = CaisseEnregistreuse.Lab_Reglement.Caption
    ActiveCell.Offset(0, 6) = CDec(CaisseEnregistreuse.Lab_Total)
    ActiveCell.Offset(0, 7).FormulaR1C1 = "=Ticket!R13C1 &"" - ""&Ticket!R13C2"
    ActiveCell.Offset(0, 8).FormulaR1C1 = "=Ticket!R14C1 &"" - ""&Ticket!R14C2"
    ActiveCell.Offset(0, 9).FormulaR1C1 = "=Ticket!R15C1 &"" - ""&Ticket!R15C2"
    ActiveCell.Offset(0, 10).FormulaR1C1 = "=Ticket!R16C1 &"" - ""&Ticket!R16C2"
    ActiveCell.Offset(0, 11).FormulaR1C1 = "=Ticket!R17C1 &"" - ""&Ticket!R17C2"
    ActiveCell.Offset(0, 12).FormulaR1C1 = "=Ticket!R18C1 &"" - ""&Ticket!R18C2"
    ActiveCell.Offset(0, 13).FormulaR1C1 = "=Ticket!R19C1 &"" - ""&Ticket!R19C2"
    ActiveCell.Offset(0, 14).FormulaR1C1 = "=Ticket!R20C1 &"" - ""&Ticket!R20C2"
    ActiveCell.Offset(0, 15).FormulaR1C1 = "=Ticket!R21C1 &"" - ""&Ticket!R21C2"
    ActiveCell.Offset(0, 16).FormulaR1C1 = "=Ticket!R22C1 &"" - ""&Ticket!R22C2"
    ActiveCell.Offset(0, 17).FormulaR1C1 = "=Ticket!R23C1 &"" - ""&Ticket!R23C2"
    ActiveCell.Offset(0, 18).FormulaR1C1 = "=Ticket!R24C1 &"" - ""&Ticket!R24C2"
    ActiveCell.Offset(0, 19).FormulaR1C1 = "=Ticket!R25C1 &"" - ""&Ticket!R25C2"
 
ActiveCell.Range(Cells(, 7), Cells(, 19)).Select
Selection.Copy
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
ActiveWorkbook.Save
Application.ScreenUpdating = True
End Sub

[NicolasST]

Bonjour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
    ActiveCell.Value = CDate(Date)
    ActiveCell.Offset(0, 1).Value = Time
    ActiveCell.Offset(0, 2) = CaisseEnregistreuse.Lab_Serveur
    ActiveCell.Offset(0, 3) = CaisseEnregistreuse.Lab_Client
    If ancienneDette = "" Then
    Else
    ActiveCell.Offset(0, 4) = CDec(ancienneDette)
    End If
    ActiveCell.Offset(0, 5) = CaisseEnregistreuse.Lab_Reglement.Caption
    ActiveCell.Offset(0, 6) = CDec(CaisseEnregistreuse.Lab_Total)
    ActiveCell.Offset(0, 7).FormulaR1C1 = "=Ticket!R13C1 &"" - ""&Ticket!R13C2"
    ActiveCell.Offset(0, 8).FormulaR1C1 = "=Ticket!R14C1 &"" - ""&Ticket!R14C2"
    ActiveCell.Offset(0, 9).FormulaR1C1 = "=Ticket!R15C1 &"" - ""&Ticket!R15C2"
    ActiveCell.Offset(0, 10).FormulaR1C1 = "=Ticket!R16C1 &"" - ""&Ticket!R16C2"
    ActiveCell.Offset(0, 11).FormulaR1C1 = "=Ticket!R17C1 &"" - ""&Ticket!R17C2"
    ActiveCell.Offset(0, 12).FormulaR1C1 = "=Ticket!R18C1 &"" - ""&Ticket!R18C2"
    ActiveCell.Offset(0, 13).FormulaR1C1 = "=Ticket!R19C1 &"" - ""&Ticket!R19C2"
    ActiveCell.Offset(0, 14).FormulaR1C1 = "=Ticket!R20C1 &"" - ""&Ticket!R20C2"
    ActiveCell.Offset(0, 15).FormulaR1C1 = "=Ticket!R21C1 &"" - ""&Ticket!R21C2"
    ActiveCell.Offset(0, 16).FormulaR1C1 = "=Ticket!R22C1 &"" - ""&Ticket!R22C2"
    ActiveCell.Offset(0, 17).FormulaR1C1 = "=Ticket!R23C1 &"" - ""&Ticket!R23C2"
    ActiveCell.Offset(0, 18).FormulaR1C1 = "=Ticket!R24C1 &"" - ""&Ticket!R24C2"
    ActiveCell.Offset(0, 19).FormulaR1C1 = "=Ticket!R25C1 &"" - ""&Ticket!R25C2"

Essai ce code dans un premier temps.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
 
 With ActiveCell
    .Value = CDate(Date)
    .Offset(0, 1).Value = Time
    .Offset(0, 2) = CaisseEnregistreuse.Lab_Serveur
    .Offset(0, 3) = CaisseEnregistreuse.Lab_Client
    If IsEmpty(ancienneDette) Then .Offset(0, 4) = CDec(ancienneDette)
 
    .Offset(0, 5) = CaisseEnregistreuse.Lab_Reglement.Caption
    ActiveCell.Offset(0, 6) = CDec(CaisseEnregistreuse.Lab_Total)
    Range(.Offset(0, 7), .Offset(0, 19)).FormulaArray = "=TRANSPOSE(Ticket!A13:A25) &"" - ""&TRANSPOSE(Ticket!B13:B25)"
End With

[Qwazerty]

Salut

Un conseil prend garde à l'utilisation de ActiveCell, ActiveWorkbook et leur petits amis.
Si lors du déroulement de ta macro, pour une raison x ou y, un autre fichier Excel vient à passer au 1er plan (ouverture d'un fichier ou si tu sélectionnes un autre fichier déjà ouvert) ta macro continuera à s’exécuter sur cet autre fichier... et la bonjour les dégâts...
Appeler Range(...) ou Cells(...) ou Sheets(...) sans préciser sur quel classeur et quel onglet tu travailles n'est pas une bonne habitude pour les même raisons.

Si ta macro travaille sur un autre fichier, il faut alors déclarer une variable qui représente cet autre fichier.
Si ta macro ne travail que sur le fichier qui la contient, préfère une structure de code dans ce genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Option Explicit 'force à déclarer les variables
 
 
Sub recap()
'--------------------Rempli la feuille Recap (Credit, Carte, Espece)------------------
 
'---------------------------------Note les consommations-------------------------------------------
 
'Déclaration des variables
Dim ancienneDette As String
Dim iCell As Integer
 
'Initialisation des variables
ancienneDette = CaisseEnregistreuse.Lab_Dette.Caption
 
 
Application.ScreenUpdating = False
'Worksheets("Recap").Activate 'selectionne la feuille Recap 'unitil d'afficher une feuille pour travailler dessus
 
'On pointe la feuille sur laquelle on va travailler
With ThisWorkbook.Sheets("Recap")
    'On point la 1ère cellule vide de la colonne A
    With .Cells(.Rows.Count, "A").End(xlUp).Offset(1, 0) '.Select
 
        .Value = CDate(Date)
        .Offset(0, 1).Value = Time
        .Offset(0, 2) = CaisseEnregistreuse.Lab_Serveur
        .Offset(0, 3) = CaisseEnregistreuse.Lab_Client
 
        If ancienneDette <> "" Then .Offset(0, 4) = CDec(ancienneDette)
 
        .Offset(0, 5) = CaisseEnregistreuse.Lab_Reglement.Caption
        .Offset(0, 6) = CDec(CaisseEnregistreuse.Lab_Total)
 
        'Tu travailles sur des colonnes allant de 7 à 19 et sur ton autre feuille des lignes allant de 13 à 25
        For iCell = 7 To 19
            .Offset(0, iCell).FormulaR1C1 = "=Ticket!R" & CStr(iCell + 6) & "C1 &"" - ""& Ticket!R" & CStr(iCell + 6) & "C2"
        Next
 
    End With
End With
 
'Pour la suite précise ce que tu veux et la structure ou se trouvent les données,
'je ne comprend pas exactement ce que tu veux faire,
'tu sembles vouloir transposer tes données mais le nombre de lignes est-il toujours identique et placé au même endroit?
ActiveCell.Range(Cells(, 7), Cells(, 19)).Select
Selection.Copy
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
 
'ActiveWorkbook.Save
'A moins que ta macro ne travaille sur un autre classeur préfère plutôt
ThisWorkbook.Save
Application.ScreenUpdating = True
End Sub

Pour la dernière partie de ton code, je ne sais pas si tu faisais juste des essais de transposition (comme semble l'avoir compris NicolasST + le titre de ton post).

@NicolasST : Intéressant l'utilisation de FormulaArray.


++
Qwaz