Discussion :

[merlinus3000]

Bonjour à tous,

J'ai une liste déroulante que je tire d'une colonne, avec mise à jour automatique, selon la formule suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(Data!$C$1;1;0;NBVAL(Data!$C:$C)-1)

Mais certains éléments de cette liste changent de statut selon les moments, je ne souhaite donc pas qu'ils apparaissent.

La liste source serait du genre (colonne A -> colonne B)

Element 1 -> Actif
Element 2 -> Actif
Element 3 -> Inactif
Element 4 -> Actif
Etc.

Est-ce réalisable ? Et comment faire ?

Merci pour votre aide.

[Daniel.C]

Bonjour,

Les éléments étant en colonne A, mets en E1, par exemple (formule matricielle, à valider avec Ctrl+Maj+Entrée) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERR(PETITE.VALEUR(SI($B$1:$B$4="actif";LIGNE($A$1:$A$4));LIGNE(A1)));"!";INDEX($A$1:$A$4;PETITE.VALEUR(SI($B$1:$B$4="actif";LIGNE($A$1:$A$4));LIGNE(A1));1))

Reproduis vers le bas autant que la colonne A. Dans la validation, mets la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER($E$1;;;EQUIV("!";$E$1:$E$10;0)-1)

[merlinus3000]

Ca marche parfaitement bien, mais dès que je fais baisser tout d'une ligne, car j'ai des titres, il y a un petit couac.

Quel est le point à modifier afin que cela s'adapte ?

Merci d'avance

[Daniel.C]

Modifie la formule en E2 (matricielle) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERR(PETITE.VALEUR(SI($B$2:$B$5="actif";LIGNE($A$2:$A$5));LIGNE(A1)));"!";INDEX($A$1:$A$5;PETITE.VALEUR(SI($B$2:$B$5="actif";LIGNE($A$2:$A$5));LIGNE(A1));1))

et tire-la vers le bas.

[merlinus3000]

Modifie la formule en E2 (matricielle) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERR(PETITE.VALEUR(SI($B$2:$B$5="actif";LIGNE($A$2:$A$5));LIGNE(A1)));"!";INDEX($A$1:$A$5;PETITE.VALEUR(SI($B$2:$B$5="actif";LIGNE($A$2:$A$5));LIGNE(A1));1))

et tire-la vers le bas.

Ça marche pour le filtre !!!

Maintenant j'ai un souci avec la "Validation des données".

Elle fonctionne quand je suis sur la même feuille, mais dès que je change de feuille, pour mettre ma liste déroulante, ça ne fonctionne plus.

Y a-t-il moyen de remédier ou contourner cela ?

Merci

[Daniel.C]

Y a-t-il moyen de remédier ou contourner cela ?

Oui. Définis une plage nommée (la façon de faire dépend de ta version d'Excel). Probablement :
Menus Insertion, Nom, Définir; donne un nom à ta plage, par exemple "Plage" et dans "Fait référence à", mets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER($E$1;;;EQUIV("!";$E$1:$E$10;0)-1)

Valide. Dans la définition de la liste de validatiion, remplace la formule par le nom "=Plage" (sans les guillemets).

[merlinus3000]

J'ai fait les modifications suivantes aux codes et tout fonctionne à merveille :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERR(PETITE.VALEUR(SI($R$2:$R$200="Active";LIGNE($Q$2:$Q$200));LIGNE(Q1)));"!";INDEX($Q$1:$Q$200;PETITE.VALEUR(SI($R$2:$R$200="Active";LIGNE($Q$2:$Q$200));LIGNE(Q1));1))

J'ai mis les 200 lignes, même si je ne les utilise pas toutes. J'avais mis la colonne entière, mais cela générait trop de temps de calcul.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
=DECALER(Options!$S$2;;;EQUIV("!";Options!$S:$S;0)-2)

Et cela fonctionne parfaitement.

Merci beaucoup pour ton aide.

[Daniel.C]

C'est sûr que les formules matricielles sont des grosses consommatrices de ressources. Tu as même intérêt à définir avec un nom la plage dynamique s'ajustant automatiquement à tes données.