Discussion :

[Rob's]

Bonjour à tous,

J'ai un soucis avec mon programme vba.
En fait, je veux faire une saisie semi-automatique avec une de mes combo box (celle qui se nomme "Defaut")mais, lorsque je valide ma saisie, la liste déroulante reste apparente et ne se ferme pas avec mon Userform...

Quelqu'un pourrait il me dire comment faire pour que cette liste disparaisse svp?

Voici mon programme:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Private Sub Defaut_Change()
On Error Resume Next
 
Dim Trouve As Boolean
Dim i As Integer
Dim j As Integer
 
For i = Defaut.ListCount - 1 To 0 Step -1
    Defaut.RemoveItem (i)
Next i
 
Trouve = False
j = -1
 
For i = 1 To 34
    If LCase(Left$(Worksheets("Tables_liste").Range("M" & i).Text, Len(Defaut.Text))) = LCase(Defaut.Text) Then
        Trouve = True
        j = j + 1
        Defaut.AddItem
        Defaut.List(j, 0) = Worksheets("Tables_liste").Range("M" & i).Text
    End If
Next i
 
'Mettre à jour la liste déroulante ouverte
 
If Trouve = True Then
    Defaut.Enabled = False
    Defaut.Enabled = True
    Defaut.SetFocus
    Defaut.DropDown
Else
    Defaut.Enabled = False
    Defaut.Enabled = True
    Defaut.SetFocus
End If
 
End Sub
 
Private Sub UserForm1_Initialize()
 
Dim i As Integer
 
For i = 1 To 34
    Defaut.AddItem
    Defaut.List(i - 1, 0) = Worksheets("Tables_liste").Range("M" & i).Text
Next i
 
Defaut.SetFocus
 
End Sub

Merci d'avance

Rob's

[PMO2017]

Bonjour,

Une piste avec la démarche suivante
1) Créez un UserForm1
2) Insérez 1 ComboBox (propriété (Name) = Defaut) et 1 CommandButton1
3) Dans une feuille nommée "Tables_liste" mettez des données à partir de M1 jusqu'à Mx
4) Copez le code suivant dans la fenêtre de code du UserForm

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Private Sub CommandButton1_Click()
MsgBox Defaut.Value   'Message de la sélection
Call InitDefaut
Defaut.Value = ""
Defaut.SetFocus
End Sub
 
Private Sub Defaut_Change()
Dim i As Integer
Dim A$
'---
Defaut.MatchEntry = fmMatchEntryNone
A$ = LCase(Defaut.Value)
'--- Mettre à jour la liste déroulante ouverte ---
If A$ <> "" Then
  For i = Defaut.ListCount To 1 Step -1
    If LCase(Left$(Defaut.List(i - 1, 0), Len(A$))) <> A$ Then Defaut.RemoveItem (i - 1)
  Next i
Else
  Call InitDefaut
End If
'---
If Defaut.ListCount = 1 Then Defaut = Defaut.List(0, 0)
End Sub
 
Private Sub UserForm_Initialize()
Dim i As Integer
Defaut.MatchEntry = fmMatchEntryNone '///ajout
Call InitDefaut
Defaut.SetFocus
End Sub
 
Private Sub InitDefaut()
Dim S As Worksheet
Dim var As Variant
'---
Set S = Worksheets("Tables_liste")
'--- le Variant, tel qu'il est interprété par Excel, est un tableau à 2 dimensions ---
var = S.Range("M1:M" & S.[m65536].End(xlUp).Row & "") ' la plage "M1:M dernière ligne"
Defaut.List = var
End Sub

Je mets le classeur exemple en pièce jointe pour faciliter.