Discussion :

[olosta]

Bonjour,

Depuis Access, je cherche à exporter une table de façon simple, dans Excel à un endroit bien précis (ex: a partir de C5).
J'ai utilisé les fonctions :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
DoCmd.TransferSpreadsheet
DoCmd.RunSavedImportExport
DoCmd.OutputTo

mais sans succès, car je n'arrive pas à placer dans une plage de cellule.

J'utilise Access 2010 et Excel 2010 pour info.

Merci d'avance.

[CoriS FrosT]

salut

j'utilise ça pour l'export

(tu dois rajouter la référence librairie Microsoft Access XX Object Library avant)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Public Sub export2Excel(sTemplate As String, sSheetName As String, sPath2Export As String, sFileName2Export As String)
    Dim oExcel As New Excel.Application
    Dim WB As New Excel.workbook
    Dim WS As Excel.Worksheet
    Dim rng As Excel.Range
 
    Dim rst As DAO.Recordset
    Dim sSQL As String
 
    sSQL = "SELECT * FROM TA_TABLE"
 
    With oExcel
        .Visible = False
        Set WB = .Workbooks.Add(sTemplate) 'ton chemin vers le template excel
 
        With WB
            Set WS = WB.Worksheets("Nom de ta feuille template")
            With WS
                Set rst = CurrentDb.OpenRecordset(sSQL, dbOpenForwardOnly, dbReadOnly)
                Set rng = .Range("C5")
                rng.CopyFromRecordset rst
                rst.Close
 
'tu peux formater ta sortie excel ici pour faire jolie...
 
                .Name = sSheetName 'tu renommes la feuille
            End With
            .SaveAs FileName:=sPath2Export & sFileName2Export, FileFormat:=52
        End With
 
        .QUIT
    End With
 
    Set WB = Nothing
    Set WS = Nothing
    Set rst = Nothing
    Set rng = Nothing
End Sub

Tu peux utiliser un modèle excel.

Dans mon cas, pour éviter que le fichier template excel ne se perde par mégarde par les utilisateurs, je l'ajoute dans une table que j'extraie à l'ouverture de la base access.

@++