Discussion :

[Invité]

Bonjour le forum,

Je viens vers vous parce que j'ai un soucis pour trouver des valeurs:
- dans la colonne D de la Feuil1 j'ai des dates un peu partout entre D2 et D601.
- dans la Feuil2 j'essai de récupérer ces dates en fonction de 2 critères: le mois et l'année.
J'ai essayé d'adapter une formule que l'on m'a donné mais en vain:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(LIGNE(Feuil1!A1)>SOMMEPROD(--(MOIS(col_D)=MOIS(B$3))*(ANNEE(col_D)=ANNEE(C$3)));"";INDEX(col_D;PETITE.VALEUR(SI(MOIS(col_D)=MOIS(B$3);SI(ANNEE(col_D)=ANNEE(C$3);LIGNE(col_D)-1;""));LIGNE(Feuil1!$A1))))

col_D:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(Feuil1!$D$2;;;EQUIV(9^9;Feuil1!$D$2:$D$601))

Je ne trouve pas l'erreur dans la formule, auriez-vous une idée ?
Merci à vous et bonne journée

Cdlt
aure_8

[canichon]

les formules c'est bien gentil mais elles ont leur limite...

est ce que vba "te fait peur" ??

[Invité]

Sincèrement je préfère l'utiliser le moins possible: d'abord parce que je suis un peu alergique au code info et puis dans mon cas le soucis c'est que ça a fonctionné une fois sur un fichier test. Mais impossible de la refaire fonctionner après l'aptation sur fichier :/.
Mais si il faut vraiment passer par le VBA soit ^^

[Piixx_e]

Salut aure_8 !

J'ai essayé d'adapter une formule que l'on m'a donné mais en vain

C'est quoi ta formule au juste ? Parce que sans que tu donnes la formule exprimée "normalement", personnellement j'aurais un peu de mal à t'aider

[Daniel.C]

Bonjour,

Ta formule est correcte; il faut seulement la valider de façon matricielle : tu cliques dans la formule, tu maintiens les touches Ctrl et Maj enfoncées et tu appuies sur Entrée (et tu relâches tout).

[Invité]

Ah ok, je ne savais comment il fallait s'y prendre. Maintenant oui, un grand merci!

Bonne journée et @+
Cdlt aure_8

[EngueEngue]

Un peu galère ta formule, this one est un peu plus simple; Appelle ton range D dateee.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(dateee;PETITE.VALEUR(SI((ANNEE(C3)=ANNEE(dateee))*(MOIS(B3)=MOIS(dateee))=1;LIGNE(dateee)-MIN(LIGNE(dateee))+1);1))

[Daniel.C]

Bonjour EngueEngue,

La formule est peut-être "galère", mais elle a l'avantage de ne pas renvoyer des erreurs quand tu tires la formule vers le bas.

[EngueEngue]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(dateee;PETITE.VALEUR(SI((ANNEE(C3)=ANNEE(dateee))*(MOIS(B3)=MOIS(dateee))=1;LIGNE(dateee)-MIN(LIGNE(dateee))+1);1))

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(dateee;PETITE.VALEUR(SI((ANNEE(C3)=ANNEE(dateee))*(MOIS(B3)=MOIS(dateee))=1;LIGNE(dateee)-MIN(LIGNE(dateee))+1);2))

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(dateee;PETITE.VALEUR(SI((ANNEE(C3)=ANNEE(dateee))*(MOIS(B3)=MOIS(dateee))=1;LIGNE(dateee)-MIN(LIGNE(dateee))+1);3))

Couplée avec un sierr... Vla le travail