Discussion :

[PSAIMOND]

Bonjour,

J'ai un code VBA que je souhaitais utiliser pour supprimer une ou plusieurs lignes d'un tableau comportant une valeur spécifique (voir tableau que je joins) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub sup_ligne_tableau()
Dim cellule As Object
Sheets("Feuil4").Select
Range("a2").Select
Range(Selection, Selection.End(xlDown)).Select
For Each cellule In Selection
If cellule = "A" Then
cellule.EntireRow.Delete 'detruit toute les cellules de la ligne
End If
Next
End Sub

Mon souci est le suivant : Cette macro fonctionne bien tant que la valeur "A" n'est pas présente plusieurs fois à la fin de ma liste, auquel cas, elle n'est pas supprimée. J'espère que quelqu'un saura m'expliquer pourquoi et me donner une solution qui évite ce problème. D'avance merci. Cordialement.

[Invité]

Bonjour,

Essayez ce code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Sup_Ligne_Tableau()
 
Dim I As Long
Dim DerniereLigne As Long
Dim Sh As Worksheet
 
    Set Sh = Sheets("Feuil4")
    DerniereLigne = Sh.Cells(Sh.Rows.Count, 1).End(xlUp).Row
 
    For I = DerniereLigne To 2 Step -1
        If Sh.Cells(I, 1) = "A" Then Sh.Cells(I, 1).EntireRow.Delete
    Next I
 
    Set Sh = Nothing
 
End Sub

Cordialement.

[PSAIMOND]

Merci, cela fonctionne. Pouvez vous SVP m'expliquer le bug dans mon code ?

D'avance merci.

[Invité]

Au fur et à mesure de la suppression de vos lignes, votre zone sélectionnée est aussi modifiée. Comme vous commencez par le début la liste, il arrive un moment où vos cellules "A" sont hors zone sélectionnée. Pour régler ce problème, lorsque vous voulez supprimer des lignes ou des cellules, il faut toujours commencer par la fin.

Cordialement.

[PSAIMOND]

Bonjour,

Je vois que nous avons ou avons eu un employeur commun !

Si je peux me permettre, pourriez vous m'indiquer une méthode qui, à l'aide d'un tableau existant, me permettre de modifier la valeur d'une cellule, en fonction de la valeur contenue dans une autre cellule, ligne à ligne ?

D'avance merci.

Cordialement.

[Invité]

Si je peux me permettre, pourriez vous m'indiquer une méthode qui, à l'aide d'un tableau existant, me permettre de modifier la valeur d'une cellule, en fonction de la valeur contenue dans une autre cellule, ligne à ligne ?

Bonjour,

Il faudrait expliquer ce que vous souhaitez faire à l'aide d'un exemple.

Cordialement.

[PSAIMOND]

Bonjour,

Pour être plus précis sur ma demande, je vous joins un tableau exemple de ma recherche qui est :

- sur toutes les ligne d'un tableau, je teste la valeur d'une cellule.
- si cette cellule à une valeur donnée, alors, je mets à jour une autre cellule de la même ligne

J'espère avoir été plus clair.

Cordialement.

Philippe

[Invité]

- sur toutes les ligne d'un tableau, je teste la valeur d'une cellule.
- si cette cellule à une valeur donnée, alors, je mets à jour une autre cellule de la même ligne

Bonjour,


Une solution possible :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Sub RemplacerValeur()
 
Dim Sh As Worksheet
 
Dim LigneEnCours As Long
Dim DerniereLigne As Long
Dim ColonneTestee As Long
 
    Set Sh = Sheets("Feuil1")
 
    ColonneTestee = 3
    DerniereLigne = Sh.Cells(Sh.Rows.Count, ColonneTestee).End(xlUp).Row
 
    For LigneEnCours = 1 To DerniereLigne
        If CStr(Mid(Sh.Cells(LigneEnCours, ColonneTestee), 2, 3)) = "326" Then Sh.Cells(LigneEnCours, 1) = "X"
    Next LigneEnCours
 
    Set Sh = Nothing
 
End Sub

Cordialement.