Discussion :

[dubdub22]

Bonjour à toutes et à tous,

Voici mon problème :

Je veux obtenir les 3 plus fortes ventes réalisées par d'un coté les hommes et de l'autre les femmes.

En plus des ventes réalisées, je veux connaitre les noms des vendeurs.

Pour les quantités vendues j'utilise deux types de formule, Max et grande.valeur (2), (3).

Pour les noms j'utilise une formule de recherchev.

Mon souci réside au niveau de la recherche du nom, s'il n'y a pas de vente exequo pas de souci, mais si j'ai deux vendeurs qui réalisent la même quantité de vente, seul le premier nom apparait, j'ai essayé avec le système "rang", mais cela me donne une place, et ce n'est pas ce que je recherche.

N'étant pas sûr d'être clair dans mon explication, je vous joins un fichier excel. Essai pour le net.xlsx

Cordialement

Dubdub22

[papouclo]

Bonjour,
Voici une proposition dans le classeur joint.
Une ligne a été insérée sous la ligne 6 ce qui reporte la plage de données en $A$11:$E$17 au lieu de $A$10:$E$16.
Pour le principe, il s'agit d'avoir un classement sans ex æquo et donc ne pas chercher le nom des venduers au moyen d'un classement sur la plage $A$11:$A$17 pour les hommes
ou sur la plage $D$11:$D$17 pour les femmes mais d'un classement sur la plage $A$11:$A$17 - LIGNE($11:$17)/1000 pour les hommes ou sur la plage $D$11:$D$17 - LIGNE($11:$17)/1000 pour les femmes.
Deux remarques :
Si l'on ne veut pas matérialiser ces plages dans des colonnes intermédiaires, il faut utiliser une formule matricielle (c'est le choix fait dans le classeur).
Si l'on est sûr que la plage de données n'atteint pas la ligne 100, on peut se contenter de diviser la ligne par 100 au lieu de la diviser par 1000.
En A4, la formule est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI($A$2="";"";GRANDE.VALEUR(SI($A$2="Homme";$A$11:$A$17;$D$11:$D$17);LIGNE()-3))

recopiée jusqu'en A6.
En A7, la formule est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(OU($A$2="";GRANDE.VALEUR(SI($A$2="Homme";$A$11:$A$17;$D$11:$D$17);LIGNE()-3)<>A6);"";A6)

En B4, la formule matricielle est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
=SI(A4="";"";INDEX(SI($A$2="homme";$B$11:$B$17;$E$11:$E$17);
EQUIV(GRANDE.VALEUR(SI($A$2="homme";$A$11:$A$17;$D$11:$D$17)-LIGNE($11:$17)/1000;LIGNE()-3);SI($A$2="homme";$A$11:$A$17;$D$11:$D$17)-LIGNE($11:$17)/1000;0)))

à valider par Ctrl + Maj + Entrée et à recopier vers le bas jusqu'en B7.
La ligne 7 insérée avec ses formules permet d'écrire deux noms de vendeurs lorsqu'il y a des ex æquo pour la 3ème des plus fortes ventes et ne pas citer seulement l'un des deux.
Cordialement
Claude

[dubdub22]

Bonjour Claude,

Je vous remercie pour votre aide et pour ces formules qui répondent exactement à ce que je veux, c'est super !!!

Mais ( car il y a toujours un mais qui se cache), lorsque j'écris une formule, j'aime bien la comprendre, et là j'ai 2 points que je ne comprends pas, non pas que vos formules ne soient pas claires, non c'est juste que je suis autodidacte, et que je n'ai pas toutes les ficelles des habitués.

Les 2 points sont:

1) à quoi sert le (-3) dans la formule ?
2) Pourquoi faut-il diviser par 1000 ou par cent ?

Voilà, c'est juste pour mon instruction, autrement vos formules me conviennent.

Merci encore de vos réponses et de votre aide.

Cordialement

Dubdub22

je marque le sujet comme résolu.

[papouclo]

Bonjour,
Content que le problème soit résolu.
1er point
Je cherche le plus souvent possible à avoir une seule formule qui se modifie toute seule par incrémentation.
La vente au rang 1 se trouve en cellule A4 et il faudrait écrire une formule du genre = GRANDE.VALEUR(plage;1);
En A5 où l'on désire la vente de rang 2, il faudrait changer la formule en = GRANDE.VALEUR(plage;2) ...
Or en A4, la fonction LIGNE() renvoie 4 donc LIGNE() - 3 renvoie le 1 attendu comme paramètre de la fonction GRANDE.VALEUR.
En A5 , LIGNE() donne 5 donc LIGNE - 3 donne 2 , paramètre pour chercher la 2ème grande valeur ...
2ème point
Le classement se fait sur des nombres entiers mais comporte des ex æquo; pour "départager" ces ex aequo, il suffit de modifier les scores en retranchant
ou en ajoutant des nombres différents pour chaque vendeur mais des nombres obligatoirement inférieurs à 1 pour ne pas pertuber l'ordre normal.
Un critère simple reste de faire intervenir le rang de la ligne où est inscrit chaque vendeur. Les lignes étant comprises entre la ligne 11 et la ligne 17,
il faut donc au moins les diviser par 18, mais il est facile d'utiliser des puissances de 10 assez grandes : 100, 1000 ...
100 suffisait mais ne connaissant pas l'importance du tableau réel, j'ai mis 1000 par mesure de sécurité.
Si on ajoute le nombre ligne()/1000 au score normal au lieu de le soustraire, l'ordre d'écriture des ex æquo sera inversé (ici contraire à l'ordre alphabétique).
Cordialement
Claude

[dubdub22]

Re bonjour Claude,

Merci bien pour cette explication, c'est mieux pour moi de savoir d'une, ce que j'écris, et deux, au cas ou dans l'avenir j'ai à nouveau besoin d'utiliser cette formule.

Voilà merci encore.

Cordialement

Georges