Avoir deux conditions dans la fonction If / If not

**Blend** · 31/12/2013, 12h10

Bonjour à tous,

J'ai un léger soucis qui, je pense, ne va pas vous poser de problème!
Sur cette ligne de code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
'la macro se déclenche à chaque fois qu'une valeur est entrée dans une cellule de la feuille
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Ligne As Variant
    'si la saisie concerne une colonne inférieure à 5 et que les saisies des colonnes A, B et D
    'ont été faites
    If Target.Column < 6 And Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then
        With Sheets("CalculsMacros")
            'on cherche sur la feuille "CalculsMacros" le numéro de ligne correspondant à l'évènement
            Ligne = Application.Match(Cells(Target.Row, 5), .[C:C], 0)
            'si  on ne le trouve pas, on affecte le n° de la ligne "Autres"
            'on peut aussi rechercher ce n°
            If Not IsNumeric(Ligne) Then Ligne = 9
            'on additionne le nombre de la colonne C de la feuille "saisie-pilote" dans la colonne E
            ' de la feuille "CalculsMacros"
            .Cells(Ligne, 5) = .Cells(Ligne, 5) + Cells(Target.Row, 3)
            .Cells(Ligne, 8) = .Cells(Ligne, 8) + 1
        End With
    End If
End Sub

Je souhaiterai que dans la fonction If (ou If not je ne sais pas trop...) soit rajouté une deuxième condition: Que la variable "Ligne" égale la colonne 5 (E) ce qui est déjà fait ET égale la colonne 4 (D).
En effet, si il y a la même cellule plusieurs fois sur la colonne E alors que sur la colonne D celles-ci sont différentes, la variable "Ligne" va prendre la première cellule trouvée en E alors que ce n'est pas forcément la bonne...

Je rajoute le fichier en pièce jointe si je me suis mal fait comprendre

.

Cordialement,

Blend

Invité · 31/12/2013, 12h27

je ne sai pas si c'est ce que tu cherche!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
If IsNumeric(Ligne) Then 
'?ton code
else
    Ligne = 9
end if

**Blend** · 31/12/2013, 12h43

Merci pour ta réponse, je l'ai rajouté en souligné:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
'la macro se déclenche à chaque fois qu'une valeur est entrée dans une cellule de la feuille
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Ligne As Variant
    'si la saisie concerne une colonne inférieure à 5 et que les saisies des colonnes A, B et D
    'ont été faites
    If Isnumeric(Ligne) And Target.Column < 6 And Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then        With Sheets("CalculsMacros")
            'on cherche sur la feuille "CalculsMacros" le numéro de ligne correspondant à l'évènement
            Ligne = Application.Match(Cells(Target.Row, 5), .[C:C], 0)
            'si  on ne le trouve pas, on affecte le n° de la ligne "Autres"
            'on peut aussi rechercher ce n°
            Else Ligne = 9            'on additionne le nombre de la colonne C de la feuille "saisie-pilote" dans la colonne E
            ' de la feuille "CalculsMacros"
            .Cells(Ligne, 5) = .Cells(Ligne, 5) + Cells(Target.Row, 3)
            .Cells(Ligne, 8) = .Cells(Ligne, 8) + 1
        End With
    End If
End Sub

Mais après test j'ai "Erreur de compilation: Else sans If". Avec la ligne

Private Sub Worksheet_Change(ByVal Target As Range)

en surligné jaune.
Est-ce mis à la mauvaise place ?

Sur le fichier joint, la macro ne prend en compte que la colonne E de la feuille 'saisie-pilote' pour reporter la valeur ("Durée") sur la feuille 'CalculsMacros' alors que celle-ci devrait prendre aussi en compte la colonne D.

**Marc-L** · 31/12/2013, 12h46

Bonjour,

à quoi sert la ligne n°15 ? Vu que la ligne With a disparu …

Invité · 31/12/2013, 13h00

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
If Isnumeric(Ligne) And Target.Column < 6 And Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then       
 With Sheets("CalculsMacros")
            'on cherche sur la feuille "CalculsMacros" le numéro de ligne correspondant à l'évènement
            Ligne = Application.Match(Cells(Target.Row, 5), .[C:C], 0)
            'si  on ne le trouve pas, on affecte le n° de la ligne "Autres"
            'on peut aussi rechercher ce n°
            Else
 Ligne = 9            'on additionne le nombre de la colonne C de la feuille "saisie-pilote" dans la colonne E
            ' de la feuille "CalculsMacros"
            .Cells(Ligne, 5) = .Cells(Ligne, 5) + Cells(Target.Row, 3)
            .Cells(Ligne, 8) = .Cells(Ligne, 8) + 1
        End With
    End If
End Sub

**SCryptCypher** · 31/12/2013, 13h33

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
With Sheets("CalculsMacros")
     If Isnumeric(Ligne) And Target.Column < 6 And Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then       
          'on cherche sur la feuille "CalculsMacros" le numéro de ligne correspondant à l'évènement
          Ligne = Application.Match(Cells(Target.Row, 5), .[C:C], 0)
          'si  on ne le trouve pas, on affecte le n° de la ligne "Autres"
          'on peut aussi rechercher ce n°
     Else
          Ligne = 9            'on additionne le nombre de la colonne C de la feuille "saisie-pilote" dans la colonne E
          ' de la feuille "CalculsMacros"
          .Cells(Ligne, 5) = .Cells(Ligne, 5) + Cells(Target.Row, 3)
          .Cells(Ligne, 8) = .Cells(Ligne, 8) + 1
      End If
End With

**Blend** · 31/12/2013, 13h56

Bonjour Marc-L,
Le with s'est décalé sur la droite à la ligne 6 quand j'ai souligné mon code

.

Rdurupt: Après test de ta macro, une erreur s'affiche "Erreur de compilation. Else sans If". En me surlignant Else et avec la ligne 2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub Worksheet_Change(ByVal Target As Range)

en surligné.

Bonjour ScryptCypher, avec ta macro, lors du renseignement de l'heure de début et de fin, une erreur d'exécution '13' (incompatibilité de type) apparait et en cliquant sur débogage, la ligne

.Cells(Ligne, 5) = .Cells(Ligne, 5) + Cells(Target.Row, 3)

est surlignée en jaune.

Je dois surement mal copier/coller... Dans ce cas pourrais-je avoir plus d'informations svp ? Merci d'avance de votre temps consacré.

Blend

**SCryptCypher** · 31/12/2013, 13h58

Il manque une "." avant le dernier Cells

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Cells(Ligne, 5) = .Cells(Ligne, 5) + .Cells(Target.Row, 3)

Invité · 31/12/2013, 14h06

à vrait dire je n'es pas regardé le code seulement le if ... else ... end if

**Blend** · 31/12/2013, 14h26

Effectivement ScryptCypher, mais cela me donne des résultats plus qu'étrange

. Ma cellule se recopie plusieurs fois dans une cellule qui n'est pas au bon endroit..!

Rdurupt, je devrais chercher de ce côté pour ma macro ?

Un exemple concret pourrait être plus compréhensif.
Sur la feuille 'saisie-pilote' --> 7:00 début, 8:00 fin [Le calcul donne 1,00

] On choisi la cause: Housseuse MSK (Machine) Pb pinces (Cause).

Ensuite, en théorie sur la feuille 'CalculsMacros' se reporte 1,00 heure à la colonne Durée totale et à la ligne Housseuse MSK.

En espérant être le plus clair possible !

Invité · 31/12/2013, 14h54

je pense que ton problème est là

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Isnumeric(Ligne) And Target.Column < 6 And Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then

dans ta proposition initiale

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Target.Column < 6 And Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then

tu ne disocie pas le test Isnumerique du reste hors tu fait l'accisition du Ligne en dessous du test???

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
If Isnumeric(Ligne) And Target.Column < 6 And Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then       
 With Sheets("CalculsMacros")
            'on cherche sur la feuille "CalculsMacros" le numéro de ligne correspondant à l'évènement
            Ligne = Application.Match(Cells(Target.Row, 5), .[C:C], 0)

je ne peux que faire des suggestions mais comme je ne voie pas à quoi peut servir Ligne

**Blend** · 31/12/2013, 15h06

Ce code a été rédigé par Daniel.C. C'est moi en rajoutant une colonne et donc une condition qui a tout bousculé..!

Le fait de rajouter "If IsNumeric (Ligne)" ne change rien de notable sur ma macro.

je ne peux que faire des suggestions mais comme je ne voie pas à quoi peut servir Ligne

C'est la variable utilisée pour connaitre la ligne dans laquelle va se reporter la durée de l'évènement en fonction de la machine

.
Ainsi si l'évènement "Vracs" de la machine "Pal 1 - HAMBA" est choisi, sa durée se reporte à la ligne 4.

Le problème vient justement de là, la variable Ligne ne prend en compte que la cause et non le nom de la machine.

Invité · 31/12/2013, 15h19

Alors Daniel au charbom!!!

**Blend** · 31/12/2013, 15h33

^^ Dois-je lui envoyer un MP ?

Mais je ne pense pas qu'il y ai que Daniel.C qui puisse résoudre mon problème. Il y a tellement d'experts en la matière que je pense que ce problème qui me semble insurmontable devrait pouvoir se résoudre très facilement

!

Invité · 31/12/2013, 15h46

Non, je suis sur mon tel dans les transports, je suis un peut impuissant.

Cétait une boutade!

**Blend** · 31/12/2013, 15h50

Bon trajet alors!

Je reviendrai par ici l'année prochaine. Bonne fête de fin d'année!

**Theze** · 31/12/2013, 18h03

Bonjour,

Comme la plage de recherche n'est pas très grande, il est suffisamment rapide de la balayer pour chercher la concaténation du nom de la machine avec le nom du problème. Si la variable n'est pas initialisée, "IsEmpty" est plus approprié :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
'la macro se déclenche à chaque fois qu'une valeur est entrée dans une cellule de la feuille
Private Sub Worksheet_Change(ByVal Target As Range)
 
    Dim Ligne As Variant
    Dim Plage As Range
    Dim Cel As Range
    Dim Chaine As String
 
    'saisie en colonnes A à E et A à D non vides
    If Target.Column < 6 And Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then
 
        'concatène le nom de la machine avec le nom du problème
        Chaine = Cells(Target.Row, 4) & Cells(Target.Row, 5)
 
        With Sheets("CalculsMacros")
 
            'on cherche sur la feuille "CalculsMacros" le numéro de ligne correspondant à l'évènement et au nom de la machine
            Set Plage = .Range(.Cells(4, 2), .Cells(.Rows.Count, 2).End(xlUp))
 
            For Each Cel In Plage
 
                If Cel.Value & Cel.Offset(, 1).Value = Chaine Then
 
                    Ligne = Cel.Row
                    Exit For
 
                End If
 
            Next Cel
 
            'si  on ne le trouve pas, on affecte le n° de la ligne "Autres"
            'on peut aussi rechercher ce n°
            If IsEmpty(Ligne) Then Ligne = 9
            'on additionne le nombre de la colonne C de la feuille "saisie-pilote" dans la colonne E
            ' de la feuille "CalculsMacros"
            .Cells(Ligne, 5) = .Cells(Ligne, 5) + Cells(Target.Row, 3)
            .Cells(Ligne, 8) = .Cells(Ligne, 8) + 1
 
        End With
 
    End If
 
End Sub

Hervé.

**nibledispo** · 01/01/2014, 02h27

Bonjour,

Je viens de découvrir la solution de Theze que je n'ai pas encore analyser mais puisque j'avais développé un code, je te le propose. Il t'appartient de choisir si tant est qu'ils ne soient pas identiques.

Le code part du principe que les machines étant moins nombreuses que les événements cumulés il est préférable:
- de rechercher la première ligne de la machine
- faire sur les lignes correspondant à cette machine la recherche de l'événement.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
    If Target.Column <> 5 Then Exit Sub ' le target ne concerne que la colonne 5
    Dim Ligne As Integer
    Dim trouvé As Boolean
    trouvé = false
    'si toutes les colonnes de 1 à 5 sont renseignées
    If Application.CountA(Cells(Target.Row, 1).Resize(, 5)) = 5 Then
        With Sheets("CalculsMacros")
          'on cherche sur la feuille "CalculsMacros" la première ligne de la machine correspondant à l'évènement
           Ligne = Application.Match(Cells(Target.Row, 4), .[A:A], 0) ' départ de la recherche
 
           Do While .Cells(Ligne, 1) = Target.Offset(0, -1) '  "Autre" est traité comme un cas courant dans la boucle
 
              If .Cells(Ligne, 3) = Target  Then
                 .Cells(Ligne, 5) = .Cells(Ligne, 5) + Cells(Target.Row, 3)
                 .Cells(Ligne, 8) = .Cells(Ligne, 8) + 1
                 trouvé = true
                 Exit Do
              End If
              Ligne = Ligne + 1
           Loop
 
          if trouvé = false then
             Msgbox " cas incompatible avec le choix dans une liste existante"
          end if
        End With
    End If
End Sub

Edit : je viens d'essayer le code de theze. il semble qu'il y ait un problème

10h 01/01/14 : j'ai enfin réussi à ouvrir ta dernière mouture du fichier (sans doute un problème DVP).
Il aurait été mieux de livrer un fichier non protégé afin d'y apporter les améliorations souhaitables.
exemple :
- il n'y a aucune raison à la fusion des colonnes A et B dans la feuille "calculsmacros"
- les colonnes A et B de "evenements" et "calculsmacros" étant strictement identiques pourquoi ne pas fusionner les deux feuilles

Cordialement,

**Blend** · 02/01/2014, 10h07

Bonjour et bonne année à tous,

Merci Theze, ta macro fonctionne à merveille! De plus elle est très bien détaillée. Cependant, le nombre de causes et de machines ici est très sommaire et il risque d'en avoir beaucoup plus. Je ne sais pas si cela va "beaucoup" ralentir le calcul de la macro mais dans le doute, je pense prendre celle de nibledispo qui prend d'abord en compte la machine. Et qui a eu la très bonne idée de rajouter une MsgBox si la cause est rédigée à la main par exemple.

Nibledispo merci donc aussi à toi!

- il n'y a aucune raison à la fusion des colonnes A et B dans la feuille "calculsmacros"
- les colonnes A et B de "evenements" et "calculsmacros" étant strictement identiques pourquoi ne pas fusionner les deux feuilles

Les fusions de cellule, j'en faisait beaucoup beaucoup (beaucoup) trop à mes débuts sur Excel mais depuis ces qq semaines, je me suis rendu compte que cela était 1-moche 2-inutil et surtout que ça rendait les calculs plus difficile...

Je ne veux pas fusionner les deux feuilles dans un soucis de lisibilité des pilotes

.

Sujet résolu à merveille encore une fois!
Bien cordialement,

Blend

Avoir deux conditions dans la fonction If / If not [XL-2010]

Macros et VBA Excel

Discussions similaires

Partager

Partager