Discussion :

[Canidé]

Bonjour,

Pouvez vous me dépanner s'il vous plait?

Sur la feuille "PointageChéquiers" de mon classeur Excel (2002 avec SP3), j'aimerai copier la plage de cellules de D4 à D203 de la colonne D dans la plage de cellules B4 à B203 de la colonne B sachant:

--- que les cellules D4 à D203 de la colonne D contient des résultats de formules (='Registre des Mouvements'!P4) pour la cellule D4, (='Registre des Mouvements'!P5) pour la cellule D5), jusque (='Registre des Mouvements'!P203) pour la cellule D203.

--- que la copie des cellules dans la colonne B se fasse sans copier les cellules sans valeur (vides) de
la colonne D.

Si un code est nécessaire, à quoi l'affecter (bouton, feuille, classeur,….) et comment faire pour l'affecter, mes connaissances dans ce domaine étant assez faibles.

J'ai regardé dans le forum mais avec mon peu de connaissances, je n'arrive pas à adapter les codes à mon classeur.

Merci pour vos réponses

[Invité]

Bonjour,

Une solution possible avec ce code dans le classeur joint.

Le code ci-dessous remplace une date d'opération par une date de valeur. La macro est lancée par un bouton dans la feuille mise à jour

Les dates mises à jour sont mises en couleur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub MettreAJourLaColonneBAPartirDeLaColonneD()
 
Dim ShPointage As Worksheet
Dim AireCible As Range
Dim CelluleCible As Range
Dim ColonneCible As Long
Dim ColonneSource As Long
 
    Set ShPointage = Sheets("PointageChéquiers")
    Set AireCible = ShPointage.Range(ShPointage.Cells(4, 2), ShPointage.Cells(203, 2))
    ColonneCible = AireCible.Column
    ColonneSource = 4
    AireCible.Interior.Color = xlNone
 
    For Each CelluleCible In AireCible
        Select Case CelluleCible.Offset(0, ColonneSource - ColonneCible)
            Case "", 0
 
            Case Else
               With CelluleCible
                ' Pour repérer les cellules mises à jour
                If CelluleCible <> CelluleCible.Offset(0, ColonneSource - ColonneCible) Then
                    .Interior.Color = RGB(228, 223, 236)
                End If
                .Value = CelluleCible.Offset(0, ColonneSource - ColonneCible)
               End With
 
        End Select
    Next CelluleCible
 
    MsgBox "Fin de mise à jour !", vbInformation, "Mise à jour de la colonne B"
 
    Set AireCible = Nothing
    Set ShPointage = Nothing
 
End Sub

Cordialement.