Discussion :

[illight]

Bonjour


J'aurai besoin de vos lumières pour améliorer une de mes fonctions que j'ai faite pour trouver la lettre d'une colonne citée. Voici la fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Function LettreColonne(NumCol As Long) As String
'fonction qui donne la lettre en fonction du numero de colonne
Dim reste, quotient As Long
quotient = Int(NumCol / 26)
reste = NumCol Mod 26
If quotient = 0 And reste = 0 Then
    Exit Function
End If
If quotient = 0 Then
    LettreColonne = Chr(64 + reste)
Else
    If reste = 0 Then
        quotient = quotient - 1
        If quotient = 0 Then
            LettreColonne = Chr(64 + 26)
        Else
            LettreColonne = Chr(64 + quotient) & Chr(64 + 26)
        End If
    Else
        LettreColonne = Chr(64 + quotient) & Chr(64 + reste)
    End If
End If
End Function

Pour les grands connaisseurs, je suis sur que vous allez avoir peur en voyant ça mais bon, justement, je voudrais pouvoir l'écrire plus simplement.

Je pense qu'il faut utiliser le ".address", mais je ne sais pas torp comment l'implémenter dans ce que j'ai écrit car normalement le .address s'utilise directement sur un sélection de cellule (un Range). Sauf que là, je l'utilise sur un nombre directement.

Un exemple d'utilisation de cette fonction pour une fonction (que j'ai créé aussi ) de création d'une liste :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Public Sub MakeListes(NomFeuille As String, NomListe As String, NbreLigne As Long, nbreColonnes As Long)
ActiveWorkbook.Names.Add Name:=NomListe, RefersTo:="='" & NomFeuille & "'!$A$1:$" & LettreColonne(nbreColonnes) & "$" & NbreLigne
End Sub

En vous remerciant par avance, je suis à votre disposition pour toute question/suggestion.

[mercatog]

C'est assez folle comme idée de chercher la(es) lettre(s) correspondant à une colonne alors que le n° de la colonne suffit largement.

pour ton exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Public Sub MakeListes(NomFeuille As String, NomListe As String, NbreLigne As Long, nbreColonnes As Long)
 
ActiveWorkbook.Names.Add Name:=NomListe, RefersTo:="='" & NomFeuille & "'!$A$1:" & Cells(NbreLigne, nbreColonnes).Address
End Sub

[illight]

Je te remercie pour ta réponse Effectivement, c'est beaucoup plus simple j'aime bien me compliquer la vie

Il faudrait que je trouve un exemple un peu parlant, mais j'en ai pas sous la main.

Merci en tout cas

[mercatog]

Je ne vois pas d'exemple qui nécessite de connaître la lettre correspondant à la colonne du moment que tu peux t'en sortir avec Address ou Column

[parmi]

Bonjour,

Je ne vois pas non plus l'utilité... mais bon... tu pourrais y aller comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
    Dim I As Byte
    Dim TempAdresse As String, Adresse As String
 
    TempAdresse = ActiveCell.Address(False, False)
    For I = 1 To Len(TempAdresse)
        If Not IsNumeric(Mid(TempAdresse, I, 1)) Then
            Adresse = Adresse & Mid(TempAdresse, I, 1)
        End If
    Next
 
    MsgBox Adresse

[AlainTech]

Bonjour à tous,

Je n'en vois pas non plus l'utilité mais j'ai trouvé ça amusant...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Test()
  MsgBox ColumnLetter(5)
  MsgBox ColumnLetter(255)
End Sub
 
Function ColumnLetter(value As Integer) As String
  ColumnLetter = Split(Columns(value).Address(False, False), ":")(0)
End Function

Evidemment, si on est payé à la ligne de code, ça n'est pas rentable...

[parmi]

Bien vu

[illight]

Et le gagnant est => Alain !

En tout cas, cette discussion a eu le mérite de vous amuser

[illight]

Je suis tombé sur un cas où, pour moi, j'en aurai besoin, mais je suis sur que vous allez me trouver une solution sans me prendre la tête

Je voudrais que dans un tableau d'une feuille particulière, trouver la dernière colonne, la "tirer" (l'autofill quoi), puis supprimer les valeurs. Pour cela, j'utilise la fonction d'AlainTeck pour savoir à partir d'où je tire, jusqu'où, et où je supprimer mes valeurs :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Dim NomF As Worksheet
Set NomF = Worksheets("Stat_globale")
'numero de la dernière colonne
j = NomF.Range("A7").End(xlToRight).Column
'selection
Range(ColumnLetter(j) & "7:" & ColumnLetter(j) & "29").Select
'tirage jusqu'à j+1
Selection.AutoFill Destination:=Range(ColumnLetter(j) & "7:" & ColumnLetter(j+1) & "29"), Type:=xlFillDefault
'suppression des valeurs sans le titre
Range(ColumnLetter(j+1) & "8:" & ColumnLetter(j+1) & "29").ClearContents

j'ai essayé de faire autrement, en utilisant le fameux .Address, mais je blique lorsqu'il faut que j'aille à la dernière colonne "+1". Voici le début du code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim NomF As Worksheet
Set NomF = Worksheets("Stat_globale")
'numero de la dernière colonne
j = NomF.Range("A7").End(xlToRight).Adress
'selection => comment dire de sélectionner sur la même colonne jusqu'à la ligne 29 ?
Range(j & ":" & ColumnLetter(j) & "29").Select
'tirage jusqu'à j+1
=> là, je bloque..

Merci pour vos lumières

[parmi]

Et si tu procédais comme ceci plutôt ?
C'est du moins la façon dont je procéderais...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    Dim Colonne As Long
 
    Colonne = Cells(7, Columns.Count).End(xlToLeft).Column
    Range(Cells(7, Colonne), Cells(29, Colonne)).Select

[illight]

Par rapport à ta formule, si la colonne A et B est vide, et que, par exemple, mon tableau commence à la colonne C, ta formule ne fonctionne plus ??

[Docmarti]

...

j'ai essayé de faire autrement, en utilisant le fameux .Address, mais je blique lorsqu'il faut que j'aille à la dernière colonne "+1".
...

Merci pour vos lumières

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test2()
 
Dim NomF As Worksheet
Set NomF = Worksheets("Stat_globale")
 
LignesIncrement = 29 - 7
 
Set c = NomF.Range("A7").End(xlToRight)
 
Range(c.Offset(0, 0), c.Offset(29 - 7, 0)).AutoFill Destination:=Range(c.Offset(0, 0), c.Offset(29 - 7, 1)), Type:=xlFillDefault
 
'suppression des valeurs sans le titre
 
Range(c.Offset(1, 1), c.Offset(29 - 7, 1)).ClearContents
End Sub

Cordialement

Docmarti

[illight]

Je pense jamais à utiliser la fonction offset, qui je pense me permettrai de faire des miracles certaines fois. J'essaye ton truc cet après-midi

Merci

[Oliv-]

Je ne vois pas d'exemple qui nécessite de connaître la lettre correspondant à la colonne du moment que tu peux t'en sortir avec Address ou Column

Bonjour,
Par exemple pour l'afficher dans un userform ou inputbox...

[illight]

ça marche Thanks