Discussion :

[phanoulevoyou]

Bonjour,

je souhaiterai calculer une ligne contenant différentes lettres ayant une même valeur ou une valeur différente.

J'ai déjà une formule qui fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(((A3:D3="G")+(A3:D3="M")+(A3:D3="HP")+(A3:D3="V")+(A3:D3="GI")+(A3:D3="GL"))*24+(A3:D3="Gj")*12+(A3:D3="S")*8)

j'aimerai juste savoir s'il est possible de simplifier cette formule afin de ne pas répéter pour les lettres ayant la valeur identique le code (a3:d3 = "x")+...

Est-il possible de nommer une zone et de donner une valeur à chaque élément de cette zone pour au final en faire le calcul ?

Je vous joins le fichier test.

Merci de votre aide,

Cdlt, PLV

[papouclo]

Bonjour,
Une formule un tout petit peu plus courte en E3 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD($N$1:$P$1*(($N$2:$P$7=A3)+($N$2:$P$7=B3)+($N$2:$P$7=C3)+($N$2:$P$7=D3)))

On obtient ainsi 72 (plutôt que 60).
Cordialement
Claude

[QuestVba]

Bonjour,

Voici un essai

Plage dynamique
Lettre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 =DECALER(Feuil1!$R$2;0;0;NBVAL(Feuil1!$R:$R)-1;1)

Code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 =DECALER(Feuil1!$S$2;0;0;NBVAL(Feuil1!$S:$S)-1;1)

Formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 =SOMMEPROD(NB.SI(A3:D3;Lettre)*1;Code)

[phanoulevoyou]

Bonjour Claude,

Alors merci pour ta formule, le hic c'est que je pense qu'elle va me faire beaucoup d'écriture pour faire ma formule. Chaque cellule où se trouve une lettre
correspond à un jour soit 31 jour donc 31 colonnes, et dans mon exemple il n'y a pas la totalité de mes lettres pouvant avoir ces valeurs. Donc ta formule va être aussi longue que la mienne au final je pense.

Pour ce qui est du résultat de ma somme, c'est un peu de ma faute car dans ma formule j'ai omis de compter une donnée, le GN, qui équivaut à une 12H d'ou le 60 au lieu du 72.

Merci pour le temps passé et joyeux noël à toi et tes proches.

Cdlt, PLV

[phanoulevoyou]

Bonjour QuestVba,

merci pour ce beau cadeau de noël, c'est exactement ce que je souhaitais.
Il ne me reste plus qu'à décortiquer tes formules pour que je les comprenne histoire d'être moins bête.

Bonne journée, et joyeux noël à toi et tes proches.

Cdlt, PLV

[QuestVba]

Hello,

DECALER: permet de renvoyer une plage de cellules qui correspond à un nombre déterminé de lignes et de colonnes.

DECALER(réf;lignes;colonnes;hauteur;largeur)

• •réf : Correspond à la référence à partir de laquelle le décalage doit être effectué.
• •lignes : Correspond au nombre de lignes de décalage par rapport à la première celulle de la plage réf (la cellule supérieure gauche). Un chiffre positif correspond à un décalage vers le bas, un chiffre négatif correspond à un décalage vers le haut.
• •colonnes : Correspond au nombre de colonnes de décalage par rapport à la première celulle de la plage réf (la cellule supérieure gauche). Un chiffre positif correspond à un décalage vers la droite, un chiffre négatif correspond à un décalage vers la gauche
• •hauteur : Correspond au nombre de lignes de la plage de cellules qui doit être renvoyée par la fonction DECALER.
• •largeur : Correspond au nombre de colonnes de la plage de cellules qui doit être renvoyée par la fonction DECALER.

NBVAL : Permet de compter le nombre de cellules contenant des données dans une plage de cellules; permet de compter toutes les cellules qui ne sont pas vides.

Combinées, elles donnent une plage dynamique variable. Utile si tu ajjoutes des données....

[phanoulevoyou]

Merci QuestVba pour tes explications