Discussion :

[xavierdestev]

Bonjour

Je n'arrive pas à avoir la forme en pointe que devrait avoir cette fonction.
Le plot ne m'affiche rien. Merci d'avance.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
function y=phi(x,N,i)
h=1./(N+1);
if (i-1)*h <= x & x <= i*h then
    y=(x-(i-1)*h)/h;
elseif i*h <= x & x <= (i+1)*h then
    y=((i+1)*h -x)/h;
else
    y=0;
end
endfunction
 
x=[0:0.1:2*%pi]';
//simple plot
plot2d(phi(x,10,2));

[Jerome Briot]

Si je comprend bien :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
function y = phi(x,N,i)
    h = 1.0/(N+1)
    for k = 1:size(x,"*")
        if (i-1)*h <= x(k) & x(k) <= i*h then
            y(k) = (x(k)-(i-1)*h)/h;
        elseif i*h <= x(k) & x(k) <= (i+1)*h then
            y(k) = ((i+1)*h -x(k))/h;
        else
            y(k) = 0;
        end
    end
 
endfunction
 
x = [0:0.1:2*%pi]';
//simple plot
plot2d(x, phi(x,10,2));

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
function y = phi(x,N,i)
 
    h = 1.0/(N+1);
 
    nx = size(x,"*");
    y = zeros(1,nx);
 
    for k = 1:nx
        if (i-1)*h <= x(k) & x(k) <= i*h then
            y(k) = (x(k)-(i-1)*h)/h;
        elseif i*h <= x(k) & x(k) <= (i+1)*h then
            y(k) = ((i+1)*h -x(k))/h;
        end
    end
 
endfunction
 
x = 0:0.1:2*%pi;
//simple plot
plot2d(x, phi(x,10,2));

ou encore :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
function y = phi(x,N,i)
 
    h = 1.0/(N+1);
 
    y = (((i-1)*h <= x & x <= i*h).*(x-(i-1)*h) + (i*h <= x & x <= (i+1)*h).*((i+1)*h -x))/h;
 
endfunction
 
x = 0:0.1:2*%pi;
//simple plot
plot2d(x, phi(x,10,2));

[xavierdestev]

Merci.

C'est cool comme réponse.
En fait, en hauteur c'est sensé allé jusqu'à 1 et de 0 à 1 en abscisse.

[Jerome Briot]

En fait, en hauteur c'est sensé allé jusqu'à 1 et de 0 à 1 en abscisse.

Ajoute des points dans le vecteur x en réduisant le pas

Par contre, il n'est pas sûr que tu trouve exactement une valeur égale à 1.

Pour les abscisses, x est dans l'intervalle [0 2pi], non ?

[xavierdestev]

Merci.

Je vais changer l'implémentation ce weekend.
C'est vraiment trop lourd pour avoir un graphique de la fonction.