Discussion :

[Phifou]

Bonjour à tous,

j'ai une demande un peu particulière, voilà je souhaite utiliser une macro qui a besoin de récupérer l'adresse de la cellule dans laquelle se trouverait le bouton.
Sachant que je souhaite mettre le bouton dans autant de case que nécessaire.

En gros, il faudrait pouvoir sur une selection mettre un bouton dans chaque cellule de la selection, un peu comme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
for each cellule in Selection
    cells = button.new
next cellule

Mais il faudrait associer une seule macro à chaque bouton et que le bouton, si c'est possible renvoie son adresse à la macro qu'il démarre.

C'est peut-être un peu compliqué, mais si vous avez des idées qui peuvent m'orienter, je devrais réussi à bidouiller un peu tout ça.
Merci d'avance de vos éclairages par avance,


Phifou

[Phifou]

Bon, je me rend bien compte que ce n'est pas facile, alors j'ai eu une autre idée qui me semble plus réalisable :

Une macro mets des boutons sur l'emplacement de cases sélectionnée et leur donne comme nom systématiquement l'adresse de la case sélectionnée. Ensuite on récupère dans la macro le nom du bouton et on en déduit l'adresse (théorique du bouton) : le fichier ne devant pas être soumis à de trop grandes modifications, ça devrait aller.

Toutefois, savez vous comment récupérer les distances des bords de la case par rapport aux marges afin d'en déduire la position de l'emplacement du bouton ?

[Theze]

Bonjour,

C'est assez simple avec un bouton ActiveX qui a la propriété "TopLeftCell" qui retourne l'adresse de la cellule se trouvant sous l'angle haut et gauche comme son nom l'indique mais attention à ce que le bouton soit bien plalcé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Private Sub CommandButton1_Click()
 
    MsgBox Me.CommandButton1.TopLeftCell.Address
 
End Sub

Hervé.

[Phifou]

Ouah c'est trop beau !!! Merci beaucoup !!

Maintenant j'aurais besoin de savoir comment connaître les positions de mes cellules : c'est à dire la distance aux marges (même si je ne suis pas sur de savoir quelle est l'unité). Donc j'aurais besoin de connaitre la position physique et non l'adresse des cellules.

Donc déjà merci beaucoup pour ces informations !!! (+1 ) et merci pour la suite par avance,


Phifou

[Invité]

Salut,

Essaie ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Test()
    Const S_TEXT = " pixels logique"
    Const INDEX_CMD_BTN = "CommandButton1" 'ou 1 pour l'index
    Const NOM_FEUILLE = "Feuil1"
 
    With ThisWorkbook.Worksheets(NOM_FEUILLE).OLEObjects(INDEX_CMD_BTN)
        .Left = .Parent.Columns("B").Left 'Coin supérieur gauche aligné au niveau de la colonne "B"
        .Top = .Parent.Rows(2).Top 'Coin supérieur gauche aligné sur la ligne n°2
        .Width = 120 '120 pixels @ 72 ppp => 240 pixels @ 144 ppp
        .Height = 40 '40 pixels @ 72 ppp => 80 pixels @ 144 ppp
 
        MsgBox "Gauche: " & .Left & S_TEXT & vbNewLine & _
               "Haut: " & .Top & S_TEXT & vbNewLine & _
               "Largeur: " & .Width & S_TEXT & vbNewLine & _
               "Gauche: " & .Height & S_TEXT & vbNewLine
    End With
End Sub

Ça te donnera une idée pour récupérer les coordonnées de tes boutons. Pour passer de pixels physique aux pixels logique, il faut connaitre le nombre de points par pouce que tu as paramétré sous Windows.

[Theze]

Bonjour,

Un petit test avec l'ajout dynamique d'un bouton, configuration de certaines de ses propriétés (pour le fun) et affichage des positions de la cellule et du bouton l'un par rapport à l'autre (elles sont les mêmes) Attention, la construction sera effective une fois le code terminé donc, après le MsgBox :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
Sub Test()
 
    Dim Fe As Worksheet
    Dim Ctrl As OLEObject
    Dim Btn As MSForms.CommandButton
    Dim Cel As Range
 
    Set Fe = Worksheets("Feuil1")
    'cellule D6
    Set Cel = Fe.Cells(6, 4)
 
    'si un second test, détruit le premier bouton
    On Error Resume Next
    Fe.OLEObjects("MonBouton").Delete
    On Error GoTo 0
 
    'crée un bouton sur la cellule D6 de deux fois sa hauteur et deux fois sa largeur
    Set Ctrl = Fe.OLEObjects.Add("Forms.CommandButton.1", , , , , , , Cel.Left, Cel.Top, Cel.Width * 2, Cel.Height * 2)
 
            'affecte l'OLEobject à l'objet CommandButton afin d'utiliser certaines
            'de ses propriétés comme ici, "Caption", "ForeColor", "Font", etc...
            Set Btn = Ctrl.Object
 
            With Btn
 
                .Name = "MonBouton"
                .Caption = "Bouton pour Phifou"
                .ForeColor = &HC00000
 
                With .Font
                    .Size = 12
                    .Bold = True
                End With
 
            End With
    'affiche les positions des deux (cellule et bouton, ce sont les mêmes)
    MsgBox "Left de la cellule : " & Cel.Left & vbCrLf & _
           "Top de la cellule : " & Cel.Top & vbCrLf & vbCrLf & _
           "Left du bouton : " & Btn.Left & vbCrLf & _
           "Top du bouton : " & Btn.Top
 
End Sub

En jouant avec les Offsets des cellules, tu peux connaître la positions des cellules que tu vise :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Sub Test()
 
    Dim Cel As Range
 
    Set Cel = Cells(6, 4) 'cellule D6
 
    'en jouant avec les Offsets on trouve les positions :
    With Cel
 
        'ici la cellule A6
        MsgBox "Top : " & Cells(6, .Offset(0, -.Column + 1).Column).Top & vbCrLf & _
               "Left : " & Cells(6, .Offset(0, -.Column + 1).Column).Left
 
        'ici la cellule B2
        MsgBox "Top : " & Cells(.Offset(-.Row + 2, 0).Row, .Offset(0, -.Column + 2).Column).Top & vbCrLf & _
               "Left : " & Cells(.Offset(-.Row + 2, 0).Row, .Offset(0, -.Column + 2).Column).Left
 
    End With
 
End Sub

Hervé.