Discussion :

[hackoofr]

Ma Question : Comment peut-on tuer toutes les instances de "Wscript.exe" sauf une qui est lancée par mon script VBS ?
J'ai commencé à faire un petit script, mais je suis bloqué au niveau de la ligne 19 Erreur de syntaxe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Set oWMISrvc = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\.\root\cimv2")
 
sProcName = Mid(wsh.fullname, InstrRev(wsh.fullname, "\") + 1)
 
Set cProcesses = oWMISrvc.ExecQuery( _
"select * from win32_process where Name = '" & sProcName & "'")
 
For Each oProcess in cProcesses
    If Instr(lcase(oProcess.Commandline), lcase(wsh.scriptname)) < 0 Then
        wsh.echo oProcess.Commandline
        wsh.echo wsh.scriptname
    else
        Process2kill = Mid(oProcess.CommandLine,InStr(oProcess.CommandLine,""" """) + 2)
        Process2kill = Replace(Process2kill,chr(34),"")
        msgbox Process2kill 
        Set colItems = GetObject("winmgmts:").ExecQuery("Select * from Win32_Process " _
        & "where commandline like '" & Process2kill &"'",,48)
        For Each objItem in colItems 
            Wscript.Echo "Terminating script with this CommandLine: " & objItem.CommandLine
            objItem.Terminate()
        Next
    End If
Next
msgbox "ok"

[ProgElecT]

Salut

Peut être cela pourra t'aider, (Reprise dans la FAQ Comment lister les processus actifs ?)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Dim svc, sQuery, oproc
Dim ProgHote, MeProg
 
    'Hote =  WScript.exe, CScript.exe
    ProgHote =  Mid(WScript.FullName, InstrRev(WScript.FullName, "\") + 1)
    MeProg = WScript.ScriptFullName
    Wscript.Echo "****************************************************************************" & vbnewline _
                & "ProgHote: " & ProgHote & vbnewline _
                & "MeProg: " & MeProg & vbnewline _
                & "****************************************************************************" & vbnewline
    Set svc = GetObject("winmgmts:root\cimv2")
    sQuery = "select * from win32_process where Name = '" & ProgHote & "'"
    For Each oproc In svc.execquery(sQuery)
        If InStr(1, oproc.Properties_("commandLine"), MeProg, vbBinaryCompare) <> 0 Then
            'je conserve
            Wscript.Echo "A conserver: " & oproc.Properties_("commandLine") & vbnewline
            Else
            'supprimer le processus
            Wscript.Echo "Suppression de " & oproc.Properties_("commandLine") & vbnewline
            'oproc.Terminate()
        End If
    Next
    Set svc = Nothing
    MsgBox "Fin"

[hackoofr]

et pour l'aide
Bon j'ai trouvé une solution très simple dans un forum anglais, je vous la partage et le problème est ainsi comme ceci :
avec une simple boucle et un filtre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Set wmi = GetObject("winmgmts:root\cimv2")
Set cProcesses = wmi.ExecQuery("select * from win32_process where Name like '%wscript.exe%' AND NOT commandline like '%" & wsh.scriptname & "%'")
 
For Each oProcess in cProcesses
    wsh.echo oprocess.commandline
    oProcess.Terminate()
Next