Discussion :

[ALEX80800]

Bonjour,

Je voudrais sur double click d'un onglet déclencher une boite dialogue proposant une liste correspondant à des mois et lui affecter la valeur choisie.

Dans la gestion des événements feuilles, je n'ai pas trouver mon bonheur.

où existe-t-il un moyen détourné pour déclencher cette macro?
Et là je n'ai pas la logique.

Merci de votre aide

[PMO2017]

Bonjour,

Une autre voie consiste à utiliser un menu contextuel obtenu avec un clic droit sur l'onglet (Tab).
Si c'est bien cela qu'il fallait comprendre, essayez la démarche ci-après :
1) Copiez le code suivant dans un module Standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Const MENU_CONTEXT_CAPTION As String = "Choisir un mois..."
 
Dim Mois As Variant   'portée Module
 
Sub MenuContextuel(Optional dummy As Byte)
Dim BAR As CommandBar
Dim C As CommandBarControl
Dim CB As CommandBarComboBox
Dim i&
'---
Mois = Array("Janvier", "Février", "Mars", "Avril", "Mai", "Juin", "Juillet", "Août", "Septembre", "Octobre", "Novembre", "Décembre")
Call DeleteMenuContextuel
Set BAR = Application.CommandBars("Ply")
Set C = BAR.Controls.Add(Type:=msoControlPopup, Before:=1, Temporary:=True)
With C
  .Caption = MENU_CONTEXT_CAPTION
  .Tag = "My_Cell_Control_Tag"
  For i& = LBound(Mois) To UBound(Mois)
    With .Controls.Add(Type:=msoControlButton)
      .Caption = Mois(i&)
      .OnAction = "'NomFeuille " & i& & "'"
    End With
  Next i&
End With
BAR.Controls(2).BeginGroup = True
End Sub
 
Sub DeleteMenuContextuel(Optional dummy As Byte)
On Error Resume Next
Application.CommandBars("Ply").Controls(MENU_CONTEXT_CAPTION).Delete
End Sub
 
Sub NomFeuille(Index As Integer)
Dim S As Worksheet
Dim A$
Dim i&
A$ = Mois(Index)
If ActiveSheet.Name = A$ Then Exit Sub
On Error Resume Next
Set S = ThisWorkbook.Sheets(A$)
If Err = 0 Then
  Do
    Err.Clear
    i& = i& + 1
    A$ = Mois(Index) & Format(i&, "00")
    Set S = ThisWorkbook.Sheets(A$)
  Loop Until Err <> 0
End If
Err.Clear
ActiveSheet.Name = A$
End Sub

2) Copiez le code suivant dans la fenêtre de code de ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Workbook_Open()
Call MenuContextuel
End Sub
 
Private Sub Workbook_Activate()
Call MenuContextuel
End Sub
 
Private Sub Workbook_Deactivate()
Call DeleteMenuContextuel
End Sub

Lancer la procédure Workbook_Activate (ce sera automatique par la suite). En cliquant droit sur un onglet apparaîtra le menu contextuel habituel avec
un nouvel item déroulant ("Choisir un mois..."). Après avoir cliqué sur un mois, la feuille active en sera renommée (Toujours si c'est bien cela qu'il fallait comprendre).

[grisan29]

bonjour PM02017

juste pour dire pour cette procédure de renommage d'onglets qui mérite largement

Pascal

[ALEX80800]

bonjour PM02017,

Effectivement le menu contextuel est un super paliatif.

J'ai entre-temps effectuer ma réflexion sur une liste d"roulante dans une cellule.

Mai je cours de ce pas à ta solution ou la combinaison des 2

Mais in faut pas que j'oublie d'affecter la value du nom du fichier à la liste déroulante.

Un grand Grand GRand GRANd GRAND merci!!!!

Résolu exponentiel 10000000000000000000000000000000000000