Discussion :

[andre michel]

Bonjour a tous,

Je débute depuis quelques mois en VBA (Office 2007), mais j'ai des connaissances dans d'autres langages. J'ai écris un prgm VBA et dans un des onglets (nom "GZ Curve"), j'ai tracé une courbe (nom "GZ"). J'ai affiché la tendance polynomiale 6ème degré et affiché l'équation qui apparait dans la zone de traçage.
Mon but est de récupérer cette fonction pour effectuer des calculs de surface.
La fonction est du type y=a x^6 + b x^5 + c x^4 + d x^3 + e x^2 + f x + g.
Il me suffit d'avoir les valeurs de a, b, c, d, e, f et g.
Cela semble faisable mais je n'ai pas tout bien saisi sur la méthode.
Un grand merci par avance si qqun peu me guider pour faire ce prgm en VBA pour récupérer ces données.

[mercatog]

Une petite gymnastique

Faire apparaitre la courbe de tendance et son équation sur le graphique
Récupérer cette équation puis la traiter
Effacer la courbe de tendance

La fonction suivante récupère les coefficients de l'équation de tendance de la courbe en paramètre Sr. C'est un tableau à 7 éléments

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Option Explicit
 
Function CoefTend(ByVal Sr As Series)
 
With Sr
    If .Trendlines.Count > 0 Then .Trendlines(1).Delete
    With .Trendlines.Add
        .Type = xlPolynomial
        .Order = 6
        .DisplayEquation = True
        .DataLabel.NumberFormat = "0.00000E+00"
        Application.Wait Time + TimeSerial(0, 0, 1)
        CoefTend = ExtrCoef(.DataLabel.Text)
        .Delete
    End With
End With
End Function
 
Private Function ExtrCoef(ByVal Tmp As String)
Dim i As Byte, n As Byte
Dim Tb
 
Tmp = Replace(Tmp, "y = ", "")
Tmp = Replace(Tmp, " + ", "|+")
Tmp = Replace(Tmp, " - ", "|-")
Tb = Split(Tmp, "|")
 
For i = LBound(Tb) To UBound(Tb)
    n = InStr(Tb(i), "x")
    If n Then Tb(i) = Left(Tb(i), n - 1)
Next i
 
ExtrCoef = Tb
End Function

Par exemple on écrit les coefficients de la courbe 1 de l'objet graphique 1 vers D1 à J1 de la feuille Feuil1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Test()
 
With Worksheets("Feuil1")
    .Range("D1:J1") = CoefTend(.ChartObjects(1).Chart.SeriesCollection(1))
End With
End Sub

[andre michel]

Bonjour,

Je vous remercie beaucoup pour votre aide bien utile ce qui m'a permis de compléter mon prgm aprés un test.

Vous souhaitant bon WE

Cordialement