Discussion :

[Christian_Bale]

Bonjour,

Je vous explique mon problème: j'ai une liste d'indicateur que je dois calculer à l'aide de différents filtres. Pour l'instant l'utilisateur doit rentrer le nom de l'indicateur en paramètre dans le %LET et le programme marche.
Cependant j'aimerais automatiser tout cela afin que toute ma liste d'indicateur se trouvant dans un fichier SAS s’exécute pour avoir tous mes filtres.

Code pour le moment:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
%let Indicateur="LCR_OF_RET_D_SEC_TR_5";
 
DATA _NULL_;
set RACINE.Stg_moteur_lcr;
if  Nom_indicateur=&Indicateur. then
do; 
call symput('Filtre_gene',filtre_g_n_rique);
call symput('Nom_du_filtre',Nom_du_filtre);
call symput('Filtre_spe',filtre_sp_cfique);
call symput('metrique',metrique);
call symput('Indicateur',Nom_indicateur);
end;
run;
 
proc sql;
create table Ind.&Indicateur.  as 
select sum(&metrique.)
from FIL.&Nom_du_filtre.
where &Filtre_spe. 
;
quit;

Ma liste d'indicateur se trouve dans une table SAS "stg_moteur" avec comme nom de variables "Nom_indicateur". la boucle doit se faire jusqu’à la fin de ma table et je ne sais pas par ou commencer.

Merci de votre aide.

[olivier.decourt]

AH ! Je vais pouvoir devancer Géraldine dans la promotion d'une solution à base de CALL EXECUTE. C'est une manière de coder qui évite de passer par des macro-variables, et qui permet de rédiger un programme à partir du contenu d'une table : typiquement ce dont tu as besoin.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
DATA _NULL_ ;
  SET RACINE.Stg_moteur_lcr ;
  /* pour chaque indicateur */
  CALL EXECUTE("PROC SQL ; CREATE TABLE IND." !! Nom_indicateur !! " AS ") ;
  CALL EXECUTE("SELECT SUM(" !! metrique !! ")" ) ;
  CALL EXECUTE("FROM FIL."!! Nom_du_filtre) ;
  CALL EXECUTE("WHERE " !! filtre_sp_cfique) ;
  CALL EXECUTE(" ; QUIT ;") ;
RUN ;

Bon courage.
Olivier

[Christian_Bale]

Encore merci, je me rappel avoir vu en cours ce CALL EXECUTE mais je l'avais oublié

Encore une question car je me retrouve de nouveau bloqué. Si je veut mettre des IF dans ce programme comment je peut m'y prendre?

Par exemple if filtre_sp_cfique=" " then ne pas faire exécuter CALL EXECUTE("WHERE " !! filtre_sp_cfique) ;"

Bonne journée.

[olivier.decourt]

ça s'écrit à peu près exactement comme tu le penses :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

IF NOT MISSING(filtre_sp_cfique) THEN CALL EXECUTE ("WHERE " !! filtre_sp_cfique) ;

[Christian_Bale]

Merci encore, maintenant je sais que je peut manipuler les if avec les call execute.